Unity3D手游開發日記(1) - 移動平台實時陰影方案

陰影這個東西,說來就話長了,很多年前人們就開始研究出各種陰影技術,但都存在各種瑕疵和問題,直到近幾年出現了PSSM,也就是CE3的CSM,陰影技術才算有個比較完美的解決方案.Unity自帶的實時陰影,也是這種技術,在電腦上很成熟的.我也是目睹了陰影技術的發展,以前也自己寫過一些陰影,本來以為以后再也不用擔心陰影了,結果做移動游戲以后,發現情況沒那么樂觀.這種基於深度的shadow map 技術,需要浮點紋理的支持,但有的移動平台不支持浮點紋理,即使支持,這種技術開銷也特別大.所以我們需要重新思考,移動平台到底什么樣的陰影方案比較合適.

我把常見的實時陰影技術分3個大的類別,逐一分析.

1. 基於模板的體積陰影

基於模型邊緣的,模型需要特別處理,正是由於基於模型邊緣的,屬於頂點級別,而不是像素級別,導致不能支持alpha test,比如主角的翅膀.放棄

2. 基於投影Projector的shadow map

基於投影的,投影紋理,需要RenderTexture,支持alpha test,

但是這種技術也有很多問題,比如反向投影(可加一張fall of 紋理解決), 多重投影(比如橋上和橋下),等等

陰影質量和RenderTexture紋理大小關閉很大,如果要一張RenderTexture紋理渲染很多角色,紋理就要大一些,要處理陰影邊緣,

但是用來處理單個角色,就能避免很多問題.可考慮.

3. 基於深度Depth的shadow map

Unity自帶的就是這種,保存深度需要浮點紋理,但是有的手機不支持,且開銷很大,不考慮.

 

通過以上分析,再結合自己游戲的實際情況,45度視角游戲,我最后定的方案是:

 

中等畫質:

 

1.只有主角采用基於投影Projector的shadow map

2.其他角色,采用最簡單的陰影面片綁在腳下.(如果怪物被擊浮空,就隱藏面片,落地再顯示,防止穿幫)

這樣的好處是,既有實時陰影,又保證了效率.

 

高畫質:

1.視野內全部角色基於投影Projector的shadow map

 

實現原理:

很簡單,先渲染角色到RenderTexture,再用Projector投影到地面.

 

1.投射shader:

 

Shader "Luoyinan/Projector/ShadowCast"
{
    Properties
    {
        _ShadowColor ("Main Color", COLOR) = (0.5, 0.5, 0.5, 1)
    }

    SubShader
    {
        Pass
        {
            Color [_ShadowColor]
        }
    }
}

 

2.接收shader:

 

Shader "Luoyinan/Projector/ShadowReceive"
{
    Properties
    {
        _Color ("Main Color", Color) = (1,1,1,1)
        _ShadowTex ("Cookie", 2D) = "" {}
        _MaskTex ("Mask", 2D) = "" {}
    }

    Subshader
    {
        Tags {"Queue"="Transparent"}
        Pass
        {
            ZWrite Off
            Fog { Mode Off }
            ColorMask RGB
            Blend DstColor Zero
            Offset -1, -1

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct v2f
            {
                float4 uvShadow : TEXCOORD0;
                float4 pos : SV_POSITION;
            };

            float4x4 _Projector;
            v2f vert (float4 vertex : POSITION)
            {
                v2f o;
                o.pos = mul (UNITY_MATRIX_MVP, vertex);
                o.uvShadow = mul (_Projector, vertex);
                return o;
            }

            sampler2D _ShadowTex;
            sampler2D _MaskTex;
            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 texM = tex2Dproj(_MaskTex, UNITY_PROJ_COORD(i.uvShadow));
                fixed4 texS = tex2Dproj(_ShadowTex, UNITY_PROJ_COORD(i.uvShadow));
                texS.rgb += texM.rgb;

                return texS;
            }
            ENDCG
        }
    }
}

 

優化:

1. RenderTexture盡量簡單,大小最好不要超過512,格式用沒alpha通道的565,關閉抗鋸齒,因為只渲染單一顏色,可關閉深度,

2. 陰影投射的shader盡量簡單,為了效率,我的shader沒用主紋理,所以不支持alpha test.如要支持,可自行修改shader.

3. 陰影攝像機看到的對象比游戲主攝像機看的多一些,只讓主攝像機看到的對象才產生陰影.能少渲染幾個角色.用OnBecameVisible來實現.

4. 為了避免反向投影穿幫,陰影方向盡量不要太斜.

5. 遠處的陰影邊緣衰減,用一張掩碼紋理:

 

 

最終效果,可以看到遠處的陰影自然衰減,也能投影到斜坡上,: