Unity Shader 法線貼圖的實現

這里有一個細節，關於法線貼圖是有兩個不同的空間的，如下：

　　切線空間：法線貼圖顏色為偏藍色

　　模型空間：法線貼圖顏色為五顏六色

因此根據不同的空間變換位置方便一致計算。

// 法線貼圖映射的編寫+透明
Shader "TMoon/05-NormalMapAndAlpha" {
    Properties{
        _Color("Color",Color) = (1,1,1,1)
        _MainTex("Main Tex",2D) = "white"{}
        _NormalMap("Normal Map",2D) = "bump"{} //bump默認值的意思：若沒有法線貼圖，則使用頂點自帶的
        _BumpScale("Bump Scale",Float) = 1
        _AlphaScale("Alpha Scale",Float) = 1
    }

    SubShader{

        Tags{ "Queue" = "Transparent" "IngnoreProjector" = "True" "RenderType" = "Transparent" }
        
        Pass{
        
            Tags {"LightMode" = "ForwardBase"}

            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM

            #include "Lighting.cginc"

            #pragma vertex vert
            #pragma fragment frag

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _NormalMap;
            float4 _NormalMap_ST;
            float _BumpScale;
            float _AlphaScale;

            // application to vertex
            // 由應用程序傳遞給頂點函數
            struct a2v {
                float4 vertex:POSITION;
                float3 normal:NORMAL; // 切線空間的確定是通過(存儲模型里的)法線和(存儲模型里的)切線確定的，所以需要模型的法線
                float4 texcoord:TEXCOORD0; // 模型的紋理坐標
                float4 tangent:TANGENT;// 模型空間的切線
            };

            // vertex to fragment
            // 由頂點函數傳遞給片元函數
            struct v2f {
                float4 svPos:SV_POSITION;
                float4 uv:TEXCOORD0; // uv.xy 存儲MainTex的紋理坐標,uv.zw 存儲法線貼圖的紋理坐標
                float3 lightDir : TEXCOORD1; // 切線空間下平行光的方向
            };

            v2f vert(a2v v) {
                v2f f;

                f.svPos = mul(UNITY_MATRIX_MVP, v.vertex);

                // 將MainTex紋理坐標賦值給v2f.uv.xy並賦值面板貼圖的旋轉縮放
                f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                // 將法線貼圖紋理坐標賦值給v2f.uv.zw並賦值面板貼圖的旋轉縮放
                f.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw;

                // 調用這個宏之后，會得到一個矩陣 rotation
                // 這個矩陣用來把模型空間下的方向轉換成切線空間下
                TANGENT_SPACE_ROTATION;

                //ObjSpaceLightDir(v.vertex) 得到模型空間下的平行光方向
                f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex));
                    
                return f;
            }

            float4 frag(v2f f) : SV_Target{

                // tex2D 根據法線貼圖的紋理坐標獲取顏色值
                fixed4 normalColor = tex2D(_NormalMap,f.uv.zw);

                // 切線空間下的法線
                fixed3 tangentNormal = UnpackNormal(normalColor);
                tangentNormal.xy = tangentNormal.xy * _BumpScale;
                tangentNormal = normalize(tangentNormal);

                fixed3 lightDir = normalize(f.lightDir);

                // tex2D 根據MainTex貼圖的紋理坐標獲取顏色值
                fixed3 texColor = tex2D(_MainTex,f.uv.xy) * _Color.rgb;

                // 為漫反射混合上每個像素點的紋理顏色
                fixed3 diffuse = _LightColor0.rgb * texColor * max(dot(tangentNormal, lightDir), 0);

                return fixed4(diffuse, _AlphaScale);
            }

            ENDCG
        }
    }

    Fallback "VertexLit"
}