(Excel)常用函數公式及操作技巧之六：
匯總計算與統計（一）
——通過知識共享樹立個人品牌。
個調稅公式
=MAX(($A1-1900)*{0,0.05,0.1,0.15,0.2,0.25,0.3,0.35,0.4,0.45}
-{0,0,25,125,375,1375,3375,6375,10375,15375})
{0,0.05,0.1,0.15,0.2,0.25,0.3,0.35,0.4,0.45} 為稅率
{0,0,25,125,375,1375,3375,6375,10375,15375} 為稅收扣除數
上列公式的簡化式 :
=MAX(應納稅所得額*0.05*{1,2,3,4,5,6,7,8,9}
-25*{0,1,5,15,55,135,255,415,615},0)
算物價的函數
物價的那個三七作五，二舍八入的尾數處理，做一個函數。就是小數點后面第二位如果是1，2的就舍掉，如果是3，4，5，6，7的都變為5，如果是8，9的小數點第一位加1，第二位就變為0。比如價格是3.32、3.31，作尾數處理就是3.3；價格是3.33、3.34、3.36、3.37，做尾數處理就是3.35；價格是3.38、3.39，做尾數處理就是3.4。
=CEILING(A1-0.02,0.05)
都是二位小數
B2=ROUND(2*A2,1)/2
超過二位小數
B2=ROUND(2*ROUNDDOWN(A2,2),1)/2
自動計算應收款滯納金
要求在給定的應收日期、滯納金率、當前日期（自動取）的基礎上自動計算出應收滯納金。
解答：
=(DATEDIF(應收日期,NOW(),"d"))*滯納金率（每天）*應收金額
淘汰率
題目如下：這個工廠有1000人，今天抽出十人來做調查，這十人一天的產量分別為101 102 105 106 98 95 96 104 110 103 （A3-A12）。
1000人當中淘汰率為5%，以這十人為標准那么這1000人他們的生產應該為多少才不會被淘汰，看看函數的幫助就知道了呀，返回數組K百分比值點，你要1000人淘汰5人就是5/1000=0.5%=0.005，就是你以這10個抽樣調查的數據為基准，只要產量達到這個數就不會被淘汰了。（95.45）
公式=PERCENTILE(A3:A12,G1)
應用公積金的一個函數
我公司職工公積金比例為26％ 也就是個人和單位各13％，給公積金投繳人員制作了一個函數。直接用基數乘以比例 基數*比例＝投繳額， 對於投繳額的要求是：取最接近“投繳額”的偶數。
我制作的函數是“=IF(MOD(INT(A1*B1),2)=0,INT(A1*B1),CEILING(A1*B1,2))”
注：A1=基數 B1＝投繳比例
也可以改成這樣
=IF(MOD(INT(A1*B1),2)=0,INT(A1*B1),INT(A1*B1)+1) 或=IF(MOD(INT(A1*B1),2)=0,INT(A1*B1),EVEN(A1*B1))
如何利用公式將數值轉為百分比格式
如用公式將1.289675顯示為128.97%，不是用格式來達到的。
＝ROUND(B1*100,1)&"%"
比高得分公式
=RANK(B4,$B$4:$B$26,1)
自動評定獎級
=VLOOKUP(L179,IF({1,0},$D$204:$D$207,$B$204:$B$207),2)
=LOOKUP(L179,{0,4,7,12,24},{"一等獎","二等獎","三等獎","紀念獎","紀念獎"})
～～～～～～～～～～～～～～～～～～～～～～～～～～～～～
對帶有單位的數據如何進行求和
在數據后必須加入單位，到最后還要統計總和，請問該如何自動求和？（例如：A1：2KG，A2：6KG.....，在最后一行自動計算出總KG數）。
=SUMPRODUCT(--LEFT(A1:A5,(LEN(A1:A5)-2)))&”KG”
對a列動態求和
可以隨着a列數據的增加，在“b1”單元格=sum(x)對a列動態求和。
=SUM(OFFSET(A1,0,0,COUNTA(A:A),1))
動態求和公式
自A列A1單元格到當前行前面一行的單元格求和。
=SUM(INDIRECT("A1:A"&ROW()-1))
列的跳躍求和
若有20列（只有一行），需沒間隔3列求和，該公式如何做？
假設a1至t1為數據（共有20列），在任意單元格中輸入公式：
=SUM(IF(MOD(TRANSPOSE(ROW(1:20)),3)=0,(a1:t1))
按ctrl＋shift＋enter結束即可求出每隔三行之和。
跳行設置：如有12行，需每隔3行求和
=SUM(IF(MOD((ROW(1:12)),3)=0,(A1:A12)))
有規律的隔行求和
要求就是在計划、實際、差異三項中對后面的12個月求和。
=SUMPRODUCT(--(MOD(COLUMN(F3:AO3)-CELL("Col",F3)+0,3)=0),F3:AO3)
=SUMIF($F$2:$AO$2,C$2,$F3:$AO3)
=SUMPRODUCT((MOD(COLUMN($F3:$AO3),3)=MOD(COLUMN(F3),3))*$F3:$AO3)
也可以拖動填充，插入行、列也不影響計算結果。
如何實現奇數行或偶數行求和
假設數據在A1:A100
奇數行:=SUMPRODUCT(MOD(ROW($A$1:$A$100),2)*$A$1:$A$100) 偶數行:=SUMPRODUCT((MOD(ROW($A$1:$A$100),2)=0)*($A$1:$A$100)) 奇數行求和 =SUMPRODUCT((A1:A100)*MOD(ROW(A1:A100),2)) 偶數行求和 =SUMPRODUCT((A1:A100)*NOT(MOD(ROW(A1:A100),2)))
單數行求和
隔行求和用什么函數，即：A1+A3+A5+A7+A9…公式如何用。
{=SUM(N(OFFSET(A1,ROW(1:50)*2-2,)))}
{=SUM(IF(MOD(ROW(A1:A100),2)=1,A1:A100,0))}
統計偶數單元格合計數值
統計F4到F62的偶數單元格合計數值 。｛=SUM(IF(MOD(ROW(F4:F62),2)=0,F4:F62))｝
隔行求和公式設置
均為數組公式：
=SUM(IF(MOD(ROW(A1:A110),2),A1:A110,0)) =SUM(N(OFFSET($A$1,ROW(1:55)*2-2,,,))) =SUM((MOD(ROW(A1:A100),2)=1)*(A1:A100)) =SUM((MOD(ROW(A1:A100),2)=0)*(A1:A100)) =SUMPRODUCT((MOD(ROW(A1:A100),2)=0)*A1:A100)
隔列將相同項目進行求和
隔列將出勤日和工資分別進行求和數組公式
=SUM(IF(($B$4:$B$25)=B26,($C$4:$C$25),0)) 或； =SUMPRODUCT(--(MOD(ROW(C5:C25),2)<>0),C5:C25)
隔行或隔列加總
隔2列加總
=SUM((MOD(ROW($A$1:$A$25),2)=0)*$A$1:$A$25)
隔2欄加總
=SUM((MOD(COLUMN($B$1:$T$1),2)=0)*$B$1:$T$1)
請問如何在一百行內做隔行相加
數組公式
A1+A3+……+A99 單 =SUM(N(OFFSET(A1,ROW(1:50)*2-2,))) A2+A4+……+A100 雙 =SUM(N(OFFSET(A1,ROW(1:50)*2-1,)))
如何將間隔一定的列的數據相加呢
碰到100多列的數據將間隔一定的數據用手工相加太煩了，也容易出錯。如果需要相加的數據均有相同的名稱（字段），可以用Sumif()來求解，如果沒有，就需要用數組公式來解決了。{=SUM((MOD(ROW(A1:A18),3)=1)*A1:A18)} 1、4、7……行相加。
隔列求和（A、B列）
=SUM(A:A,B:B) =SUM(A:A,B:B,C:C) （統計A、B、C列）
隔列求和的公式
| 品種及日期 |
1月1日 |
1月2日 |
1月3日 |
1月4日 |
1月5日 |
余額 |
|||||
|
|
進 |
出 |
進 |
出 |
進 |
出 |
進 |
出 |
進 |
出 |
|
| A |
1 |
1 |
2 |
5 |
3 |
2 |
7 |
9 |
8 |
1 |
3 |
=SUMIF($B$2:$K$2,"進",B3:K3)-SUMIF($B$2:$K$2,"出",B3:K3)
=SUM(SUMIF(B$2:K$2,{"進","出"},B3:K3)*{1,-1})
隔列求和
| 類別 |
成品代碼 |
單價 |
安貞 |
北辰 |
長安 |
長春 |
合計 |
|||||
| 庫存 |
銷售 |
庫存 |
銷售 |
庫存 |
銷售 |
庫存 |
銷售 |
庫存 |
銷售 |
|||
| 皮帶 |
V19201 |
270.00 |
1 |
2 |
1 |
2 |
1 |
2 |
1 |
2 |
|
|
庫存合計=SUMIF($D$3:$BS$3,"庫存",$D$4:$BT$4), 銷售合計=SUMIF($D$3:$BS$3,"銷售",$D$4:$BT$4) =SUMIF($D$3:$BS$3,BT$3,$D4:$BS4) =SUMPRODUCT((MOD(COLUMN($D4:$BS4),2)=0)*$D4:$BS4)
關於隔行、隔列求和的問題
隔2列加總 =SUM((MOD(ROW($A$1:$A$25),2)=0)*$A$1:$A$25) 隔2行加總 =SUM((MOD(COLUMN($B$1:$T$1),2)=0)*$B$1:$T$1) 均為數組公式。
EXCEL中求兩列的對應元素乘積之和
如:a1*b1+a2*b2+b3*b3...的和 =SUM(A1:A3*B1:B3) (數組公式) =SUMPRODUCT(A1:A10,B1:B10)
計算900~1000之間的數值之和
sumif函數的計算格式為: =sumif($a$1:$a$20,">1000")。即返回$a$1:$a$20中大於1000的數值的和,但如果想計算900~1000之間的數值之和,應該如何編寫。
請參考：{=SUM(IF((A1:A20>900)*(A1:A20<1000),A1:A20))}或{=SUM((900<A1:A20)*(A1:A20<1000)*A1:A20)}
2、=SUMIF(A1:A20,">900")-SUMIF(A1:A20,">1000")
雙條件求和
1、 求一班女生的個數 :
=SUMPRODUCT((A2:A9=1)*(B2:B9=""女""))
2、求一班成績的和 :
=SUMIF(A2:A9,1,C2:C9) "
3、求一班男生成績的和 :
=SUMPRODUCT((A2:A9=1)*(B2:B9=""男""),C2:C9) "
如何實現這樣的條件求和
求型號中含BC但不含ABC的量:
| A |
B |
C |
|
|
|
型號 |
數量 |
|
| 1 |
CRVABC12 |
100 |
|
| 2 |
CVABC13 |
102 |
|
| 3 |
CVBC12 |
104 |
|
| 4 |
CNVBC13 |
106 |
|
=SUMIF($A$2:$A$12,"*"&"bc"&"*",$B$2:$B$12)-SUMIF($A$2:$A$12,"*"&"abc"&"*",$B$2:$B$12)
=SUMPRODUCT((ISNUMBER(FIND("BC",A2:A12))<>ISNUMBER(FIND("ABC",A2:A12)))*B2:B12)
A1:A10數字顯為文本格式時，如何求和
=SUMPRODUCT(A1:A10)
求和
所有本范例所使用的數據都為引用以下綠色區域，並定義為對應的標題 。
| Name |
Sex |
Age |
Position |
Salary |
| 張無忌 |
男 |
26 |
主角 |
10000 |
| 韋小寶 |
男 |
16 |
主角 |
13000 |
| 滅絕 |
女 |
55 |
配角 |
3000 |
| 周芷若 |
女 |
22 |
主角 |
8000 |
| 鰲拜 |
男 |
62 |
普通演員 |
2000 |
| 儀琳 |
女 |
18 |
配角 |
5000 |
| 岳靈珊 |
女 |
19 |
配角 |
4500 |
| 令狐沖 |
男 |
27 |
主角 |
15000 |
| 性空 |
男 |
88 |
普通演員 |
2200 |
| 東方不敗 |
不詳 |
45 |
主角 |
9000 |
A 求所有演員工資總額
71700 =SUM($G$7:$G$16)
簡單求和
B 求男演員工資總額
42200 =SUMIF($D$7:$D$16,"男",$G$7:$G$16)
單條件求和.1
C 求年齡在20歲以下的演員工資
22500 =SUMIF($E$7:$E$16,"<20",$G$7:$G$16)
單條件求和.2
D 求主角和配角的工資(不是普通演員)
67500 =SUMIF($F$7:$F$16,"*角",$G$7:$G$16)
單條件求和.3
E 求20歲以下女演員工資
9500 {=SUM(($D$7:$D$16="女")*($E$7:$E$16<20)*$G$7:$G$16)}
多條件求和-同時滿足條件
F 求男性或主角的工資
59200 {=SUM(IF(($D$7:$D$16="男")+($F$7:$F$16="主角"),$G$7:$G$16))}
多條件求和-只須滿足條件之一
G 求男性非主角或主角非男性的工資(即除男主角外的男性和主角)
g.1 21200 {=SUM(IF(($D$7:$D$16="男")-($F$7:$F$16="主角"),$G$7:$G$16))}
g.2 21200 {=SUM(IF(($F$7:$F$16="主角")-($D$7:$D$16="男"),$G$7:$G$16))}
多條件求和-只滿足條件之一而不能同時滿足
H 啊~~~你不知道什么是數組函數啊，可是你有時候也要用多條件求和？
不要緊，教你用另外的方法：SUBTOTAL
求20歲以下女演員工資
71700 =SUBTOTAL(9,$G$7:$G$16)
現在你看到的還不是最后結果，請按如下操作
1、把數據區域設置成可篩選
2、把SEX篩選成"=女", 把年齡篩選成<20
3、你再看上面的公式結果…
去掉其中兩個最大值和兩個最小值，再求和
請問如何去掉兩個最高分，兩個最低分，剩余人員的分數求和，例如A1-A7中的7個分，去掉兩個最高分，兩個最低分，剩余人員的分數求和。
=SUM(A1:A50)-MAX(A1:A50)-LARGE(A1:A50,2)-MIN(A1:A50)-SMALL(A1:A50,2)
=SUM(A1:A20)-SUM(LARGE(A1:A20,{1,2}))-SUM(SMALL(A1:A20,{1,2}))
=TRIMMEAN(A1:A7,4/7)*(7-4)
=SUMPRODUCT(LARGE(A1:A7,ROW(A1:A7))*(ROW(1:7)>2)*(ROW(1:7)<6))
=SUMPRODUCT((A$1:A$7<LARGE(A$1:A$7,2))*(A$1:A$7>SMALL(A$1:A$7,2))*A$1:A$7)
=SUM (A!:A7)-LARGE(A!:A7,1)-LARGE(A!:A7,2)-SMALL(A!:A7,1)-SMALL(A!:A7,2)
將此函數橫着使用（A1-G1）
=TRIMMEAN(A1:G1,4/7)*(7-4) =SUMPRODUCT(LARGE(A1:G1,COLUMN(A1:G1))*(COLUMN(A:G)>2)*(COLUMN(A:G)<6))
去掉兩個最高分、最低分，顯示出被去掉的分數
被去掉的分數：
最大兩個：=large(data,{1;2})
最小兩個：=small(data,{1;2})
永恆的求和
1、=SUM(OFFSET(A1,,,ROW()-ROW(A1)))可以對A列數值自動求和。
2、=SUM(INDIRECT("R2C:R[-1]C",FALSE))
3、=SUM(INDIRECT("A2:A"&ROW()-1))
=SUM(INDIRECT(ADDRESS(1,COLUMN())&":"&ADDRESS(ROW()-1,COLUMN())))
按字體顏色求和
做法：
G3={SUM(IF(($A$2:$A$19=E3)*($B$2:$B$19=F3),$C$2:$C$19))}
G4:G11公式為G3公式下拖.
～～～～～～～～～～～～～～～～～～～～～～～～～～～～～
如何分班統計男女人數
男=SUMPRODUCT(($B$2:$B$446=$E2)*($C$2:$C$446=F$1)) =SUMPRODUCT(($B$2:$B$446=E3)*($C$2:$C$446=F$1)) =SUMPRODUCT(($B$2:$B$446=$E2)*($C$2:$C$446=F$1)) ｛=SUM(($B$2:$B$446=$E2)*($C$2:$C$446=$F$1))｝ ｛=SUM(($B$2:$B$446=F2)*($C$2:$C$446=$G$1)*$D$2:$D$446)｝ 女=SUMPRODUCT(($B$2:$B$446=$E2)*($C$2:$C$446=G$1)) 合計=COUNTIF($B$2:$B$446,E2)