導語: 如今已2019年, 有許許多多的插件或者編輯器都支持根據數據表自動生成數據實體類了, 比如IDEA, 各種MyBatis的代碼生成工具, 等等. 本篇介紹一下如何使用IDEA的groovy腳本文件生成帶JPA注解的實體類
一, 使用IDEA連接數據庫
- 需注意:
- 正式版IDEA才有此功能, 社區版木有
- 演示圖片使用的IDEA版本為2018.3, 不同版本界面可能有細小差別
- 創建新的數據連接
- (1)如果沒有, 可以上方菜單欄: 視圖-工具窗口-Database打開
- 新建Oracle數據庫也是相同操作
- 配置數據連接
- 填寫一個連接名，隨便填什么都行
- 不用選擇，默認就行
- 填寫數據庫連接的 IP地址，比如本地數據庫可以填寫：localhost或者127.0.0.1
- 填寫數據庫開放的端口號，一般沒設置的話默認都是3306
- 填寫你需要連接的數據庫名
- 填寫數據庫的用戶名
- 填寫數據庫密碼
- 這里會有一個驅動需要點擊下載，圖中是已經下載好了
- 填寫自己的數據庫連接url，然后可以點擊9所在按鈕進行測試連接，本地連接失敗檢查是否開啟了mysql服務
二, IDEA自帶的兩種創建實體類的方法
(1)如果只是創建簡單的, 只有屬性, getter, setter的實體類, 而不需要JPA/Hibernate的實體類注解
1. 單擊打開剛剛創建的數據連接
2. 打開schemas, 找到自己需要創建實體類的表(可以使用ctrl或shift多選)
3. 右鍵: Scripted Extensions - Generate POJOs.groovy
4. 選擇生成路徑就OK了
+ **需注意**
+ 生成的包名可能有問題, 默認是`package com.sample`, 需要自己手動修改
(2)使用了Hibernate/Jpa框架, 需要的是有注解的實體類, Idea也提供了相應的方法
- -1-添加JPA模塊
- 打開項目結構
- 打開模塊, 點擊+號添加模塊
- 選擇JPA
- 點擊右下角確定后, 關閉項目結構
-
-2-使用Persistence工具生成帶注解的實體類-1
- 如果上一步沒問題的話, IDEA左下角側邊欄會出現Persistence工具欄
- 打開Persistence工具欄, 右鍵項目: Generate Persistence Mapping - By Database Schema
-
-3-使用Persistence工具生成帶注解的實體類-2
- 選擇數據庫連接
- 選擇生成類所在包
- 選擇要生成的表
- 選擇要生成的字段(選擇表后字段默認除了外鍵全選)
- 修改要生成的屬性名
- 修改要生成的屬性類型
- 勾上即為生成帶注解的實體類
生成的類實例如下
三, 更進一步, 使用自己的Groovy生成帶注解的實體類
- 上面介紹了兩個使用IDEA生成實體類的方法, 各有優缺點
+生成不帶注解的實體類簡單高效, 但缺點就是如果使用的是Jpa/Hibernate框架就不適合
+生成帶注解的實體類能生成注解實體類, 但缺點就是生成的實體類的注解可能不太符合我們的注解, 只能生成到當前項目包下, 面對一些復雜的數據庫如Oracle會顯示很多系統表而且表空間切換不太方便- 我們知道Idea生成不帶注解的實體類是通過Groovy腳本文件生成的, 我們也能找到這個文件, 那我們能不能修改這個文件, 讓它生成帶注解的實體類呢?
(1)使用自己的Groovy生成帶注解的實體類的好處
- 在Database工具欄里, 操作簡單方便
- 可以自己對腳本進行一些編輯, 使生成的實體類達到自己的定制需求
- 對Oracle這樣的數據庫生成實體類時, 避免了系統表的影響, 可以自己選擇表空間進行操作
- 可以生成在電腦上的任何位置, 不受限制
(2)使用自己的Groovy生成帶注解的實體類的不足
- @author 作者名需要自己修改腳本
- @Table(Schema="") 的表空間名不能讀取, 需要自己修改腳本, 設定表空間名(mysql可以直接刪除這個屬性的定義)(IDEA的Persistence工具可以讀取(Schema=""屬性並生成, 但我們不知道它是怎么獲取的)
- @Id的主鍵生成方式不可知, 需要生成后自己確定(mysql用戶可以直接修改腳本設定主鍵生成方式, 但Oracle用戶需要生成實體類后再逐個確認)
(3)使用自己的Groovy生成帶注解的實體類可以繼續完善的地方
1, 如果需要hashcode()和equals()方法, 也修改腳本, 使其自動生成
(4)新建一個Groovy腳本文件
- Database工具欄里, 右鍵右鍵: Scripted Extensions - Go to Scripts Directory
- 在目錄下新建一個Generate MyPOJOs.groovy
- 添加里面的內容
//1. 修改idea為自己名字的地方可以修改作者名字為自己的//2. schema = \"后面添加自己的表空間名稱(mysql可以不添加, 不用這個schema屬性也行)這里可以根據提示修改
import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.text.SimpleDateFormat
/*
* Available context bindings:
* SELECTION Iterable<DasObject>
* PROJECT project
* FILES files helper
*/
packageName = ""
typeMapping = [
(~/(?i)tinyint|smallint|mediumint/) : "Integer",
(~/(?i)int/) : "Long",
(~/(?i)bool|bit/) : "Boolean",
(~/(?i)float|double|decimal|real/) : "Double",
(~/(?i)datetime|timestamp|date|time/) : "Date",
(~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
(~/(?i)/) : "String"
]
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}
def generate(table, dir) {
def className = javaName(table.getName(), true)
def fields = calcFields(table)
packageName = getPackageName(dir)
PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
printWriter.withPrintWriter { out -> generate(out, className, fields, table) }
// new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}
// 獲取包所在文件夾路徑
def getPackageName(dir) {
return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}
def generate(out, className, fields, table) {
out.println "package $packageName"
out.println ""
out.println "import javax.persistence.Column;"
out.println "import javax.persistence.Entity;"
out.println "import javax.persistence.Table;"
out.println "import javax.persistence.Id;"
out.println "import javax.persistence.GeneratedValue;"
out.println "import java.io.Serializable;"
Set types = new HashSet()
fields.each() {
types.add(it.type)
}
if (types.contains("Date")) {
out.println "import java.util.Date;"
}
if (types.contains("InputStream")) {
out.println "import java.io.InputStream;"
}
out.println ""
out.println "/**\n" +
" * @Description \n" +
" * @Author idea\n" + //1. 修改idea為自己名字
" * @Date " + new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
" */"
out.println ""
out.println "@Entity"
out.println "@Table ( name =\"" + table.getName() + "\" , schema = \"\")" //2. schema = \"后面添加自己的表空間名稱(mysql可以不添加, 不用這個schema屬性也行)
out.println "public class $className implements Serializable {"
out.println ""
out.println genSerialID()
fields.each() {
out.println ""
// 輸出注釋
if (isNotEmpty(it.commoent)) {
out.println "\t/**"
out.println "\t * ${it.commoent.toString()}"
out.println "\t */"
}
if ((it.annos+"").indexOf("[@Id]") >= 0) out.println "\t@Id"
if (it.annos != "") out.println " ${it.annos.replace("[@Id]", "")}"
// 輸出成員變量
out.println "\tprivate ${it.type} ${it.name};"
}
// 輸出get/set方法
fields.each() {
out.println ""
out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
out.println "\t\treturn this.${it.name};"
out.println "\t}"
out.println ""
out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
out.println "\t\tthis.${it.name} = ${it.name};"
out.println "\t}"
}
// 輸出toString方法
out.println ""
out.println "\t@Override"
out.println "\tpublic String toString() {"
out.println "\t\treturn \"TpApiConfig{\" +"
fields.each() {
out.println "\t\t\t\t\"${it.name}='\" + ${it.name} + '\\'' +"
}
out.println "\t\t\t\t'}';"
out.println "\t}"
out.println ""
out.println "}"
}
def calcFields(table) {
DasUtil.getColumns(table).reduce([]) { fields, col ->
def spec = Case.LOWER.apply(col.getDataType().getSpecification())
def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
def comm = [
colName : col.getName(),
name : javaName(col.getName(), false),
type : typeStr,
commoent: col.getComment(),
annos : "\t@Column(name = \"" + col.getName() + "\" )"]
if ("id".equals(Case.LOWER.apply(col.getName())))
comm.annos += ["@Id"]
fields += [comm]
}
}
// 已經修改為使用javaName, 如果有需要可以在def className = javaName(table.getName(), true)中修改為javaClassName
// 處理類名（這里是因為我的表都是以t_命名的，所以需要處理去掉生成類名時的開頭的T，
// 如果你不需要那么請查找用到了 javaClassName這個方法的地方修改為 javaName 即可）
def javaClassName(str, capitalize) {
def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
.collect { Case.LOWER.apply(it).capitalize() }
.join("")
.replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
// 去除開頭的T http://developer.51cto.com/art/200906/129168.htm
s = s[1..s.size() - 1]
capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
def javaName(str, capitalize) {
// def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
// .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
// capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
.collect { Case.LOWER.apply(it).capitalize() }
.join("")
.replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
def isNotEmpty(content) {
return content != null && content.toString().trim().length() > 0
}
static String changeStyle(String str, boolean toCamel) {
if (!str || str.size() <= 1)
return str
if (toCamel) {
String r = str.toLowerCase().split('_').collect { cc -> Case.LOWER.apply(cc).capitalize() }.join('')
return r[0].toLowerCase() + r[1..-1]
} else {
str = str[0].toLowerCase() + str[1..-1]
return str.collect { cc -> ((char) cc).isUpperCase() ? '_' + cc.toLowerCase() : cc }.join('')
}
}
static String genSerialID() {
return "\tprivate static final long serialVersionUID = " + Math.abs(new Random().nextLong()) + "L;"
}
- 表上右鍵, 選擇自己寫的腳本生成實體類
效果如下:
