AVR開發 Arduino方法（四） 串行通信子系統

　　Arduino UNO R3主處理器ATMega328P的串行通信子系統可以用於與計算機、外設或其他微控制器進行通信，它支持3種串行通信方式：通用同步/異步收發器，串行外設接口和兩線串行接口。

1. 通用同步/異步收發器

　　在串行通信中，波特率用來衡量傳輸速率的快慢，同步和異步的對象是波特率的時鍾信號；同步通信的設備之間需要一條額外的時鍾線，也因此同步方式可以提供更高的波特率；這里將以異步為例。

　　下面的示例可以使通過串口發送給Arduino的數據回顯到串口監視器上：

// SerialEcho.ino
char data;

void setup() {
  Serial.begin(9600);
}

void loop() {
  if (Serial.available() > 0) {
    data = Serial.read();
    Serial.print(data);
  }
}

 　　與通用同步/異步收發器相關的Arduino庫函數有：

 

　　Serial.begin(speed)：打開串口0並設置它的波特率

　　speed：串口0的波特率

　　Serial.available()：判斷串口0的緩沖區內是否有數據

　　函數返回串口0緩沖區內數據的字節數

　　Serial.read()：讀取串口0輸入數據

　　函數返回串口0輸入數據的一個字節

　　Serial.print(val)：向串口0打印數據

　　val：打印的數據

　　Serial.println(val)：向串口0打印數據並換行

　　val：打印的數據

 

　　ATMega328P的串口0由5個相關寄存器控制，串口0狀態和控制寄存器A（UCSR0A）的結構如下圖所示：

RXC0

TXC0

UDRE0

FE0

DOR0

PE0

U2X0

MPCM0

接收完成標志位RXD和數據寄存器空標志位UDRE分別在完成一幀數據接收和發送緩沖區為空時被置為1，可以通過向它們寫1清0。

　　串口狀態和控制寄存器B（UCSR0B）的結構如下圖所示：

RXCIE0

TXCIE0

UDRIE0

RXEN0

TXEN0

UCSZ02

RXB08

TXB08

向接收使能位RXNE或發送使能位TXNE寫入1可以分別使能串口0的接收或發送功能。

　　串口0控制寄存器C（UCSR0C）的結構如下圖所示：

URSEL01

UMSEL00

UPM01

UPM00

USBS0

UCSZ01

UCSZ00

UCPOL0

向終止位選擇控制位USBS0位寫入0，則只有1個停止位，寫入1則有2個停止位。數據幀長度控制位UCSZ0[2:0]同時存在UCSR0B寄存器和UCSR0C寄存器中，它和奇偶校驗模式控制位UPM0[1:0]位的設置如下表所示：

UCSZ0[2:0]	數據幀長度		UPM0[1:0]	奇偶校驗模式
000	5位		00	無奇偶校驗
001	6位
010	7位		01	（保留）
011	8位
100	（保留）		10	偶校驗
101	（保留）
110	（保留）		11	奇校驗
111	9位

　　串口0波特率寄存器（UBRR0H和UBRR0L）的計算公式是：

　　Arduino UNO R3開發板使用8位數據幀長度，1個停止位，無奇偶校驗，通過直接訪問寄存器改寫以上程序為：

// SerialEcho_reg.ino
unsigned char USART0_Receive();
void USART0_Transmit(unsigned char val);

void setup() {
  UCSR0A = 0x20;
  UCSR0B = 0x18;
  UCSR0C = 0x06;

  UBRR0H = 0x00;
  UBRR0L = 0x67;
}

void loop() {
  USART0_Transmit(USART0_Receive());
}

unsigned char USART0_Receive() {
  while (!(UCSR0A & (1 << RXC0)));
  return UDR0;
}

void USART0_Transmit(unsigned char val) {
  while (!(UCSR0A & (1 << UDRE0)));
  UDR0 = val;
}

 

2. 串行外設接口

　　串行外設接口是一種同步的串行通信方式，因此它需要比通用同步/異步收發器多一條時鍾線。此外，串行外設接口還引入了主機和從機的概念，通信中使用的時鍾信號由主機產生，從機只有在被主機選中時才能與其進行通信；因此，一個串行外設接口設備一般需要連接4條信號線：SPI時鍾SCK，主入從出MISO，主出從入MOSI和SPI選中SS。

74HC595是一種8位的存儲器，它的結構如下圖所示：

