Unity Shader 屏幕后效果——攝像機運動模糊（速度映射圖實現）

速度映射圖主要是為了得到每個像素相對於前一幀的運動矢量，其中一種方法是使用攝像機的深度紋理來推導。

推導過程如下：

先由深度紋理逆推出NDC（歸一化的設備坐標）下的頂點坐標，利用VP矩陣（視角*投影矩陣）的逆矩陣反向變換出每個像素在世界空間中的位置，

再利用世界空間下的坐標與前一幀的VP矩陣順向變換出前一幀的NDC坐標，利用NDC下前一幀和相當幀的坐標差來確定速度的方向，

最后利用速度的方向對紋理采樣的結果進行加權平均並多次繪制，以達到帶有物體運動方向的模糊效果。

 

基於這一原理，需要准備的要素有：

1.攝像機的深度紋理（是由NDC下的坐標映射來的，需要先反向映射回NDC）

2.當前幀的VP矩陣的逆矩陣

3.前一幀的VP矩陣

 

攝像機深度值和深度紋理的獲取方法在之前的博客中有寫，具體可以參考：

https://www.cnblogs.com/koshio0219/p/11178215.html

視角矩陣（V矩陣）：

MyCamera.worldToCameraMatrix;（也就是世界空間變換到攝像機空間（也叫視角空間，觀察空間））

投影矩陣（P矩陣）：

MyCamera.projectionMatrix;（也就是攝像機空間變換到裁剪空間）

 

具體的數學推導過程可以見這篇文章：

http://feepingcreature.github.io/math.html

 

下面是具體的程序實現：

1.此腳本掛載在攝像機上，用於模糊參數調控，深度紋理准備，矩陣傳遞：

using UnityEngine;

public class MotionBlurWithDepthTexCtrl : ScreenEffectBase
{
    private const string _BlurSize = "_BlurSize";
    private const string _PreViewMatrix = "_PreViewMatrix";
    private const string _CurViewInserseMatrix = "_CurViewInserseMatrix";

    [Range(0.0f, 1.0f)]
    public float blurSize = .5f;

    //前一幀的VP矩陣
    private Matrix4x4 preViewMatrix;

    private Camera myCamera;
    public Camera MyCamera
    {
        get
        {
            if(null == myCamera)
            {
                myCamera = GetComponent<Camera>();
            }
            return myCamera;
        }
    }

    //開啟這相機深度模式，並初始化前一幀的VP矩陣
    private void OnEnable()
    {
        MyCamera.depthTextureMode |= DepthTextureMode.Depth;

        //右乘原則，前邊是P矩陣，后邊是V矩陣
        preViewMatrix = MyCamera.projectionMatrix * MyCamera.worldToCameraMatrix;
    }

    //不用時恢復
    private void OnDisable()
    {
        MyCamera.depthTextureMode &= ~DepthTextureMode.Depth;
    }

    private void OnRenderImage(RenderTexture source, RenderTexture destination)
    {
        if (Material)
        {
            Material.SetFloat(_BlurSize, blurSize);
            //設置前一幀的VP矩陣
            Material.SetMatrix(_PreViewMatrix, preViewMatrix);
            //計算當前幀VP矩陣，右乘
            Matrix4x4 curViewMatrix = MyCamera.projectionMatrix * MyCamera.worldToCameraMatrix;
            //存起來，作為下次計算的前一幀
            preViewMatrix = curViewMatrix;
            //設置當前幀的VP矩陣的逆矩陣
            Material.SetMatrix(_CurViewInserseMatrix, curViewMatrix.inverse);

            Graphics.Blit(source, destination, Material);
        }
        else
            Graphics.Blit(source, destination);

    }
}

基類腳本見：

https://www.cnblogs.com/koshio0219/p/11131619.html

 

2.Shader腳本：

Shader "MyUnlit/MotionBlurWithDepthTex"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Pass
        {
            ZTest Always Cull Off ZWrite Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            half4 _MainTex_TexelSize;
            fixed _BlurSize;
            //聲明深度紋理和對應矩陣
            sampler2D _CameraDepthTexture;
            float4x4 _PreViewMatrix;
            float4x4 _CurViewInserseMatrix;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                //這里的的uv同時存了主紋理的uv和深度紋理uv，xy為主紋理，zw為深度紋理
                half4 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv.xy =v.uv;
                o.uv.zw=v.uv;

                //主紋理外的紋理要進行平台差異化處理
                #if UNITY_UV_STARTS_AT_TOP
                if(_MainTex_TexelSize.y<0)
                    o.uv.w=1-o.uv.w;        
                #endif

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //用深度紋理和zw取得深度值
                float d=SAMPLE_DEPTH_TEXTURE(_CameraDepthTexture,i.uv.zw);
                //反映射回NDC坐標，由[0,1]到[-1,1]的映射，z分量就是深度值本身
                float4 H=float4(i.uv.x*2-1,i.uv.y*2-1,d*2-1,1);
                //用VP的逆矩陣反向變換並除以w分量得到世界坐標位置，為什么除以w詳細見前面數學推導的文章鏈接
                float4 D=mul(_CurViewInserseMatrix,H);
                float4 worldPos=D/D.w;

                //分別得到前一幀和當前幀的NDC坐標取差值計算速度方向
                float4 curViewPos=H;
                float4 preViewPos=mul(_PreViewMatrix,worldPos);
                preViewPos/=preViewPos.w;

                //除以的系數可以根據自己的需求調整
                float2 velocity=(curViewPos.xy-preViewPos.xy)/10.0f;

                float2 uv=i.uv.xy;
                //紋理采樣的速度權重，這里進行了前2幀的計算，包括當前幀總共3個值，值依次遞減且保證和為1，不為1則需要進行額外的除法
                //目的是為了讓越之前的幀看上去效果越淡，軌跡逐漸消失
                float velColRate[3]={0.6,0.3,0.1};
                //當前采樣結果用權重最大的值0.6
                fixed4 col = tex2D(_MainTex, uv)*velColRate[0];
                uv+=velocity*_BlurSize;

                for(int it=1;it<3;it++)
                {
                    //前兩幀采樣結果依次遞減，0.3,0.1
                    fixed4 curCol=tex2D(_MainTex,uv.xy)*velColRate[it];
                    //將所有結果加起來，保證權重為1
                    col+=curCol;
                    //按速度方便對紋理進行偏移，並用模糊系數加以控制
                    uv+=velocity*_BlurSize;
                }

                return fixed4(col.rgb,1.0);
            }
            ENDCG
        }
    }
    FallBack Off
}

效果如下：