unity中Shader實現地形中根據實際高度繪制等高線，剖切功能，顏色漸變等功能

問題背景

在做地形模塊時，需要根據實際地形高度畫出世界相應的等高線，以及根據高度做顏色漸變，以及剖切功能。

解決方法

通過像素點在世界坐標系下的真實高度值來判斷計算繪制等高線，剖切功能以及顏色漸變均有世界坐標實際高度值來判斷，具體邏輯在代碼中，這些均 在shder 中為的fragment階段進行，

Shader代碼

Shader "Custom/StratumFrontShader" {
    Properties{
        _FristColir("MainColor", color) = (0,1,0,1)           //第一種顏色：綠
        _SecondColor("SecondColor", color) = (1,0,0,1)       //第二種顏色：紅
        _Diffuse("Diffuse", Color) = (1,1,1,1)

        _K("K", float) = 0.8
        _P("P", float) = 0.8
    }
    SubShader {
        pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "unitycg.cginc"
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            uniform half _K;
            uniform half _P;

            //高低點顏色
            fixed4 _FristColir;
            fixed4 _SecondColor;
            
            //高低點值
            float _HighValue;
            float _LowValue;
             
            //是否顯示等高線
            float _IsShowContour=0;

            //等高線密集比例
            float _ContourScale=0.12;

            //是否是同一顏色
            float _IsSameColor=0;

             //是否開啟剖切
             float clipping;
             float3 clipPlanePosition;
             float3 clipPlaneNormal;


            struct v2f {
                float4 pos:POSITION;
                float y : TEXCOORD1;
                fixed3 worldNormal: TEXCOORD2;
                fixed3 worldPos: TEXCOORD3;
            };

            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
                o.y = v.vertex.y;
                return o;
            }
            fixed4 frag(v2f IN):COLOR
            {
               float y = IN.y;
    
             //剖切邏輯
              if ( clipping > 0.0 ) {
                float  r = dot( normalize( IN.worldPos - clipPlanePosition ), clipPlaneNormal );
                 if ( r > 0.0 ) {
                    discard;
                 }
               }

               //等高線
               float f = abs( frac( y * _ContourScale ) - 0.5 );  
               float df = fwidth( y * _ContourScale );             
               float g = smoothstep( -df * 2, df * 2, f );
               float3 lineCol = float3( 0.0, 0.0, 0.0 );

               //顏色隨高度漸變
               float h=saturate((_HighValue-y)/(_HighValue-_LowValue));
               h = _IsSameColor == 0 ? h : 0;//同一種顏色時為第一默認色
               fixed3 col = lerp( _FristColir, _SecondColor, h );
               g = _IsShowContour == 0 ? g : 1;
               col = lerp( lineCol, col, g );

               //光照
               float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
               float lightDot = clamp(dot(IN.worldNormal, worldLightDir), -1, 1);
               lightDot = exp(-pow(_K* (1 - lightDot), _P));
               float3 diffuse = _LightColor0.rgb * col * lightDot;
               fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
               fixed3 color0=ambient + diffuse;

              return (fixed4(color0,1));
            }
            ENDCG
        }
    }
}

ps：剖切功能：在於實際坐標點與剖切面的夾角選擇性剔除。漸變功能：根據高度區間變換做的混合，等高線：高度值根據設定參數計算，插值出等高線。

這里是我功能源代碼，這里做了剖切和顏色漸變和光照，提供給大家做個參考吧。

效果如下：