Unity Shader 屏幕后效果——顏色校正

屏幕后效果指的是，當前整個場景圖已經渲染完成輸出到屏幕后，再對輸出的屏幕圖像進行的操作。

 

在Unity中，一般過程通常是：

1.建立用於處理效果的shader和臨時材質，給shader腳本傳遞需要控制的參數和變量

2.利用OnRenderImage函數抓取當前屏幕渲染紋理

OnRenderImage(RenderTexture source, RenderTexture destination){  }

第一個參數為處理前紋理，第二個為最終顯示紋理

3.在OnRenderImage函數中調用Graphics.Blit方法對抓取的紋理進行具體的后期操作

Graphics.Blit(source, destination, material,-1);

material為需要處理的材質，-1為參數pass的默認值，表示對shader中所有的pass依次調用，這里也可以省略

 

為此，首先可以提前建立一個基類ScreenEffectBase，主要用於檢查Shader並創建臨時材質：

腳本如下：

using UnityEngine;

[ExecuteInEditMode]
//屏幕后處理效果主要是針對攝像機進行操作，需要綁定攝像機
[RequireComponent(typeof(Camera))]
public class ScreenEffectBase : MonoBehaviour
{
    public Shader shader;
    private Material material;
    protected Material Material
    {
        get
        {
            material = CheckShaderAndCreatMat(shader, material);
            return material;
        }
    }

    //用於檢查並創建臨時材質
    private Material CheckShaderAndCreatMat(Shader shader, Material material)
    {
        Material nullMat = null;
        if (shader != null)
        {
            if (shader.isSupported)
            {
                if (material && material.shader == shader){ }
                else
                {
                    material = new Material(shader){ hideFlags = HideFlags.DontSave };
                }
                return material;
            }
        }
        return nullMat;
    }
}

之后創建的屏幕后處理效果的控制腳本都可以繼承自該基類，例如我們創建關於基本顏色校正的控制腳本：

using UnityEngine;

public class ColorCorrectionCtrl : ScreenEffectBase
{
    private const string _Brightness = "_Brightness";
    private const string _Saturation = "_Saturation";
    private const string _Contrast = "_Contrast";

    [Range(0, 3)]
    public float brightness = 1.0f;
    [Range(0, 3)]
    public float saturation = 1.0f;
    [Range(0, 3)]
    public float contrast = 1.0f;

    private void OnRenderImage(RenderTexture source, RenderTexture destination)
    {
        if (Material!=null)
        {
            Material.SetFloat(_Brightness, brightness);
            Material.SetFloat(_Saturation, saturation);
            Material.SetFloat(_Contrast, contrast);

            Graphics.Blit(source, destination, Material);
        }
        else
            Graphics.Blit(source, destination);
    }
}

其中，brightness，saturation，contrast分別為調整參數——亮度，飽和度和對比度，_Brightness，_Saturation，_Contrast為之后對應的shader中需要相應定義的屬性參數。

這里利用構建的材質Material對shader的屬性賦值並調用Graphics.Blit進行屏幕后效果的處理。

 

具體實現顏色校正的shader如下：

Shader "MyUnlit/ColorCorrection"
{
    Properties
    {
        //這里的參數主要用於展示在材質面板中進行調節，但因為這次是臨時創建的材質，參數都已經放在了C#腳本中調整，因此相對應的參數都可以省略
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }

        Pass
        {
            //OnRenderImage的調用可能會發生在渲染透明物體之前，為了不影響之后透明物體的渲染，需要：開啟深度測試+雙面渲染+關閉深度寫入
            ZTest always
            Cull off
            ZWrite off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            half _Brightness;
            half _Saturation;
            half _Contrast;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                //因為是臨時創建的材質，這里不需要對紋理進行任何變換操作（無可操作的材質面板），直接傳遞即可，_MainTex_ST也不需要定義
                o.uv = v.uv;
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);

                //亮度計算直接疊加
                fixed3 color = col.rgb*_Brightness;

                //飽和度和灰度有關，先計算最低灰度系數下的圖像，隨后對原始的圖像進行插值操作
                fixed3 gray = fixed3(0.2125, 0.7154, 0.0721);
                //點積得到最低灰度值，構成最低灰度圖像
                fixed minGray = dot(gray, col.rgb);
                fixed3 grayColor = fixed3(minGray, minGray, minGray);
                //對灰度圖像和原始圖像插值操作以得到最終系數的顯示圖像
                color = lerp(grayColor, color, _Saturation);

                //對比度效果類似，先計算最低對比度圖像，即(0.5,0.5,0.5)，隨后插值操作
                fixed3 minContrast = fixed3(0.5, 0.5, 0.5);
                color = lerp(minContrast, color, _Contrast);

                //得到所有處理完成后的圖像顏色，但alpha保持不變
                fixed4 finColor = fixed4(color, col.a);

                UNITY_APPLY_FOG(i.fogCoord, finColor);
                return finColor;
            }
            ENDCG
        }
    }
    //關閉回調
    fallback off
}

效果如下（隨便調的不用在意~）：