SAP EPIC 銀企直連 農業銀行 Socket 接口項目實踐

SAP EPIC 銀企直連大部分銀行用的是Http 接口，可以直接在SM59中創建 到外部服務器的HTTP連接即可與銀行前置機通信，快速進行銀企直連接口開發。

少部分銀行用的是Socket （農業銀行，南京銀行等），這時有2種方式：

• JAVA 把Socket 封裝成Http，然后ABAP調用；
• ABAP直接調用Socket；

可根據項目實際情況靈活選擇。一般情況建議采用SAP標准的EPIC 銀企直連解決方案，穩定可靠，開發工作量少，大大降低實施成本。

 1.3.1關於通訊方式

ERP與ICT之間的交易數據包都采用TCP/IP協議的Socket同步短連接方式。
Socket 方式中報文結構為“包頭+數據包”。包頭固定為7個字節長，第1字節為是否加密標志（0-不加密，1-加密）。后6個字節是數據包的長度，即將報文長度直接轉為字符串存儲，長度不足6位則右邊用空格補足，比如：“1234 ”。比如匯兌的長度為1234字節的數據包，其包頭為“01234 ”共7位，其中數據包長度包含加密包標志位。由於加密需要雙方約定專門的加密算法，因此一般ERP送的加密標志都為0-不加密。

 

 

WebSocket Communication with ABAP Push Channel using Text Messages

Open WebSocket

Send message to APC

Close WebSocket

If the form field amc of the URL contains "x", an opened WebSocket receives text messages from the ABAP Messaging Channel DEMO_AMC.
Such messages are then sent in the APC handler class but can also be sent by program DEMO_SEND_AMC.
The program DEMO_RECEIVE_AMC can receive text messages sent by the APC handler class.

If you send the message get handle, you will receive the connection attach handle of the APC-server.

 

REPORT demo_apc_tcp_client.
 
CLASS apc_handler DEFINITION FINAL .
  PUBLIC SECTION.
    INTERFACES if_apc_wsp_event_handler.
    DATA       message TYPE string.
ENDCLASS.
 
CLASS apc_handler IMPLEMENTATION.
  METHOD if_apc_wsp_event_handler~on_open.
  ENDMETHOD.
 
  METHOD if_apc_wsp_event_handler~on_message.
    TRY.
        message = i_message->get_text( ).
      CATCH cx_apc_error INTO DATA(apc_error).
        message = apc_error->get_text( ).
    ENDTRY.
  ENDMETHOD.
 
  METHOD if_apc_wsp_event_handler~on_close.
    message = 'Connection closed!'.
  ENDMETHOD.
 
  METHOD if_apc_wsp_event_handler~on_error.
  ENDMETHOD.
ENDCLASS.
 
CLASS apc_demo DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main.
ENDCLASS.
 
