使用idea的groovy腳本自動創建MybatisPlus的實體

1. 選中數據庫的表；
2. 右擊選擇Scripted Extension中的Go to scripts diretory；
3. 新建一個文件，名稱為：MybatisPlusGenerate POJOs.groovy；
4. 復制粘貼如下內容；
5. 選中數據庫中需要新建entity的表；
6. 右擊選中Scripted Extension中的MybatisPlusGenerate POJOs.groovy執行；
7. 在指定目錄下生成駝峰命名的實體對象；
8. 需要修改生成內容的，可以看看腳本內容，進行修改。

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDate

/*
 * Available context bindings:
 * SELECTION Iterable<DasObject>
 * PROJECT  project
 * FILES  files helper
 */

// 此處指定包路徑，路徑需要自行維護;
packageName = "com.cyneck.web.entity;"

// 此處指定對應的類型映射，可按需修改，目前tinyint如果要映射到自定義枚舉類型，只能手動修改
typeMapping = [
        (~/(?i)bigint/)                         : "Long",
        (~/(?i)smallint|mediumint|tinyint|int/) : "Integer",
        (~/(?i)bool|bit/)                       : "Boolean",
        (~/(?i)float|double|decimal|real/)      : "BigDecimal",
        (~/(?i)time|datetime|timestamp/)        : "LocalDateTime",
        (~/(?i)date/)                           : "LocalDate",
        (~/(?i)blob|mediumblob|binary|bfile|clob|raw|image/): "Byte[]",
        (~/(?i)text|mediumtext/)                : "String",
        (~/(?i)/)                               : "String"
]

// 上面用到類和它的導入路徑的之間的映射
importMap = [
        "BigDecimal" : "java.math.BigDecimal",
        "LocalDate" : "java.time.LocalDate",
        "LocalDateTime": "java.time.LocalDateTime",
]

// 導入路徑列表，下面引用的時候會去重，也可以直接聲明成一個 HashSet
importList = []

// 彈出選擇文件的對話框
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "Entity"
    def fields = calcFields(table)
    new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8")).withPrintWriter { out -> generate(out, className, fields, table) }
}

// 從這里開始，拼實體類的具體邏輯代碼
def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    // 引入所需的包
    out.println "import lombok.Data;"
    out.println "import lombok.EqualsAndHashCode;"
    out.println "import lombok.experimental.Accessors;"
    out.println "import com.baomidou.mybatisplus.annotation.*;"
    out.println "import java.io.Serializable;"
    // 去重后導入列表
    importList.unique().each() { pkg ->
        out.println "import " + pkg + ";"
    }
    out.println ""
    // 添加類注釋
    out.println "/**"
    // 如果添加了表注釋，會加到類注釋上
    if (isNotEmpty(table.getComment())) {
        out.println " * " + table.getComment()
    }
    out.println " *"
    out.println " * @author Eric.Lee"
    out.println " * @since " + LocalDate.now()
    out.println " */"
    // 添加類注解
    out.println "@Data"
    out.println "@EqualsAndHashCode(callSuper = false)"
    out.println "@Accessors(chain = true)"
    out.println "@TableName(\"${table.getName()}\")"
    out.println "public class $className implements Serializable {"
    out.println ""
    out.println genSerialID()
    boolean isId = true
    // 遍歷字段，按下面的規則生成
    fields.each() {
        // 輸出注釋
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        // 這邊默認第一個字段為主鍵，實際情況大多數如此，遇到特殊情況可能需要手動修改
        if (isId) {
            out.println "\t@TableId(type = IdType.AUTO)"
            isId = false
        }
        if ((it.annos + "").indexOf("[@Id]") >= 0) out.println "\t@Id"

        if (it.annos != "") out.println " ${it.annos.replace("[@Id]", "")}"

        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        if (importMap.containsKey(typeStr)) {
            importList.add(importMap.get(typeStr))
        }
        fields += [[
                           name : javaName(col.getName(), false),
                           type : typeStr,
                           comment: col.getComment(),
                           annos : "\t@TableField(\"" + col.getName() + "\")"
                   ]]
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

static String genSerialID() {
    return "\tprivate static final long serialVersionUID = " + Math.abs(new Random().nextLong()) + "L;"
}