當11（SH_CP）引腳有上升沿產生時，14（DS）引腳上的電平信號會被采樣，並移入8位移位寄存器中，多余的位將從9（Q7’）引腳移出；當12（ST_CP）引腳上有上升沿產生，並且13（OE）引腳為低電平時，移位寄存器中的內容會被復制到存儲寄存器中並輸出。

　　74HC595芯片不是標准的串行外設接口設備，但可以使用串行外設接口向它輸入數據，如圖所示連接電路，Arduino開發板11（PB3/MOSI）引腳連接到74HC595芯片14（DS）引腳，13（PB5/SCK）引腳連接到11（SH_CP）引腳；74HC595芯片12（ST_CP）引腳可以連接到任一Arduino數字引腳，這里是A0（PC0）引腳：

　　下面的示例代碼可以使74HC595芯片連接的LED呈現明暗交替的圖案：

// ShiftOutLed.ino
const int DS = 11;
const int SH_CP = 13;
const int ST_CP = A0;

void setup() {
  pinMode(DS, OUTPUT);
  pinMode(SH_CP, OUTPUT);
  pinMode(ST_CP, OUTPUT);

  digitalWrite(ST_CP, LOW);
  shiftOut(DS, SH_CP, MSBFIRST, B10101010);
  digitalWrite(ST_CP, HIGH);
}

void loop() {
}

 　　與串行外設接口相關的Arduino庫函數有：

 

　　shiftOut(dataPin, clockPin, bitOrder, value)：作為主機移位輸出

　　dataPin：指定移位輸出的引腳

　　clockPin：指定同步時鍾信號的引腳

　　bitOrder：從高位開始發送數據（MSBFIRST）或從低位開始發送數據（LSBFIRST）

　　val：移位輸出的數據

 

　　ATMega328P的串行外設接口由2個相關寄存器控制，SPI控制寄存器SPCR的結構如下圖所示：

SPIE

SPE

DORD

MSTR

CPOL

CPHA

SPR1

SPR0

SPI使能位SPE寫入1則啟用串行外設接口，寫入0則禁用；數據序列位DORD位寫入1則從SPI數據寄存器SPDR的高位開始發送，寫入0則從低位開始發送；時鍾相位位CPHA寫入1則數據在上升沿采樣，寫入0則在下降沿采樣。此外，Arduino作為主機，則主/從選擇位MSTR需寫入1。

　　SPI狀態寄存器SPSR的結構如下圖所示：

SPIF

WCOL

SPI2X

SPI2X位與SPCR寄存器中的SPR[1:0]位共同設定SPI的分頻系數，如下表所示：

SPI2X	SPR[1:0]	時鍾源
0	00	系統時鍾4分頻
0	01	系統時鍾16分頻
0	10	系統時鍾64分頻
0	11	系統時鍾128分頻
1	00	系統時鍾2分頻
1	01	系統時鍾8分頻
1	10	系統時鍾32分頻
1	11	系統時鍾64分頻

　　通過直接訪問寄存器改寫以上程序為：

// ShiftOutLed_reg.ino
void setup() {
  DDRB |= (1 << PB3) | (1 << PB5);
  DDRC |= (1 << PC0);
  
  PORTC &= ~(1 << PC0);
  SPCR = 0x77;
  SPDR = 0xaa;
  PORTC |= (1 << PC0);
}

void loop() {
}

3. 兩線串行接口

　　兩線串行接口同樣也是一種同步的串行通信方式，它的讀和寫時序如下圖所示：

　　

　　

由於主機先發送從機地址，從機應答后再發送其他數據，因此兩線串行接口不需要類似於串行外設接口的選擇信號線；又因為采用半雙工的通信方式，兩線串行接口只需要一條數據線，所以一個兩線串行接口設備一般只需要2條信號線，即時鍾信號線SCL和數據信號線SDA。

　　兩線串行接口可以工作在主機發送模式，主機接收模式，從機發送模式或從機接收模式，Arduino IDE的Wire庫提供了這四種模式的示例，我們主要關注主機發送模式和主機接收模式，下面是這兩個示例：

// master_writer.ino
#include <Wire.h>

void setup() {
  Wire.begin();
}

byte x = 0;

void loop() {
  Wire.beginTransmission(8);
  Wire.write("x is ");
  Wire.write(x);
  Wire.endTransmission();

  x++;
  delay(500);
}

// master_reader.ino
#include <Wire.h>

void setup() {
  Wire.begin();
  Serial.begin(9600);
}

void loop() {
  Wire.requestFrom(8, 6);

  while (Wire.available()) {
    char c = Wire.read();
    Serial.print(c);
  }

  delay(500);
}

 　　與兩線串行接口主機相關的Arduino庫函數有：

 

