Unity shader 護盾shield的簡單實現

先上效果圖

shader所用的貼圖資源

擾動

直接對uv進行變換就可以了，記得首先把六邊形格子地圖的Tilling調高點 先預先調成合適大小的六邊形，然后repeat鋪滿整個護盾

// Tiles and offsets the value of input UV by the inputs Tiling and Offset respectively.
// This is commonly used for detail maps and scrolling textures over Time.
void Unity_TilingAndOffset_float(float2 UV, float2 Tiling, float2 Offset, out float2 Out)
{
    Out = UV * Tiling + Offset;
}

直接在vertex着色器中對appdata傳進來的uv進行變動，兩者 offset的變動頻率不同

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                half2 uv = TRANSFORM_TEX(v.uv, _MainTex);
                Unity_TilingAndOffset_float(uv, half2(1, 1), half2(0, -_Time.y), o.uv);
                Unity_TilingAndOffset_float(uv, half2(1, 1), half2(0, -_Time.y * 2), o.uvGlow);
                
                float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz; 
		
                o.worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));
		o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

護盾邊緣光

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float2 uvGlow : TEXCOORD1;
                float4 vertex : SV_POSITION;
		half3 worldNormal : TEXCOORD2;
                half3 worldViewDir : TEXCOORD3;
            };

vertex着色器

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
		...                
                float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz; 
		
                o.worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));
		o.worldNormal = UnityObjectToWorldNormal(v.normal);
                ...
                    
                return o;
            }

fragment着色器

先獲取世界坐標系下的法線向量和世界坐標系下攝像機到頂點的向量，1-點乘得到的值然后結合到最后的顏色輸出計算中，法線向量與攝像機到頂點的向量的所成夾角可視為從中心點向邊緣擴散，角度越來越大，到邊緣區角度呈局部最大值

            half4 frag (v2f i) : SV_Target
            {
		...
                half rim = pow(1 - abs(dot(normalize(i.worldNormal), normalize(i.worldViewDir))), _RimNum);

                // 邊緣高光
                col = lerp(col, _LightColor, rim);
                ...

                return col;
            }

全部代碼

Shader "Unlit/ShieldForceField"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        [NoScaleOffset] _LightTex ("LightTex", 2D) = "white" {}
        _Hologram ("Hologram", 2D) = "white" {}
        [HDR] _LightColor ("LightColor", Color) = (1, 1, 1, 1)
        // 邊緣光幅度
        _RimNum("Rim" , Range(0 , 5)) = 1
    }
    SubShader
    {
        Tags
        {
            "RenderType" = "Transparent"
            "Queue" = "Transparent"
            "IgnoreProjector" = "True"
            "ForceNoShadowCasting" = "True"
        }
        Cull Off
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "../../../../../Assets/ShaderGraphic.cginc"
			
	    sampler2D _MainTex, _LightTex, _Hologram;
            float4 _MainTex_ST;
            half4 _LightColor;
            
            float _RimNum;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float2 uvGlow : TEXCOORD1;
                float4 vertex : SV_POSITION;
		half3 worldNormal : TEXCOORD2;
                half3 worldViewDir : TEXCOORD3;
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                half2 uv = TRANSFORM_TEX(v.uv, _MainTex);
                Unity_TilingAndOffset_float(uv, half2(1, 1), half2(0, -_Time.y), o.uv);
                Unity_TilingAndOffset_float(uv, half2(1, 1), half2(0, -_Time.y * 2), o.uvGlow);
                
                float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz; 
		
                o.worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));
		o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            half4 frag (v2f i) : SV_Target
            {
                half4 col = tex2D(_MainTex, i.uv);
                half4 light = tex2D(_LightTex, i.uv);

                // light.rgb = light.r * _LightColor.rgb;
                light.rgb = _LightColor.rgb;
                col.rgb += light.rgb * _LightColor.a;

                half4 holoColor = tex2D(_Hologram, i.uvGlow);
                col += holoColor * 0.3;

                col.a = 0.5;

                half rim = pow(1 - abs(dot(normalize(i.worldNormal), normalize(i.worldViewDir))), _RimNum);

                // 邊緣高光
                col = lerp(col, _LightColor, rim);

                return col;
            }
            ENDCG
        }
    }
}

最后大功告成了，后續可能會繼續改進一下（加上相交時會留下邊緣光）