SQL分割字符串函數

SQL分割字符串函數SQL里類似Split的分割字符串函數
SQL對字符串的處理能力比較弱，比如我要循環遍歷象1,2,3,4,5這樣的字符串，如果用數組的話，遍歷很簡單，但是T-SQL不支持數組，所以處理下來比較麻煩。下邊的函數，實現了象數組一樣去處理字符串。
一.用臨時表作為數組

 

/*
函 數 名：F_split
函數作用：分割字符串
函數參數：
    @c    ### 要分割的字符串
    @split    ### 分隔符號
示例：
    Select * From dbo.F_split('a,b,c,d',',')
    返回結果：
        a
        b
        c
        d
*/
CREATE FUNCTION F_split(@c     VARCHAR(2000), 
                        @split VARCHAR(2)) 
returns @t TABLE( 
  col VARCHAR(20)) 
AS 
  BEGIN 
      WHILE( Charindex(@split, @c) <> 0 ) 
        BEGIN 
            INSERT @t 
                   (col) 
            VALUES (Substring(@c, 1, Charindex(@split, @c) - 1)) 

            SET @c = Stuff(@c, 1, Charindex(@split, @c), '') 
        END 

      INSERT @t 
             (col) 
      VALUES (@c) 

      RETURN 
  END
Go

 

二、按指定符號分割字符串，返回分割后的元素個數，方法很簡單，就是看字符串中存在多少個分隔符號，然后再加一，就是要求的結果

 

/*
函 數 名：Get_StrArrayLength
函數作用：返回分割字符串的長度
函數參數：
    @str    ### 要分割的字符串
    @split    ### 分隔符號
示例：
    Select dbo.Get_StrArrayLength('78,1,2,3',',')
    返回結果：
        4
*/
Select dbo.Get_StrArrayLength('78,1,2,3',',')
CREATE FUNCTION Get_StrArrayLength (@str   VARCHAR(1024),
                                    @split VARCHAR(10)
) 
returns INT 
AS 
  BEGIN 
      DECLARE @location INT 
      DECLARE @start INT 
      DECLARE @length INT 

      SET @str=Ltrim(Rtrim(@str)) 
      SET @location=Charindex(@split, @str) 
      SET @length=1 

      WHILE @location <> 0 
        BEGIN 
            SET @start=@location + 1 
            SET @location=Charindex(@split, @str, @start) 
            SET @length=@length + 1 
        END 

      RETURN @length 
  END
Go

 

三、按指定符號分割字符串，返回分割后指定索引的第幾個元素，象數組一樣方便

 

/*
函 數 名：Get_StrArrayStrOfIndex
函數作用：按指定符號分割字符串，返回分割后指定索引的第幾個元素，象數組一樣方便
函數參數：
    @str    ### 要分割的字符串
    @split    ### 分隔符號
    @index    ### 取第幾個元素
示例：
    Select dbo.Get_StrArrayStrOfIndex('8,9,4',',',2)
    返回結果：
        9
*/
CREATE FUNCTION Get_StrArrayStrOfIndex(@str   VARCHAR(1024), 
                                        @split VARCHAR(10), 
                                        @index INT) 
returns VARCHAR(1024) 
AS 
  BEGIN 
      DECLARE @location INT 
      DECLARE @start INT 
      DECLARE @next INT 
      DECLARE @seed INT 

      SET @str=Ltrim(Rtrim(@str)) 
      SET @start=1 
      SET @next=1 
      SET @seed=Len(@split) 
      SET @location=Charindex(@split, @str) 

      WHILE @location <> 0 
            AND @index > @next 
        BEGIN 
            SET @start=@location + @seed 
            SET @location=Charindex(@split, @str, @start) 
            SET @next=@next + 1 
        END 

      IF @location = 0 
        SELECT @location = Len(@str) + 1 

      RETURN Substring(@str, @start, @location - @start) 
  END
Go