1.面板數據分類
（1）短面板（N>T）和長面板(N<T) （2）動態面板(解釋變量包含被解釋變量的滯后值）和靜態面板 （3）平衡面板（每個個體在相同的時間內都有觀測值）和非平衡面板
2.面板數據模型
（1）非觀測效應模型（存在不可觀測的個體效應模型）
-
固體效應模型（fixed effects model,fe）
-
隨機效應模型 (random effects model,re)
-
選擇fe還是re，用hausman檢驗。Help hausman查看用法，例如： . xtreg ln_wage age msp ttl_exp, fe . estimates store fixed . xtreg ln_wage age msp ttl_exp, re . hausman fixed ., sigmamore
（2）混合回歸模型（不存在不可觀測的個體效應模型） 
二、面板數據模型估計及標准誤的修正
1.面板數據模型的估計方法
（1）固定效應模型
-
固定效應變化（組內變換）
-
stata命令：xtreg y x ,fe
-
引入時間效應的雙向固定效應的stata命令：xi:xtreg y x i.year,fe 其中i.year直接生成了年份的虛擬變量，控制了時間效應。 另外，也可以通過 tab year,gen(year)這一命令生成年份的虛擬變量。
LSDV
-
將不可觀測的個體效應 αi看做待估計的參數， αi 就是第i個個體的截距
-
估計n個截距的方法就是引入n-1個虛擬變量（如果省略常數項，則引入n個虛擬變量）
-
如果不存在時間效應：xi:reg y x i.code 其中i.code直接生成了個體的虛擬變量
-
如果存在時間效應：xi:reg y x i.code i.year
（2）隨機效應模型估計
-
GLS
-
Stata命令：xtreg y x ,re
-
雙向控制，xi:xtreg y x i.year,re
三、短面板數據分析的基本程序
1.簡介
（1）以檢驗啤酒稅將降低交通死亡率的假說為例[美國48個州，1982-1988年的數據] （2）模型設定與數據 
（3）變量：
-
被解釋變量：fatal（交通死亡率）
-
核心解釋變量：beertax（啤酒稅）
-
可觀測的控制變量：spircons（酒精的消費量）、unrate（失業率）、perinck（人均收入）
-
μi：不可觀測的個體效應
-
γt：時間效應
2.基本流程
（一）模型設定與數據
1.查看數據： des 
2.查看面板數據特征： xtdes Xtdes給出面板數據的特征。本例中，判斷為短面板數據 
3.將數據設為面板數據格式： xtset state year xtset 個體變量 時間變量(告訴stata，這是面板數據），如本例中寫 xtset state year 
（二）描述性統計與作圖
1.描述性統計（sum+關鍵變量名）： sum fatal beertax spircons unrate perinck 
2.畫出關鍵變量與被解釋變量的散點圖和回歸直線： twoway (scatter fatal beertax) (lfit fatal beertax) 符號與理論上相反，可能的原因：沒有控制其他變量。 后面昨晚LSDV估計后，用avplot命令畫出二者的偏回歸圖（控制了其他變量。） 
3.生成年份虛擬變量： tab year, gen(year) 4.LSDV回歸： reg fatal beertax spircons unrate perinck year2-year7 i.state 
【3，4步驟可合並成：
reg fatal beertax spircons unrate perinck i.year i.state】
5.畫出關鍵變量與被解釋變量的偏回歸圖： avplot beertax 
6.畫出所有解釋變量與被解釋變量的偏回歸圖： avplots 
7.畫出關鍵變量的時間序列圖 ： xtline fatal 
8.畫出關鍵變量的時間序列圖： xtline beertax 
（三）模型的選擇
1.比較混合回歸模型和固定效應模型： xtreg fatal beertax spircons unrate perinck year2-year7,fe 
PLS or FE？ 2.tab year,gen(year) 3.在使用命令“xtreg,fe”時，如果不加選項cluster(state),則輸出結果還包含一個F檢驗，其原假設為“H0:all μi=0”，若拒絕原假設，則選擇固定效應模型。
2.安裝xtcsd命令： ssc install xtcsd 
3.檢驗截面相關問題：
-
xtcsd,pes xtcsd,fri xtcsd,fre
xtcsd命令只有在運行完fe或re回歸后，才能使用
4.安裝命令： ssc install xtscc 
5.（存在截面相關問題時）處理了誤差項截面相關問題的LSDV估計： xi:xtscc fatal beertax spircons unrate perinck year2-year7 i.state 
6.（存在截面相關問題時）對州虛擬變量做F檢驗： testparm _Istate* 
7.（不存在截面相關問題時）使用聚類到州獲得的標准誤處理自相關和異方差問題： xi:reg fatal beertax spircons unrate perinck year2-year7 i.state, cluster(state) 
8.（不存在截面相關問題時）對州虛擬變量做F檢驗： testparm _Istate* 
（四）比較固定效應模型fe和隨機效應模型re
1.（Husman檢驗）固定效應估計： xtreg fatal beertax spircons unrate perinck year2-year7, fe 
2.（Husman檢驗）存儲固定效應估計的結果： est store FE 3.（Husman檢驗）隨機效應估計： xtreg fatal beertax spircons unrate perinck year2-year7, re 
4.（Husman檢驗）將兩個估計結果進行比較(hausman 檢驗，如果P值小於0.05，則表示拒絕原假設。用fe更合適： hausman FE ., sigmamore 
-
hausman FE ., sigmaless
3.報告計量結果
-
由於之前的hausman 檢驗選擇了fe模型，所以要報告固定效應模型的估計結果，同時要解決誤差項可能存在的自相關、異方差和截面相關問題。
-
前面xtcsd檢驗表明存在截面相關。
（一）假設選擇固定效應模型 1.固定效應模型估計： xtreg fatal beertax spircons unrate perinck year2-year7, fe 
2.檢驗截面相關問題 xtcsd,pes abs xtcsd,fri abs xtcsd,fre abs 
（二）如果不存在截面相關，檢驗是否存在異方差 1.安裝xttest3： ssc install xttest3 
-
xtreg fatal beertax spircons unrate perinck year2-year7, fe
-
xttest3
（三）自相關檢驗 1.安裝xtserial： search xtserial
2.生成州虛擬變量： tab state,gen(state)
3.完成自相關檢驗： xtserial fatal beertax spircons unrate perinck state2-state48 year2-year7
（四）最終報告由如下命令估計的結果 這里給出不同解釋變量組合，進行回歸后的結果保存：
xtreg fatal beertax spircons unrate perinck year2-year7, fe robust
est store result1
xtreg fatal beertax unrate perinck year2-year7, fe robust
est store result2
xtreg fatal beertax spircons perinck year2-year7, fe robust
est store result3
（五）結果匯報 1.安裝estout命令，esttab是estout的一個命令： ssc install estout 
2.結果報告(括號內是t統計量值）： esttab result1 result2 result3 ,se ar2 
3.把結果保存到word中(括號內是穩健標准誤）： esttab result1 result2 result3 using tab.rtf ,se ar2 4.把結果保存到excel中(括號內是穩健標准誤）： esttab result1 result2 result3 using tab.csv ,se ar2 
（六）補充
假設選擇隨機效應模型
xtreg fatal beertax spircons unrate perinck year2-year7, re cluster(state)//對自相關和異方差穩健的隨機效應模型估計
xtscc redfatal redbeertax redspircons redunrate redperinck redyear2 redyear3 redyear4 redyear5 redyear6 redyear7//xtscc可以同時解決三大問題
完整do命令：
use "D:\administrator\Desktop\互聯網金融\第一講數據及do文件\traffic-original.dta", clear
des
xtdes
xtset state year
sum fatal beertax spircons unrate perinck
twoway (scatter fatal beertax) (lfit fatal beertax)
graph save Graph "D:\administrator\Desktop\Graph.gph"
twoway (scatter fatal beertax) (lfit fatal beertax)
tab year, gen(year)
reg fatal beertax spircons unrate perinck year2-year7 i.state
avplot beertax
avplots
xtline fatal
xtline beertax
xtreg fatal beertax spircons unrate perinck year2-year7,fe
ssc install xtcsd
xtcsd,pes
xtcsd,fri
xtcsd,fre
ssc install xtscc
xi:xtscc fatal beertax spircons unrate perinck year2-year7 i.state
testparm _Istate*
xi:reg fatal beertax spircons unrate perinck year2-year7 i.state, cluster(state)
testparm _Istate*
xtreg fatal beertax spircons unrate perinck year2-year7, fe
est store FE
xtreg fatal beertax spircons unrate perinck year2-year7, re
hausman FE ., sigmamore
hausman FE ., sigmaless
ssc install xttest3
xtreg fatal beertax spircons unrate perinck year2-year7, fe
xtcsd,pes abs
xtcsd,fri abs
xtcsd,fre abs
xttest3
search xtserial
tab state,gen(state)
xtserial fatal beertax spircons unrate perinck state2-state48 year2-year7
xtreg fatal beertax spircons unrate perinck year2-year7, fe robust
est store result1
xtreg fatal beertax unrate perinck year2-year7, fe robust
est store result2
xtreg fatal beertax spircons perinck year2-year7, fe robust
est store result3
ssc install estout
esttab result1 result2 result3 ,se ar2
esttab result1 result2 result3 using tab.rtf ,se ar2
esttab result1 result2 result3 using tab.csv ,se ar2
xtreg fatal beertax spircons unrate perinck year2-year7, re cluster(state)
—————————————— 寫在最后，這是作者對上課內容的整理筆記，點個↓
