AVR開發 Arduino方法（三） 定時/計數器子系統

　　Arduino UNO R3的主處理器ATMega328P擁有3個定時/計數器，它們分別是Timer0，Timer1和Timer2；它們都通過對來自內部或外部的脈沖信號進行計數的方式完成基本的定時/計數功能以及一些其他的功能。

　　Timer0和Timer2是8位定時/計時器，Timer1是16位定時/計數器；下面以Timer2為例討論定時/計數器子系統的典型應用，這些內容同樣適用於Timer0和Timer1。

1. 精准延時

　　在前面的例子中，已經使用了一些與精准延時相關的Arduino庫函數：

 

　　delay(ms)：延遲一段時間

　　ms：延遲的時長，單位是毫秒

 

　　請注意，上面的Arduino庫函數使用了Timer0的中斷，因此不要在任何中斷服務程序中調用它，否則程序可能無法正常工作。

　　如果需要在延遲的同時，Arduino可以執行其他程序，這需要借助第三方庫MsTimer2；你可以在http://playground.arduino.cc/Main/MsTimer2下載到它，把下載到的MsTimer2.zip解壓到Arduino IDE安裝目錄下的libraries文件夾里就可以使用了，它包含了一個示例：

// FlashLed.ino
#include <MsTimer2.h>

void flash() {
  static boolean output = HIGH;
  
  digitalWrite(13, output);
  output = !output;
}

void setup() {
  pinMode(13, OUTPUT);

  MsTimer2::set(500, flash);
  MsTimer2::start();
}

void loop() {
}

 　　這個示例的效果與Blink示例基本相同，MsTimer2庫提供了3個庫函數：

 

　　MsTimer2::set(interval, function)：每隔一段時間執行指定函數

　　interval：間隔時長，單位是毫秒

　　function：指定執行函數的名稱

　　MsTimer2::start()：開始每隔一段時間執行指定函數

　　MsTimer2::stop()：結束每隔一段時間執行指定函數

 

　　Timer2有2個控制寄存器：TCCR2A和TCCR2B，它們的結構如下圖所示：

COM2A1

COM2A0

COM2B1

COM2B0

WGM21

WGM20

 

FOC2A

FOC2B

WGM22

CS22

CS21

CS20

其中WGM2[2:0]位用於設置模式，CS2[2:0]位用於設置時鍾源，如下表所示：

WGM2[2:0]	模式	計數上限		CS2[2:0]	時鍾源
000	正常	0xFF		000	無
001	相位校正脈寬調制	0xFF		001	系統時鍾
010	比較匹配時清零	OCR2A		010	系統時鍾8分頻
011	快速脈寬調制	0xFF		011	系統時鍾32分頻
100	（保留）			100	系統時鍾64分頻
101	相位校正脈寬調制	OCR2A		101	系統時鍾128分頻
110	（保留）			110	系統時鍾256分頻
111	快速脈寬調制	OCR2A		111	系統時鍾1024分頻

 其余位暫且設置為0。

　　精准延時可以采用正常模式。正常模式下，Timer2不斷從0x00計數到0xFF；當定時計數器寄存器TCNT2每一次返回0x00時，若Timer2的中斷屏蔽寄存器TIMSK2的溢出中斷使能位TOIE2為1，則產生中斷，它的結構如下圖所示：

OCIE0B

OCIE0A

TOIE0

 　　通過直接訪問寄存器改寫以上程序為：

// FlashLed_reg.ino
void flash() {
  PORTB ^= (1 << PB5);
}
void setup() {
  DDRB |= (1 << PB5);

  // 正常模式，系統時鍾256分頻，計數初值為6
  TCCR2A = 0x00;
  TCCR2B = 0x06;
  TCNT2 = 0x06;
  
  TIMSK2 |= (1 << TOIE2);
  sei();
}

void loop() {
}

ISR(TIMER2_OVF_vect) {
  static volatile int iTimes = 0;

  // 中斷125次為500毫秒
  if (++iTimes == 125) {
    flash();
    iTimes = 0;
  }
  // 重新賦初值6
  TCNT2 = 0x06;
}

　　程序中的“中斷125次為500毫秒”是這樣計算出來的：Arduino UNO R3開發板使用16MHz的系統時鍾，Timer2使用系統時鍾256分頻，每記256－6=250個脈沖溢出一次，則每秒溢出16000000÷256÷250=250次，因此每溢出125次為500毫秒。

2. 脈寬調制

　　脈寬調制的一個典型應用是控制直流電機速度。將直流電機兩極分別連接到直流電源的正負兩極上，電機會以最快速度運行；要調整電機速度，一個很容易想到的方法是調整直流電源的功率，但在數字系統中還有一個更簡單的方式：使用高低電平寬度不一樣的脈沖信號快速開關直流電機；因為慣性的作用，電機不會以最快的速度運行。一般來說，高電平在一個脈沖周期中所占寬度更寬時，直流電機速度越快；我們把高電平所占一個脈沖周期的寬度稱為占空比。