CLASS apc_demo IMPLEMENTATION.
  METHOD main.
    DATA(tcp_server) = `C:\ncat\ncat.exe`.
    DATA(ip_adress)  = cl_gui_frontend_services=>get_ip_address( ).
    DATA(port)       = `12345`.
    DATA(terminator) = `0A`.
    DATA(msg)        = `Hello TCP, answer me!`.
 
    cl_demo_input=>new(
      )->add_text(
         `For the TCP server, download the freely available NCAT.EXE`
      )->add_field( CHANGING field = tcp_server
      )->add_field( CHANGING field = ip_adress
      )->add_field( CHANGING field = port
      )->add_field( CHANGING field = terminator
      )->add_field( CHANGING field = msg
      )->request( ).
 
    "Server
    IF cl_gui_frontend_services=>file_exist(
         file = tcp_server ) IS INITIAL.
      cl_demo_output=>display( 'TCP Server not found!' ).
      LEAVE PROGRAM.
    ENDIF.
    cl_gui_frontend_services=>execute(
    EXPORTING
      application = `cmd.exe`
      parameter  =  `/c ` && tcp_server &&
                   ` -l ` && ip_adress && ` -p ` && port ).
    WAIT UP TO 1 SECONDS.
 
    TRY.
        DATA(event_handler) = NEW apc_handler( ).
 
        "Client
        DATA(client) = cl_apc_tcp_client_manager=>create(
          i_host   = ip_adress
          i_port  = port
          i_frame = VALUE apc_tcp_frame(
            frame_type =
              if_apc_tcp_frame_types=>co_frame_type_terminator
            terminator =
              terminator )
          i_event_handler = event_handler ).
 
        client->connect( ).
 
        "Send mesasage from client
        DATA(message_manager) = CAST if_apc_wsp_message_manager(
          client->get_message_manager( ) ).
        DATA(message) = CAST if_apc_wsp_message(
          message_manager->create_message( ) ).
        DATA(binary_terminator) = CONV xstring( terminator ).
        DATA(binary_msg) =
          cl_abap_conv_codepage=>create_out( )->convert( msg ).
        CONCATENATE binary_msg binary_terminator
               INTO binary_msg IN BYTE MODE.
        message->set_binary( binary_msg ).
        message_manager->send( message ).
 
        "Wait for a message from server
        CLEAR event_handler->message.
        WAIT FOR PUSH CHANNELS
             UNTIL event_handler->message IS NOT INITIAL
             UP TO 10 SECONDS.
        IF sy-subrc = 4.
          cl_demo_output=>display(
            'No handler for APC messages registered!' ).
        ELSEIF sy-subrc = 8.
          cl_demo_output=>display(
            'Timeout occurred!' ).
        ELSE.
          cl_demo_output=>display(
            |TCP client received:\n\n{ event_handler->message }| ).
        ENDIF.
 
        client->close(
          i_reason = 'Application closed connection!' ).
 
      CATCH cx_apc_error INTO DATA(apc_error).
        cl_demo_output=>display( apc_error->get_text( ) ).
    ENDTRY.
 
  ENDMETHOD.
ENDCLASS.
 
START-OF-SELECTION.
  apc_demo=>main( ).

<ap>
  <CCTransCode>交易代碼</CCTransCode>
  <ProductID>產品標識</ProductID>
  <ChannelType>渠道標識</ChannelType>
  <CorpNo>企業技監局代碼/客戶號</CorpNo>
  <OpNo>企業操作員編號</OpNo>
  <AuthNo>認證碼</AuthNo>
  <ReqSeqNo>請求方流水號</ReqSeqNo>
  <ReqDate>請求日期</ReqDate>
  <ReqTime>請求時間</ReqTime>
  <Sign>數字簽名</Sign>
  <FileFlag>文件標識</FileFlag>
  <Corp>
    <StartDate>起始日期</StartDate>
    <EndDate>終止日期</EndDate>
  </Corp>
  <Channel>
    <LastJrnNo>0</LastJrnNo>
  </Channel>
  <Cmp>
    <DbAccNo>賬號</DbAccNo>
    <DbProv>省市代碼</DbProv>
    <DbCur>貨幣號</DbCur>
    <StartTime>末筆時間戳</StartTime>
  </Cmp>
</ap>

<ap>
  <CCTransCode>CQRA10</CCTransCode>
  <ProductID>ICC</ProductID>
  <ChannelType>ERP</ChannelType>
  <CorpNo>00000035</CorpNo>
  <OpNo>0011</OpNo>
  <AuthNo/>
  <ReqSeqNo>2021042211375856</ReqSeqNo>
  <ReqDate>20210422</ReqDate>
  <ReqTime>193758</ReqTime>
  <Sign/>
  <FileFlag/>
  <Corp>
    <StartDate>20210401</StartDate>
    <EndDate>20210421</EndDate>
  </Corp>
  <Channel>
    <LastJrnNo>0</LastJrnNo>
  </Channel>
  <Cmp>
    <DbAccNo>0023649</DbAccNo>
    <DbProv>15</DbProv>
    <DbCur>01</DbCur>
    <StartTime/>
  </Cmp>
</ap>                                                                                                                                                                                                                                                              

歡迎交流探討