ROS的DDNS腳本

ROS使用ADSL上網時，每次撥號IP都會改變，導致外網訪問ROS服務器失敗，目前最常見的解決方案是使用DDNS這種動態域名工具，在撥號后（IP發生變化后）通知DDNS服務器更新IP，最終使用DDNS服務商提供的靜態域名即可永久訪問這台服務器。ROS官方僅支持changeip，但通過其它方法也可以實現支持花生殼，測試通過的腳本如下：

一、國外changeip的腳本，修改自changeip官方網站：

# Define User Variables
:global ddnsuser "user"
:global ddnspass "password"
:global ddnshost "xxxx.onmypc.org"
:global ddnsinterface "changkuan"

# Define Global Variables
:global ddnsip
:global ddnslastip

:if ([ :typeof $ddnslastip ] = nothing ) do={ :global ddnslastip "0" }

# Grab the current IP address on that interface.
:global ddnsip [ /ip address get [/ip address find interface=$ddnsinterface ] address ]
:log info $ddnsip
# Did we get an IP address to compare?
:if ([ :typeof $ddnsip ] = nil ) do={
   :log info ("DDNS: No ip address present on " . $ddnsinterface . ", please check.")
} else={

  :if ($ddnsip != $ddnslastip) do={

    :log info "DDNS: Sending UPDATE!"
    :log info [ :put [/tool dns-update name=$ddnshost address=[:pick $ddnsip 0 [:find $ddnsip "/"] ] key-name=$ddnsuser key=$ddnspass ] ]
    :global ddnslastip $ddnsip

  } else={ 
    :log info "DDNS: No update required."
  }

}

# End of script

二、國內花生殼的腳本，官方提供的腳本每次都會更新，根據上述changip腳本修改之，實現IP變化后才更新：

local server "http://ddns.oray.com"
local domain "xxxx.oicp.net"
local users "user"
local paswd "password"
local adslinterface "changkuan"
local ipaddr
:global lastipaddr

set ipaddr [/ip address get [/ip address find interface=$adslinterface] address]
:if ([ :typeof $ipaddr ] = nil ) do={
   :log info ("ORAY: No ip address present on " . $adslinterface . ", please check.")
} else={
   set ipaddr [:pick $ipaddr 0 ([len $ipaddr] -3)]   
   :log info $ipaddr
   :if ($ipaddr != $lastipaddr) do={
    local par "/ph/update?&hostname=$domain&myip=$ipaddr"
    :log info "ORAY: Sending UPDATE!"
    :log info [:put [ /tool fetch url=($server . $par) mode=http user=$users password=$paswd ] ]
    :global lastipaddr $ipaddr

  } else={ 
    :log info "ORAY: No update required."
  }
}