　　如圖所示連接電路，11（PB3/OC2A）引腳通過三極管間接控制直流電機：

　　用Arduino庫函數輸出一個脈寬調制信號十分簡單，下面的示例使得直流電機由慢到快，又由快到慢反復運行：

// FadingMotor.ino
int motor = 11;
int speed = 0;
int fadeAmount = 5;

void setup() {
  pinMode(motor, OUTPUT);
}

void loop() {
  analogWrite(motor, speed);

  speed = speed + fadeAmount;
  if (speed <= 0 || speed >= 255) {
    fadeAmount = -fadeAmount;
  }

  delay(30);
}

　　與脈寬調制相關的Arduino庫函數有：

 

　　analogWrite(pin, value)：在指定引腳上輸出一個指定占空比脈寬調制信號

　　pin：指定引腳

　　value：脈寬調制信號的占空比；0為0%，255為100%

 

　　Timer2擁有2個輸出比較寄存器OCR2A和OCR2B，它們通過與TCNT2寄存器發生比較匹配時對引腳置位、清零或取反來完成脈寬調制信號的輸出。TCCR2A寄存器中的COM2A[1:0]位用於設置OCR2A寄存器發生比較匹配時的行為，如下表所示：

COM2A[1:0]	行為
00	正常的端口操作，OC2A未連接
01	WGM22=0，正常的端口操作，OC2A未連接 WGM22=1，發生比較匹配時OC2A取反
10	發生比較匹配時OC2A清零，計數到下限時OC2A置位
11	發生比較匹配時OC2A置位，計數到下限時OC2A清零

　　通過直接訪問寄存器改寫以上程序為：

// FadingMotor_reg.ino
int speed = 0;
int fadeAmount = 5;

void setup() {
  DDRB |= (1 << PB3);

  // 快速脈寬調制，OC2A比較匹配置位，下限清零，系統時鍾
  TCCR2A = 0x83;
  TCCR2B = 0x01;
}

void loop() {
  OCR2A = speed;

  speed = speed + fadeAmount;
  if (speed <= 0 || speed >= 255) {
    fadeAmount = -fadeAmount;
  }

  delay(30);
}

3. 輸入捕獲*

　　輸入捕獲用來計算外部輸入信號的周期，它是Timer1的特有功能，Arduino官網提供了一個輸入捕獲的示例：

// PulseIn.ino
const int pin = 8;
unsigned long duration;

void setup() {
  pinMode(pin, INPUT);
}

void loop() {
  duration = pulseIn(pin, HIGH);
}

　　與輸入捕獲相關的Arduino庫函數有：

 

　　pulseIn(pin, value)：計算指定引腳輸入外部信號的周期

　　pin：指定引腳

　　value：捕獲脈沖的類型，LOW（低電平，0V）或HIGH（高電平，5V）

　　函數返回外部輸入信號的周期，是一個unsigned long類型的整數，單位為微秒

 

　　Timer1的控制寄存器與Timer2的不盡相同，請參閱ATMega328P芯片手冊16-bit Timer/Counter1 with PWM章的Register Description小節進行設置。通過直接訪問寄存器改寫以上程序為：

// PulseIn_reg.ino
unsigned long duration;
unsigned long timer1_pulse_in();

void setup() {
  DDRB &= ~(1 << PB0);
  PORTB &= ~(1 << PB0);

  // 正常模式，系統時鍾8分頻
  // 噪聲抑制關閉，下降沿觸發輸入捕獲
  TCCR1A = 0x00;
  TCCR1B = 0x42;
  TCCR1C = 0x00;
  TIMSK1 |= (1 << ICIE1) | (1 << TOIE1);
  sei();
}

void loop() {
  duration = timer1_pulse_in();
}

volatile int iOvf = 0;
volatile bool isCap = false;
volatile uint16_t iCap = 0;
volatile uint16_t iLastCap = 0;

unsigned long timer1_pulse_in() {
  unsigned long duration;

  while (!isCap);
  duration = 0xffff - iCap 
      + 0xffff * (iOvf - 1) 
      + iLastCap;

  isCap = false;
  return duration;
}

ISR(TIMER1_CAP_vect) {
  iCap = iLastCap;
  iLastCap = (ICR1H << 8) | ICR1L;
  
  isCap = true;
}

ISR(TIMER1_OVF_vect) {
  iOvf += 1;
}

　　事實上，本章僅僅討論了定時/計數器子系統的典型應用，這僅僅是定時/計數器子系統強大功能的冰山一角，由於篇幅關系沒有提及的部分，另請參閱ATMega328P芯片手冊。