neo4j基本增刪改查

1. 首先，我們刪除數據庫中以往的圖，確保一個空白的環境進行操作：

MATCH (n) DETACH DELETE n

2. 接着，我們創建一個人物節點：

CREATE (n:Person {name:'John'}) RETURN n

CREATE是創建操作，Person是標簽，代表節點的類型。花括號{}代表節點的屬性，屬性類似Python的字典。這條語句的含義就是創建一個標簽為Person的節點，該節點具有一個name屬性，屬性值是John。

如圖所示，在Neo4J的界面上可以看到創建成功的節點。

 

 

3. 我們繼續來創建更多的人物節點，並分別命名：

CREATE (n:Person {name:'Sally'}) RETURN n;
CREATE (n:Person {name:'Steve'}) RETURN n;
CREATE (n:Person {name:'Mike'}) RETURN n;
CREATE (n:Person {name:'Liz'}) RETURN n;
CREATE (n:Person {name:'Shawn'}) RETURN n;

如圖所示，6個人物節點創建成功

 

4. 接下來創建地區節點

CREATE (n:Location {city:'Miami', state:'FL'});
CREATE (n:Location {city:'Boston', state:'MA'});
CREATE (n:Location {city:'Lynn', state:'MA'});
CREATE (n:Location {city:'Portland', state:'ME'});
CREATE (n:Location {city:'San Francisco', state:'CA'});

可以看到，節點類型為Location，屬性包括city和state。 

如圖所示，共有6個人物節點、5個地區節點，Neo4J貼心地使用不用的顏色來表示不同類型的節點

 

5. 接下來創建關系

MATCH (a:Person {name:'Liz'}), 
      (b:Person {name:'Mike'}) 
MERGE (a)-[:FRIENDS]->(b)

這里的方括號[]即為關系，FRIENDS為關系的類型。注意這里的箭頭-->是有方向的，表示是從a到b的關系。 如圖，Liz和Mike之間建立了FRIENDS關系，通過Neo4J的可視化很明顯的可以看出：

6. 關系也可以增加屬性

MATCH (a:Person {name:'Shawn'}), 
      (b:Person {name:'Sally'}) 
MERGE (a)-[:FRIENDS {since:2001}]->(b)

在關系中，同樣的使用花括號{}來增加關系的屬性，也是類似Python的字典，這里給FRIENDS關系增加了since屬性，屬性值為2001，表示他們建立朋友關系的時間。

7. 接下來增加更多的關系

MATCH (a:Person {name:'Shawn'}), (b:Person {name:'John'}) MERGE (a)-[:FRIENDS {since:2012}]->(b)
MATCH (a:Person {name:'Mike'}), (b:Person {name:'Shawn'}) MERGE (a)-[:FRIENDS {since:2006}]->(b)
MATCH (a:Person {name:'Sally'}), (b:Person {name:'Steve'}) MERGE (a)-[:FRIENDS {since:2006}]->(b)
MATCH (a:Person {name:'Liz'}), (b:Person {name:'John'}) MERGE (a)-[:MARRIED {since:1998}]->(b)

如圖，人物關系圖已建立好，有點圖譜的意思了吧？

 

8. 然后，我們需要建立不同類型節點之間的關系-人物和地點的關系

MATCH (a:Person {name:'John'}), (b:Location {city:'Boston'}) MERGE (a)-[:BORN_IN {year:1978}]->(b)

這里的關系是BORN_IN，表示出生地，同樣有一個屬性，表示出生年份。 

如圖，在人物節點和地區節點之間，人物出生地關系已建立好。

 

9. 同樣建立更多人的出生地

MATCH (a:Person {name:'Liz'}), (b:Location {city:'Boston'}) MERGE (a)-[:BORN_IN {year:1981}]->(b)
MATCH (a:Person {name:'Mike'}), (b:Location {city:'San Francisco'}) MERGE (a)-[:BORN_IN {year:1960}]->(b)
MATCH (a:Person {name:'Shawn'}), (b:Location {city:'Miami'}) MERGE (a)-[:BORN_IN {year:1960}]->(b)
MATCH (a:Person {name:'Steve'}), (b:Location {city:'Lynn'}) MERGE (a)-[:BORN_IN {year:1970}]->(b)

建好以后，整個圖如下

 

10. 至此，知識圖譜的數據已經插入完畢，可以開始做查詢了。我們查詢下所有在Boston出生的人物

MATCH (a:Person)-[:BORN_IN]->(b:Location {city:'Boston'}) RETURN a,b

結果如圖

 

11. 查詢所有對外有關系的節點

MATCH (a)-->() RETURN a

注意這里箭頭的方向，返回結果不含任何地區節點，因為地區並沒有指向其他節點（只是被指向）

 

12. 查詢所有有關系的節點

MATCH (a)--() RETURN a

結果如圖

 

13. 查詢所有對外有關系的節點，以及關系類型

MATCH (a)-[r]->() RETURN a.name, type(r)

結果如圖

 

14. 查詢所有有結婚關系的節點

MATCH (n)-[:MARRIED]-() RETURN n

結果如圖

 

15. 創建節點的時候就建好關系

CREATE (a:Person {name:'Todd'})-[r:FRIENDS]->(b:Person {name:'Carlos'})

結果如圖

 

16. 查找某人的朋友的朋友

MATCH (a:Person {name:'Mike'})-[r1:FRIENDS]-()-[r2:FRIENDS]-(friend_of_a_friend) RETURN friend_of_a_friend.name AS fofName

返回Mike的朋友的朋友：

 

從圖上也可以看出，Mike的朋友是Shawn，Shawn的朋友是John和Sally

 

17. 增加/修改節點的屬性

MATCH (a:Person {name:'Liz'}) SET a.age=34
MATCH (a:Person {name:'Shawn'}) SET a.age=32
MATCH (a:Person {name:'John'}) SET a.age=44
MATCH (a:Person {name:'Mike'}) SET a.age=25

這里，SET表示修改操作

18. 刪除節點的屬性

MATCH (a:Person {name:'Mike'}) SET a.test='test'
MATCH (a:Person {name:'Mike'}) REMOVE a.test

刪除屬性操作主要通過REMOVE

19. 刪除節點

MATCH (a:Location {city:'Portland'}) DELETE a

刪除節點操作是DELETE

20. 刪除有關系的節點

MATCH (a:Person {name:'Todd'})-[rel]-(b:Person) DELETE a,b,rel