Unity Shader 屏幕后效果——Bloom外發光

Bloom的原理很簡單，主要是提取渲染圖像中的亮部區域，並對亮部區域進行模糊處理，再與原始圖像混合而成。

 

一般對亮部進行模糊處理的部分采用高斯模糊，關於高斯模糊，詳見之前的另一篇博客：

https://www.cnblogs.com/koshio0219/p/11152534.html

 

計算方法：

總共需要用到4個Pass，它們的順序如下：

Pass 1：得到紋理的亮度值（灰度值），由此計算出亮部區域，傳遞給一個臨時的新紋理，這里叫_Bloom

Pass 2,3：單獨對_Bloom進行高斯模糊（縱橫），_Bloom紋理更新

Pass 4：混合原始紋理和_Bloom紋理，得到最終效果

 

為了得到更為細致的Bloom效果，建議將游戲的顏色空間由默認的伽馬空間轉為線性空間，必要時還可開啟HDR

 

控制腳本：

using UnityEngine;

public class BloomCtrl : ScreenEffectBase
{
    private const string _LuminanceThreshold = "_LuminanceThreshold";
    private const string _BlurSize = "_BlurSize";
    private const string _Bloom = "_Bloom";

    [Range(0, 4)]
    public int iterations = 3;
    [Range(0.2f, 3.0f)]
    public float blurSize = 0.6f;
    [Range(1, 8)]
    public int dowmSample = 2;
    [Range(0.0f, 4.0f)]
    public float luminanceThreshold = 0.6f;//控制Bloom效果的亮度閾值，因為亮度值大多數時不大於1，故該值超過1時一般無效果，但開啟HDR后圖像的亮度取值范圍將擴大

    private void OnRenderImage(RenderTexture source, RenderTexture destination)
    {
        if (Material != null)
        {
            Material.SetFloat(_LuminanceThreshold, luminanceThreshold);

            int rth = source.height / dowmSample;
            int rtw = source.width / dowmSample;

            RenderTexture buffer0 = RenderTexture.GetTemporary(rtw, rth, 0);
            buffer0.filterMode = FilterMode.Bilinear;

            //第1個Pass中提取紋理亮部，存到buffer0中，以便后面進行高斯模糊處理
            Graphics.Blit(source, buffer0,Material,0);

            for(int i = 0; i < iterations; i++)
            {
                Material.SetFloat(_BlurSize, blurSize*i+1.0f);

                //第2，3個Pass中對亮部分別進行縱向和橫向的渲染處理（高斯模糊）
                RenderTexture buffer1 = RenderTexture.GetTemporary(rtw, rth, 0);
                Graphics.Blit(buffer0, buffer1, Material,1);
                RenderTexture.ReleaseTemporary(buffer0);//臨時創建的渲染紋理不能直接釋放 x： buffer0.Release();

                buffer0 = RenderTexture.GetTemporary(rtw, rth, 0);
                Graphics.Blit(buffer1, buffer0, Material, 2);
                RenderTexture.ReleaseTemporary(buffer1);
            }

            //第4個Pass將buffer0高斯模糊后的結果傳給_Bloom以進行最后的混合
            Material.SetTexture(_Bloom, buffer0);
            Graphics.Blit(source,destination,Material,3);//注意這里用原始紋理作為源紋理而不是buffer0，因為buffer0已經作為另一個參數進行了傳遞，而這里還需要原始的紋理以進行混合
            RenderTexture.ReleaseTemporary(buffer0);
        }
        else
            Graphics.Blit(source, destination);
    }
}

基類腳本見：

https://www.cnblogs.com/koshio0219/p/11131619.html

 

Shader腳本：

Shader "MyUnlit/Bloom"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Bloom("Bloom",2D)="black"{}
        _LuminanceThreshold("Luminance Threshold",Float)=0.5
        _BlurSize("Blur Size",Float)=1.0
    }
    SubShader
    {
        CGINCLUDE

        #include "UnityCG.cginc"

        sampler2D _MainTex;
        half4 _MainTex_TexelSize;
        sampler2D _Bloom;
        float _LuminanceThreshold;
        float _BlurSize;

        struct v2f
        {
           half2 uv : TEXCOORD0;
           float4 pos : SV_POSITION;
        };

        struct v2fBloom
        {
           //half4是因為這里還要存儲_Bloom紋理
           half4 uv:TEXCOORD0;
           float4 pos:SV_POSITION;
        };

        v2f vert(appdata_img v)
        {
           v2f o;
           o.pos=UnityObjectToClipPos(v.vertex);
           o.uv=v.texcoord;    
           return o;
        }

        v2fBloom vertBloom(appdata_img v)
        {
           v2fBloom o;
           o.pos=UnityObjectToClipPos(v.vertex);

           //xy存儲主紋理，zw存儲_Bloom紋理，這樣不必再申請額外空間
           o.uv.xy=v.texcoord;
           o.uv.zw=v.texcoord;

           //紋理坐標平台差異化判斷，主要針對DirectX,因為DirectX與OpenGL紋理坐標原點不同(分別在左上和左下)
           //同時Unity平台對於主紋理已經進行過內部處理，因此這里只需要對_Bloom紋理進行平台檢測和翻轉
           //主要表現為進行y軸方向的翻轉（因為y軸方向相反），對於_Bloom紋理來說也就是w
           #if UNITY_UV_STARTS_AT_TOP
           if(_MainTex_TexelSize.y<0){
                  o.uv.w=1.0-o.uv.w;
           }
           #endif

           return o;
        }

        //提取超過亮度閾值的圖像
        fixed4 fragExtractBright(v2f i):SV_Target
        {
            fixed4 col=tex2D(_MainTex,i.uv);
            fixed val=clamp(Luminance(col)-_LuminanceThreshold,0.0,1.0);
            return col*val;
        }

        //對xy和zw對應的紋理采樣進行混合
        fixed4 fragBloom(v2fBloom i):SV_Target
        {
            return tex2D(_MainTex,i.uv.xy)+tex2D(_Bloom,i.uv.zw);
        }

        ENDCG

        ZTest Always
        Cull Off
        ZWrite Off

        //Pass 1:提亮部
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment fragExtractBright     
            ENDCG
        }

        //Pass 2,3:高斯模糊，這里直接調用以前寫的Pass
        UsePass "MyUnlit/GaussianBlur/GAUSSIANBLUR_V"

        UsePass "MyUnlit/GaussianBlur/GAUSSIANBLUR_H"

        //Pass 4:混合原圖和模糊后亮部
        Pass
        {
            CGPROGRAM
            #pragma vertex vertBloom
            #pragma fragment fragBloom
            ENDCG
        }
    }
    Fallback Off
}

 

效果如下：