1、透明度測試
1.1、介紹
只要一個片元的透明度不滿足條件（通常小於某個閾值），那么就舍棄對應的片元。被舍棄的片元不會在進行任何的處理，也不會對顏色緩沖產生任何影響；否則，就會按照普通的不透明物體來處理，即進行深度測試，深度寫入等等。雖然簡單，但是很極端，要么完全透明，要么完全不透明。
意思就是，如果我們設置閾值為0.5，那么只要片元透明度<0.5，就會變透明，否則不透明。
1.2、代碼
很簡單，+幾句代碼就行了。
Shader "Unlit/AlphaTest"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
//透明度閾值。范圍0-1
_CutOff("CutOff",Range(0,1)) = 0.6
}
SubShader
{
//設置渲染隊列為AlphaTest
Tags { "Queue" = "AlphaTest" "IgnoreProjector" = "True" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fog
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
};
struct v2f
{
float2 uv : TEXCOORD0;
UNITY_FOG_COORDS(1)
float4 vertex : SV_POSITION;
};
sampler2D _MainTex;
float4 _MainTex_ST;
float _CutOff;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
UNITY_TRANSFER_FOG(o,o.vertex);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed4 col = tex2D(_MainTex, i.uv);
//如果采樣的alpha值小於閾值，剔除
if(col.a < _CutOff)
{
//剔除意思就是不讓gpu渲染這個片元，跳過。
discard;
}
UNITY_APPLY_FOG(i.fogCoord, col);
return col;
}
ENDCG
}
}
}
1.3、效果
這個透明紋理每個方格透明度是不同的（能在PS中設置）。
當我們修改閾值時：
2、透明度混合
2.1、介紹
透明度混合可以得到真正的半透明效果，它會使當前片元的透明度作為混合因子，與已經儲存在顏色緩沖中的顏色值進行混合，得到新的顏色。
但是，透明度混合需要關閉深度寫入，這使得我們要非常小心物體的渲染順序。注意：透明度混合只關閉了深度寫入，但沒有關閉深度測試。這表示當使用透明度混合渲染一個片元時，還是會比較它的深度值與當前深度緩沖中的深度值，如果深度值距離攝像機更遠，那么就不會在進行混合操作。比如一個不透明物體在透明物體前面，我們先渲染不透明物體，可以正常的擋住不透明物體。
正確的渲染順序：
1、先渲染所有不透明物體，並開啟他們的深度測試和深度寫入。
2、把半透明物體按它們距離攝像機的遠近進行排序，按照從后往前的順序渲染這些半透明物體，並開啟深度測試，關閉深入寫入。
關於Blend語義：
Blend命令：
ShaderLab中的混合因子：
ShaderLab中的混合操作：
2.2、代碼
此為開啟深度寫入的半透明效果，用於解決因為關閉深度寫入可能導致的錯誤排序（但使用2個Pass同樣會消耗更多性能）。
使用兩個Pass來渲染模型，第一個Pass開啟深度寫入，但不輸出顏色，僅僅是把該模型的深度值寫入深度緩沖，從而剔除模型中被自身遮擋的片元。第二個Pass來進行正常的透明度混合。
Shader "Unlit/17mY"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
_Diffuse("Diffuse",Color) = (1,1,1,1)
//透明強度
_AlphaScale("AlphaScale",Range(0,1)) = 0.5
}
SubShader
{
Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
LOD 100
Pass
{
ZWrite on
//ColorMask設置為0，則不會輸出任何顏色
ColorMask 0
}
Pass
{
Tags{"LightMode"="ForwardBase"}
//關閉深度寫入
ZWrite Off
//因子：源顏色的alpha，目標顏色的（1-alpha）
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fog
#include "UnityCG.cginc"
#include "Lighting.cginc"
struct v2f
{
float4 vertex : SV_POSITION;
float2 uv : TEXCOORD0;
float3 worldNormal : TEXCOORD1;
float3 worldPos : TEXCOORD2;
};
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Diffuse;
float _AlphaScale;
v2f vert (appdata_base v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
//求漫反射
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed4 texColor = tex2D(_MainTex, i.uv);
fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
fixed3 diffuse = _LightColor0.rgb * texColor.rgb * _Diffuse.rgb * max(0,dot(worldLightDir,i.worldNormal));
fixed3 color = ambient + diffuse;
//透明度 * _AlphaScale
return fixed4(color,texColor.a * _AlphaScale);
}
ENDCG
}
}
}
3.3、效果
3、額外知識
3.1、深度測試、深度寫入、合並
深度測試：
Gpu會把該片元的深度值和已經存在於深度緩沖中的深度值進行比較。這個比較函數由開發者設置，通常這個比較函數是小於等於，即如果這個片元的深度大於等於當前深度緩沖區中的值，那么就舍棄它。這是因為我們總想只顯示出離攝像機最近的物體，而那些被其他物體遮擋的就不需要出現在屏幕上。
深度寫入：
是否要將像素的深度寫入到深度緩沖中。前提是通過了深度測試。
合並：
當我們執行渲染時，顏色緩沖中往往已經有了上次渲染之后的顏色結果，那么，我們使用這次渲染得到的顏色完全覆蓋掉之前的結果還是進行其他處理，就是合並需要解決的。
對於不透明物體，開發者可以關閉混合（Blend）操作。這樣片元着色器計算得到的顏色值就會之間覆蓋掉顏色緩沖區中的像素值。但對於半透明物體，就需要混合操作來讓這個物體看起來是透明的。