　　Wire.begin()：作為主機打開兩線串行接口

　　Wire.beginTransmission(address)：開始向指定地址從機傳輸數據

　　address：指定從機的地址

　　Wire.write(val)：向從機發送數據

　　val：發送的數據

　　Wire.endTransmission()：結束向從機發送數據

　　Wire.requestFrom(address, quantity)：向指定地址從機請求指定字節數的數據

　　address：指定從機的地址

　　quantity：指定請求的字節數

　　Wire.available()：判斷兩線串行接口的緩沖區內是否有數據

　　函數返回兩線串行接口緩沖區內數據的字節數

　　Wire.read()：讀取兩線串行接口輸入的數據

　　函數返回兩線串行接口輸入數據的一個字節

 

　　ATMega328P的兩線串行接口的主機模式由3個相關寄存器控制。兩線串行接口波特率寄存器TWBR的計算公式是：

其中，TWPS是預分頻系數，它由兩線串行接口狀態寄存器TWSR中的TWPS[1:0]位設置，寄存器的結構如下圖所示：

TWS7

TWS6

TWS5

TWS4

TWS3

TWPS1

TWPS0

　　兩線串行接口控制寄存器TWCR的結構如下圖所示：

TWINT

TWEA

TWSTA

TWSTO

TWWC

TWEN

TWIE

向TWI使能位TWEN寫入1則啟用兩線串行接口，寫入0則禁用；向起始信號使能位TWSTA或停止信號使能位TWSTO寫入1，則會產生起始信號或停止信號，停止條件產生后，TWSTO位會自動清零。

　　TWI中斷標志位被置1表示產生了相關事件的中斷，通過判斷TWSR寄存器高5位的值可以判斷中斷事件，如下表所示：

主機發送模式（TWPS[1:0] = 00）		主機接收模式（TWPS[1:0] = 00）
狀態碼	狀態	狀態碼	狀態
0x08	START已發送	0x08	SATRT已發送
0x10	重復START已發送	0x10	重復START已發送
0x18	SLA+W已發送，接收到ACK	0x38	SLA+R或NOT ACK仲裁失敗
0x20	SLA+W已發送，接收到NOT ACK	0x40	SLA+R已發送，接收到ACK
0x28	數據已發送，接收到ACK	0x48	SLA+R已發送，接收到NOT ACK
0x30	數據已發送，接收到NOT ACK	0x50	接收到數據，已產生ACK
0x38	SLA+W或數據的仲裁失敗	0x58	接收到數據，已產生NOT ACK

　　通過直接訪問寄存器改寫以上程序為：

// master_writer_reg.ino
#define READ        0x01
#define WRITE        0x00
void twi_write(byte address, byte val);

void setup() {
  TWSR &= ~(1 << TWPS1) & ~(1 << TWPS0);
  TWBR = 0x48;
}

byte x = 0;

void loop() {
  twi_write(8, x);

  x++;
  delay(500);
}

void twi_write(byte address, byte val) {
  // 發送開始
  TWCR = (1 << TWINT) | (1 << TWSTA) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x08) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 發送從機地址
  TWDR = (address << 1) | WRITE;
  TWCR = (1 << TWINT) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x18) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 發送數據
  TWDR = val;
  TWCR = (1 << TWINT) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x28) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 發送停止
  TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
}

// master_reader_reg.ino
#define READ        0x01
#define WRITE        0x00

byte data;
void twi_read(byte address);

void setup() {
  TWSR &= ~(1 << TWPS1) & ~(1 << TWPS0);
  TWBR = 0x48;

  Serial.begin(9600);
}

void loop() {
  twi_read(8);
  Serial.print(data);

  delay(500);
}

void twi_read(byte address) {
  // 發送開始
  TWCR = (1 << TWINT) | (1 << TWSTA) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x08) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 發送從機地址（偽寫）
  TWDR = (address << 1) | WRITE;
  TWCR = (1 << TWINT) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x18) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 發送重復開始
  TWCR = (1 << TWINT) | (1 << TWSTA) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x10) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 發送從機地址（讀）
  TWDR = (address << 1) | READ;
  TWCR = (1 << TWINT) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x40) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }

  // 讀取數據
  TWCR = (1 << TWINT) | (1 << TWEN);
  while (!(TWCR & (1 << TWINT)));
  if ((TWSR & 0xf8) != 0x58) {
    TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
    return;
  }
  data = TWDR;

  // 發送停止
  TWCR = (1 << TWINT) | (1 << TWEN) | (1 << TWSTO);
}