FPGA實現圖像的二值形態學濾波：邊界提取

　　輪廓是對物體形狀的有力描述，對圖像分析和識別十分有用。通過邊界提取算法可以得到物體的邊界輪廓。

　　二值圖像的邊界提取主要基於黑白區域的邊界查找，和許多邊界查找算法相比它適合於二值圖像。

　　邊界提取的算法比較簡單，以黑色 0 作為背景，白色 1 作為提取。以 3x3 模板為例，9 個像素都為 0 或 1 時輸出為 0，否則為 1 。如圖所示：

 

一、FPGA實現

　　算法比較簡單，直接上代碼吧。

module Boundary
//========================< 端口 >==========================================
(
input   wire                clk                     ,
input   wire                rst_n                   ,
//input ---------------------------------------------
input   wire                RGB_de                  ,
input   wire                RGB_hsync               ,
input   wire                RGB_vsync               ,
input   wire    [15:0]      RGB_data                ,
//output --------------------------------------------
output  wire                boundary_de             ,
output  wire                boundary_hsync          ,
output  wire                boundary_vsync          ,
output  reg     [15:0]      boundary_data
);
//========================< 信號 >==========================================
//matrix_3x3 ----------------------------------------
wire    [15:0]              matrix_11               ;
wire    [15:0]              matrix_12               ;
wire    [15:0]              matrix_13               ;
wire    [15:0]              matrix_21               ;
wire    [15:0]              matrix_22               ;
wire    [15:0]              matrix_23               ;
wire    [15:0]              matrix_31               ;
wire    [15:0]              matrix_32               ;
wire    [15:0]              matrix_33               ;
//同步 ----------------------------------------------
reg     [ 1:0]              RGB_de_r                ;
reg     [ 1:0]              RGB_hsync_r             ;
reg     [ 1:0]              RGB_vsync_r             ;
//==========================================================================
//==    matrix_3x3，生成3x3矩陣，輸入和使能需對齊，耗費1clk
//==========================================================================
//--------------------------------------------------- 矩陣順序
//        {matrix_11, matrix_12, matrix_13}
//        {matrix_21, matrix_22, matrix_23}
//        {matrix_31, matrix_32, matrix_33}
//--------------------------------------------------- 模塊例化
matrix_3x3_16bit
#(
    .COL                    (480                    ),
    .ROW                    (272                    )
)
u_matrix_3x3_16bit
(
    .clk                    (clk                    ),
    .rst_n                  (rst_n                  ),
    .din_vld                (RGB_de                 ),
    .din                    (RGB_data               ),
    .matrix_11              (matrix_11              ),
    .matrix_12              (matrix_12              ),
    .matrix_13              (matrix_13              ),
    .matrix_21              (matrix_21              ),
    .matrix_22              (matrix_22              ),
    .matrix_23              (matrix_23              ),
    .matrix_31              (matrix_31              ),
    .matrix_32              (matrix_32              ),
    .matrix_33              (matrix_33              )
);
//==========================================================================
//==    邊緣提取，耗費1clk
//==========================================================================
always @ (posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        boundary_data <= 16'h0000;
    end
    else if((matrix_11 == 16'h0000) && (matrix_12 == 16'h0000) && (matrix_13 == 16'h0000) &&
            (matrix_21 == 16'h0000) && (matrix_22 == 16'h0000) && (matrix_23 == 16'h0000) &&
            (matrix_31 == 16'h0000) && (matrix_32 == 16'h0000) && (matrix_33 == 16'h0000)
            ) begin
                            boundary_data <= 16'hffff;
    end
    else if((matrix_11 == 16'hffff) && (matrix_12 == 16'hffff) && (matrix_13 == 16'hffff) &&
            (matrix_21 == 16'hffff) && (matrix_22 == 16'hffff) && (matrix_23 == 16'hffff) &&
            (matrix_31 == 16'hffff) && (matrix_32 == 16'hffff) && (matrix_33 == 16'hffff)
            ) begin
                            boundary_data <= 16'hffff;
    end
    else begin
        boundary_data <= 16'h0000;
    end
end
//==========================================================================
//==    信號同步
//==========================================================================
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        RGB_de_r    <= 2'b0;
        RGB_hsync_r <= 2'b0;
        RGB_vsync_r <= 2'b0;
    end
    else begin  
        RGB_de_r    <= {RGB_de_r[0],    RGB_de};
        RGB_hsync_r <= {RGB_hsync_r[0], RGB_hsync};
        RGB_vsync_r <= {RGB_vsync_r[0], RGB_vsync};
    end
end

assign boundary_de    = RGB_de_r[1];
assign boundary_hsync = RGB_hsync_r[1];
assign boundary_vsync = RGB_vsync_r[1];
    


endmodule

 

二、上板驗證

 　　輸入找了張二值圖片，如果沒有二值圖片，可以在邊界提取前自己寫一下閾值判斷即可。

　　二值原圖：

　　邊界提取后：

　　由實驗結果可知，邊界提取成功，外部的白色和內部的黑色都變為了白色，只有邊界處是黑色。

 

參考資料：[1] Opens Lee：FPGA開源工作室（公眾號）