(Excel)常用函數公式及操作技巧之四：
文本與頁面設置(五)
——通過知識共享樹立個人品牌。
如何提取一串數字中的幾位數字（字符）
如：050326
提取后3位數字
=RIGHT(A1,3) “3”是提取3位，如果改“4”，則提取4位。
=RIGHT(A3,LEN(A3)-3)
=MID(A3,4,3)
=REPLACE(A3,1,3,"")
提取中間的4位數字，“5032”
=MID(A1,2,4)
=MID(A3,(LEN(A3)-4)/2+1,4)
要提取 050324 中的 502 怎么提取？即：第二、三兩位和第五位數字
=MID(A3,2,2)&MID(A3,5,1)
=MID(A3,2,1)&MID(A3,3,1)&MID(A3,5,1)
如何把一個單元格中的數字挑出來
一個單元格中有數字、空格、漢字，如：“11210101 銀行存款/工行”，數字的位數不確定，但都從最左邊開始，數字和漢字中間有一個空格。如何只把數字顯示出來？
1、如果都是這樣就簡單 "都從最左邊開始，數字和漢字中間有一個空格"
假定在A1，公式為：=LEFT(A1,FIND(" ",A1)-1)
2、數據分列不更簡單么？分列符號選中空格前面那個框。
分割文本
有一列數據，全部是郵箱的，現在想將@前面的賬號與@后面的域名分割開，分為兩列，如何做？
采用函數分割：例如：A1: name@163.com
B1:=LEFT(A1,FIND("@",A1)-1) --> name
C1:=RIGHT(A1,LEN(A1)-FIND("@",A1)) --> 163.com
或：數據-分列-分列-分隔符號-@就可以了
按照給定的位數，截斷小數點后的數字
對整數無效，且這個函數沒有四舍五入的功能
12512.2514 12512.25
=TRUNC(B23,2)
單元格數字提取問題
單元格里面填寫的 CHIP(0601-2299),把0601-2299 提取出來應該怎么做。
=IF(B3="","",SUBSTITUTE(MID(B3,FIND("(",B3)+1,100),")",""))
我用IF函數是因為看到你給的表格當中,數據和數據之間都有一行空行,
如果沒有空行的話,數據是連續的時候公式可以簡化為：
=SUBSTITUTE(MID(B3,FIND("(",B3)+1,100),")","")
以關鍵字提取名稱
求當輸入球隊時，自動生成聯賽名稱
| 聯賽 |
球隊 |
當輸入球隊時 |
函數自動生成 |
| 英超 |
車路士 |
車路士 |
英超 |
| 英超 |
阿仙奴 |
愛華頓 |
英超 |
| 英超 |
曼聯 |
祖雲達斯 |
意甲 |
| 英超 |
利物浦 |
麥斯納 |
意甲 |
| 英超 |
愛華頓 |
|
|
| 英超 |
米杜士堡 |
|
|
| 意甲 |
祖雲達斯 |
|
|
=INDEX(A$2:A$23,MATCH(D2,B$2:B$23,0))
=INDIRECT("A"&MATCH(D2,B:B,))
=VLOOKUP(D2,IF({1,0},$B$2:$B$23,$A$2:$A$23),2,0)
如何把文本中的前幾個字符去除
如將“第二班AAA”中的“第二班”三個字去除。
1、用公式：
=RIGHT($A2,3)
=RIGHT($A2,LEN($A2)-FIND("班",$A2))
=MID($A2,FIND("班",$A2)+1,LEN($A2))
=RIGHT(B2,LENB(B2)-LEN(B2))
=REPLACE(A1,1,3,"")
=SUBSTITUTE(A1,"第二班",)
如前幾個字符或后英文字數, 不相同或不固定，公式可用:
{=MID(A2,MATCH(0,--(CODE(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1))<65),0),255)}
2、數據>分列>固定寬度,把上述數據分為兩列后,刪除第一班的列
對一列中的文字統一去掉最后一個字
能否對一列中的文字統一去掉最后一個字?這些文字不統一,有些字數多,有些字數少。如何處理?
=REPLACE(A1,LEN(A1),1," ")(在過渡列進行)
討如何去掉單元格中的第一個數字？
=MID(A1,2,LEN(A1)-1) 或者 =RIGHT(A1,LEN(A1)-1)
=REPLACE(A1,1,1,"")
論一下取最后一個單詞的方法
例如現在在A1中有一句“M. Henry Jackey”，如何用函數將最后的一個單詞取出來呢？ 當然，我們現在是知道最后的單詞是6個字符，可以用Right(A1,6)來計算，但如果最后一個單詞的字符數是不定的呢，如果做呢？ 請大家試下有幾種方法。
方法1、用一列公式填充
=IF(LEFT(RIGHT($A$1,ROW()),1)=CHAR(32),RIGHT($A$1,ROW()-1),“”)
方法2、=MID(A1,FIND(" *",SUBSTITUTE(A1," "," *",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))+1,LEN(A1)-FIND(" ",A1))
方法3、=IF(ISERROR(SEARCH("",TRIM(LEFT(B1)))),RIGHT($A$1,ROW()),"")拖出來的第一個字符就行。
方法4、{=RIGHT(A1,LEN(A1)-MAX((MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)=" ")*ROW(INDIRECT("1:"&LEN(A1)))))}
嫌長就（假定最長100字符）
{=RIGHT(A1,LEN(A1)-MAX((MID(A1,ROW(1:100),1)=" ")*ROW(1:100)))}
如何去掉單元格最后一位數字
說明:單元格前面的數據不能改變，去掉最后一位數字。
=LEFT(A2,LEN(A2)-IF(ISNUMBER(--RIGHT(A2)),LEN(LOOKUP(9E+307,--RIGHT(A2,ROW(INDIRECT("1:"&LEN(A2)))))),))
如果后面代的數值在兩位以內,也可以用以下方式實現,當然如果超過兩位的話,可以加語句 IF(ISNUMBER(RIGHT(TRIM(A2), X )+0)=TRUE,1,0) X 代表后面數值的個數。
=LEFT(TRIM(A2),LEN(TRIM(A2))-IF(ISNUMBER(RIGHT(TRIM(A2),1)+0)=TRUE,1,0)+IF(ISNUMBER(RIGHT(TRIM(A2),2)+0)=TRUE,1,0))
如何在一列已經輸入的數據前添加“p”
比如一列數據 添加后變
112234 p112234
123435 p123435
124355 p124355
123545 p123545
選中所有單元格，設置格式，自定義-〉在缺省的“G/通用格式”前面加上“"p"”（半角的雙引號中間是p）即可
加一列全是“p”，使用&=a1&b1 Shift+7
="P"&A1
在自定義中輸入"Q"#即可,很簡單的。
什么函數可以插入字符
怎樣用第一列的數據形成第二列的數據，即在特定位置加上幾個相同字符串？
解答： b1="04"& a1
問：哪如果倒過來呢？
答：用公式A1=MID(B1,3,13)或A1=SUBSTITUTE(B1,"04","",1)
如何在數據前添加“*”號
數據如在B列,在A列整列加“*”，C列C1輸入公式C1=A1&B1,
下拉。用“選擇性粘貼”選“值”復制到D列，刪去A、B、C列。
數字前面加上數字
123
0123
75223
比如說上述的數字，我想在它們前面加上38910104，而且位置短的數字，會自動補0
變成如下：
3891010400123
3891010400123
3891010475223）
=TEXT(A1,"3891010400000")
3、查找替換，查找欄輸入：第*班，替換欄空置，全部替換