Unity Shader 廣告牌效果

廣告牌效果指的是，一個二維平面的法線方向始終與視線（攝像機的觀察方向）相同。廣泛運用於渲染煙霧，雲朵，閃光等。

它的本質在於構建旋轉矩陣，此時我們可以選擇三個基向量來構建此矩陣。

指向→的方向（X軸）

指向↑的方向（Y軸）

平面的法線方向（Z軸）

計算方法通常是：

1.根據當前攝像機的方向確定法線方向（廣告牌效果的本質），並歸一化

normal=normalize(viewDir);

2.根據得到的法線方向和初始的向上方向（在本地空間中即為float3（0,1,0））計算向右的方向，並歸一化

right=normalize(cross(up,normal));（使用向量的叉乘計算）

3.用計算后的向右方向和法線方向重新校正向上的方向，得到精確值

up'=normalize(cross(right,normal));

 

計算出旋轉矩陣后對原始的頂點進行各自方向上的偏移

 

腳本如下：

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "MyUnlit/Billboarding"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Color("Color Tint",color)=(1,1,1,1)
    }
    SubShader
    {
        //對頂點進行變換需禁用合P
        Tags{ "Queue" = "Transparent" "RenderType" = "Transparent" "IgnoreProjector" = "true" "DisableBatching" = "True" }

        Pass
        {
            //透明度混合
            Tags{ "lightmode" = "forwardbase" }
            ZWrite off
            Blend SrcAlpha OneMinusSrcAlpha
            Cull off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Color;

            v2f vert (appdata v)
            {
                v2f o;
                //計算模型空間中的視線方向
                float3 objViewDir = mul(unity_WorldToObject, float4(_WorldSpaceCameraPos, 1));

                //計算旋轉矩陣的各個基向量
                float3 normalDir =normalize(objViewDir);
                float3 upDir =float3(0, 1, 0);
                float3 rightDir = normalize(cross(normalDir, upDir));
                upDir = normalize(cross(normalDir, rightDir));

                //用旋轉矩陣對頂點進行偏移
                float3 localPos =rightDir * v.vertex.x + upDir * v.vertex.y + normalDir * v.vertex.z;

                //將偏移之后的值作為新的頂點傳遞計算
                o.vertex = UnityObjectToClipPos(float4(localPos,1));
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                col.rgb *= _Color.rgb;
                UNITY_APPLY_FOG(i.fogCoord, col);
                return col;
            }
            ENDCG
        }
    }
    fallback "Transparent/VertexLit"
}