SQL處理分割字符串

建一個表值函數，如下：
USE [LMS]
GO
/****** Object:  UserDefinedFunction [dbo].[f_split]    Script Date: 2013/8/26 16:04:37 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
 ALTER FUNCTION [dbo].[f_split]
 (
     @strText varchar(3000),--待分離的原字符串
     @strSplit varchar(100)--分隔符
 )
 RETURNS @temp Table
 (
     ID int IDENTITY PRIMARY KEY,
     Code varchar(1000)
 )
 AS
 BEGIN
     Declare @intLen int --用來存儲待分離原字符串長度
     Declare @intSplitLen int --分隔符長度
     Declare @intIndex int --用來存儲分離字符串在原字符串的位置
    Declare @strVal varchar(1000)--用來存儲分離出來后的字符串
     --獲取原字符串的長度
    Set @intLen = LEN(RTRIM(LTRIM(@strText)))
     Set @intSplitLen = LEN(RTRIM(LTRIM(@strSplit)))
     --原字符串不為空，才繼續分離
     If(@intLen > 0)
     Begin
         --循環原字符串，直至原字符串被分離完畢
         While CHARINDEX(@strSplit,@strText)>0
         Begin
             --獲取分離字符串在原字符串的位置
             Set @intIndex = CHARINDEX(@strSplit,@strText)
             --獲取分離出的字符串，並插入表中
             Set @strVal = RTRIM(LTRIM(LEFT(@strText,@intIndex-1)))
             if(LEN(@strVal)>0)
             Begin
                 Insert Into @temp (Code) values(@strVal)
             End
             --分離后，將分離出的字符串（包括分隔符）從原字符串中刪除
             Set @strText = Substring(@strText,@intIndex+@intSplitLen,@intLen-@intIndex)
             --重新設置原字符串的長度
             Set @intLen = LEN(@strText)
         End
         --如果分離后的原字符串依然不為空，則也應該插入表中
         if(LEN(RTRIM(LTRIM(@strText)))>0)
         Begin
             Insert Into @temp (Code) values(@strText)
         End
     End
     return
end

調用方法：
DECLARE @BOStateIDs VARCHAR(100)    
SET @BOStateIDs='1,4,5'

CREATE TABLE #TempIDs(ID INT)
INSERT INTO #TempIDs
SELECT  code
FROM    [dbo].[f_split](@BOStateIDs, ',')

select * from BOBasicInfo where BOStatusID IN(
SELECT ID FROM #TempIDs
)