FPGA產生可調頻率占空比的PWM

1.PWM產生原理

首先需要一個N比特的計數器，此計數器最大值為2^N，最小值為0。為了控制PWM的頻率，需要一個步進值“period”，為了控制占空比，需要一個閾值“duty”。

如下圖所示，計數器（cnt）在每個系統時鍾周期中增加“period”大小，當cnt < duty 時，輸出pwm_out為0，當cnt >= duty 時，輸出pwn_out 置1，調整period和duty的值即可控制PWM波形的頻率和占空比。

計算公式為  period =  2^N * (Tsysclk / Tpwm) = 2^N * (fpwm /fsysclk) , duty = 2N * (1 - DC).

式中Tsysclk、fsysclk為系統時鍾的周期、頻率，Tpwm、fpwm為產生的PWM的周期、頻率，DC為產生PWM的占空比（小於1的數，如30%）。位寬N越大，產生的PWM頻率越准確。

 

 2.Verilog代碼

module pwm
#(
    parameter N = 16 //pwm bit width 
)
(
    input         clk,
    input         rst,
    input[N - 1:0]period,    //pwm step value
    input[N - 1:0]duty,        //duty value
    
    output        pwm_out     //pwm output
    );
 
reg[N - 1:0] period_r;        //period register
reg[N - 1:0] duty_r;        //duty register
reg[N - 1:0] period_cnt;    //period counter
reg pwm_r;
assign pwm_out = pwm_r;
always@(posedge clk or posedge rst)
begin
    if(rst==1)
    begin
        period_r <= { N {1'b0} };
        duty_r <= { N {1'b0} };
    end
    else
    begin
        period_r <= period;
        duty_r   <= duty;
    end
end
//period counter, step is period value
always@(posedge clk or posedge rst)
begin
    if(rst==1)
        period_cnt <= { N {1'b0} };
    else
        period_cnt <= period_cnt + period_r;
end

always@(posedge clk or posedge rst)
begin
    if(rst==1)
    begin
        pwm_r <= 1'b0;
    end
    else
    begin
        if(period_cnt >= duty_r)    //if period counter is bigger or equals to duty value, then set pwm value to high
            pwm_r <= 1'b1;
        else
            pwm_r <= 1'b0;
    end
end

endmodule

3.仿真驗證

系統時鍾為50MHz，使用上述代碼產生頻率200Hz，占空比30%的 PWM，取N = 32，計算得period = 17197.87 = 17198，duty = 3006477107

仿真測試代碼

`timescale 1ns / 1ps
module pwm_tb();

parameter   N = 32; //計數器位寬
//reg define
reg         sys_clk  ;
reg         rst     ;
reg [N-1:0] period  ;
reg [N-1:0] duty    ;

//wire define
wire        pwm_out ;

//初始化輸入信號
initial begin
    sys_clk = 1'b1;
    rst     = 1'b1;
    period  = 32'd0;
    duty    = 32'd0;
    #10
    rst     = 1'b0;
    period  = 32'd17198;    //步進值
    duty    = 32'd3_006_477_107; //占空比閾值
end

//sys_clk:模擬系統時鍾，每10ns電平翻轉一次，周期為20ns，頻率為50Mhz
always #10 sys_clk = ~sys_clk;

//例化PWM模塊
pwm
#(
    .N  (N)  //pwm bit width 
)
pwm_inst
(
    .clk    (sys_clk    ),
    .rst    (rst    ),
    .period (period ),   //pwm step value
    .duty   (duty   ),     //duty value

    .pwm_out(pwm_out)   //pwm output
);

endmodule

結果如下圖，波形成功產生

 【參考資料】

1. ALINX 《ZYNQ那些事兒》