salesforce零基礎學習（八十二）審批郵件獲取最終審批人和審批意見

項目中，審批操作無處不在。配置審批流時，我們有時候會用到queue，related user設置當前步驟的審批人，審批人可以一個或者多個。當審批人有多個時，郵件中獲取當前記錄的審批人和審批意見就不能隨便的取一個審批人了，有以下方式針對不同的場景可以獲取到當前記錄的最終審批人以及審批意見。

郵件內容使用以下幾種方式實現：

　　1.代碼里面實現郵件發送

　　2.email template(text/html/custom)

　　3.visualforce emailTemplate

對發送郵件方式不清楚的，可以參看：salesforce 零基礎學習（六十七）SingleEmailMessage 那點事

為方便查看效果，設置一下場景：針對Account更新操作，如果Account中Type進行了改變，提交一個更新申請的審批流程，如果審批流程在審批過程中，再次更改Type則提示有審批中的記錄，不允許再次修改。審批通過或者失敗則發送給創建人。郵件內容包括最終審批人以及審批意見。

准備工作

1.在Account上新增兩個字段 Type New用來記錄新更改的Type值，Type更改以后是不直接回寫的，只有審批通過以后才能回寫，Update Status用來記錄審批狀態

2.增加Account上的validation rule，避免已經有修改申請單情況下重復更改Type

3.增加申請單表以及相關的字段

4.增加審批流以及審批人對應的Queue,當Status是Pending Approval時，進入審批流，審批通過或者拒絕更新狀態

 5.配置Account以及Main_Info_Update__c的trigger，實現相關的賦值以及自動進入審批流操作

AccountTrigger：實現更新前對關鍵字段賦值以及更新后的創建更新申請數據以及自動提交審批流

trigger AccountTrigger on Account(before update,after update) {

    if(Trigger.isBefore) {
        if(Trigger.isUpdate) {
            for(Account acc : trigger.new) {
                String oldType = trigger.oldMap.get(acc.Id).Type;
                System.debug(LoggingLevel.INFO, '*** acc.Update_Status__c: ' + acc.Update_Status__c);
                if(acc.Update_Status__c <> 'Pending Approval') {
                    if(acc.Type <> oldType) {
                        //將Account的Type_New__c賦值，Account的值回滾到以前的值
                        acc.Type_New__c = acc.Type;
                        acc.Type = oldType;
                        acc.Update_Status__c = 'Pending Approval';
                    }
                } else {
                    //TODO
                    //add error or do something
                }
            }
        }
    }

    if(Trigger.isAfter) {
        if(Trigger.isUpdate) {
            List<Main_Information_Update__c> updateList = new List<Main_Information_Update__c>();
            for(Account acc : trigger.new) {
                if(acc.Type_New__c <> null) {
                    Main_Information_Update__c updateItem = new Main_Information_Update__c();
                    updateItem.Type__c = acc.Type_New__c;
                    updateItem.Type_Old__c = acc.Type;
                    updateItem.Update_Status__c = 'Pending Approval';
                    updateItem.Account__c = acc.Id;
                    updateList.add(updateItem);
                }
            }

            //插入數據並提交到審批流
            if(updateList.size() > 0) {
                insert updateList;
                List< Approval.ProcessSubmitRequest> requestList = new List< Approval.ProcessSubmitRequest>();
                for(Main_Information_Update__c item : updateList) {
                    Approval.ProcessSubmitRequest request = new Approval.ProcessSubmitRequest();
                    request.setObjectId(item.Id);
                    requestList.add(request);
                    //List<Approval.ProcessResult> requestResultList =  Approval.process(requestList,false);
                    
                    //TODO
                    //對於提交審批流失敗的數據處理，
                }
                Approval.process(requestList);
            }
        }
    }

}

MainInformationUpdateTrigger：實現審批通過回寫Account以及發送郵件操作

trigger MainInformationUpdateTrigger on Main_Information_Update__c (after update) {
    if(Trigger.isAfter) {
        if(Trigger.isUpdate) {
            List<Account> updateAccountList = new List<Account>();
            //記錄哪些需要發送郵件
            Map<Id,Main_Information_Update__c> mainId2ObjMap = new Map<Id,Main_Information_Update__c>();
            for(Main_Information_Update__c updateItem : Trigger.new) {
                if(updateItem.Update_Status__c == 'Approved' || updateItem.Update_Status__c == 'Rejected') {
                    Account acc = new Account();
                    acc.Id = updateItem.Account__c;
                    acc.Type_New__c = null;
                    //acc.Update_Status__c = updateItem.Update_Status__c;
                    acc.Update_Status__c = null;
                    updateAccountList.add(acc);
                    mainId2ObjMap.put(updateItem.Id, updateItem);
                }
            }

            if(updateAccountList.size() > 0) {
                //TODO
                //try catch處理
                update updateAccountList;

                //發送郵件
                for(Id mainId : mainId2ObjMap.keySet()) {
                    if(mainId2ObjMap.get(mainId).Update_Status__c == 'Approved') {
                        EmailUtil.sendEmail('Approved', mainId2ObjMap.get(mainId));
                    } else {
                        EmailUtil.sendEmail('Rejected', mainId2ObjMap.get(mainId));
                    }
                    
                }
            }
        }
    }
}

至此准備工作結束，下面是幾種方式尋找審批人

一.在代碼里面處理郵件功能（不使用email template）

email template可以配置，更加利於維護，但是有時需要在email template進行相關的特殊操作，比如某些計算，匯總以及日期格式轉換等操作是email template(text/html/custom)無法搞定的功能，所以有時候需要在代碼里面寫郵件的body部分。通過代碼獲取。通過代碼獲取審批人以及審批意見主要需要ProcessInstance以及ProcessInstanceStep兩個表。具體實現如下：

public without sharing class EmailUtil {
    
    //獲取審批意見，審批人，以及其他簡單信息
    public static String getAccountUpdateAprovedEmailBody(Main_Information_Update__c updateItem) {
        String returnBody = '';

        ProcessInstance processResult = [SELECT Id,
                                            (SELECT StepStatus, Comments,ActorId FROM Steps order by createddate desc)
                                         FROM ProcessInstance
                                         WHERE targetObjectId = :updateItem.Id limit 1];
        String actorId = processResult.Steps[0].ActorId;
        String comments = processResult.Steps[0].comments;
        User actor = [select Id,Name from User where Id = :actorId limit 1];
        returnBody += '申請單編號為 : ' + updateItem.Id + '<br/>';
        returnBody += '審批人:' + actor.Name + '<br/>';
        returnBody += '審批意見:' + comments;
        return returnBody;
    }


    public static void sendEmail(String type,Main_Information_Update__c updateItem) {
        String htmlBody;
        htmlBody = getAccountUpdateAprovedEmailBody(updateItem);
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
        email.setSenderDisplayName('System Admin');
        email.setHtmlBody(htmlBody);
        if(type == 'Approved') {
            email.setSubject('審批通過提示');
        } else {
            email.setSubject('審批失敗提示');
        }

        email.setTargetObjectId(updateItem.Account__r.OwnerId);//使用此種方式給org內部User/Contact/Lead發郵件，email limit的count不加1
        email.setSaveAsActivity(false);//如果設置targetObjectId，則必須設置setSaveAsActivity為false
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});
    }
}

二.使用text/html/custom類型的email template：email template這三種類型可以使用merge field，提供了獲取審批流的相關屬性信息，比如審批人，審批意見，審批狀態等，可以直接獲取到。

 

在審批流中的final approve配置email alert即可。

三.使用visualforce EmailTemplate方式獲取審批人和審批意見：上面也說到了，有一些情況下，html,text,custom實現不了，這個時候visualforce emailTemplate就可以上了，但是email template中無法使用到Approval相關的merge field，而且沒有controller，這種情況下，可以使用兩種方式進行解決。

1)在email template中使用apex component,通過component的controller方法獲取需要的相關信息。

 1.在email template中使用component，component傳遞當前記錄的ID，用來處理獲取審批人和審批意見的邏輯。

<messaging:emailTemplate subject="審批通過提示" recipientType="User" relatedToType="Main_Information_Update__c">
    <messaging:htmlEmailBody>
        <p>申請單編號：{!relatedTo.Id}</p>
        <p><c:approvalResult showComponent="ActorName" objId="{!relatedTo.Id}"/></p>
        <p><c:approvalResult showComponent="Comments" objId="{!relatedTo.Id}"/></p>
    </messaging:htmlEmailBody>
</messaging:emailTemplate>

2.approvalResult.Component用來顯示UI

<apex:component controller="ApprovalResultClr" access="global" allowDML="true">
    <apex:attribute name="showComponent" description="approval comments" type="String"/>
    <apex:attribute name="objId" description="approval comments" type="String" assignTo="{!targetObjId}"/>

    <apex:outputPanel rendered="{!showComponent == 'Comments'}">
        審批意見：{!comments}
    </apex:outputPanel>
    <apex:outputPanel rendered="{!showComponent == 'ActorName'}">
        審批人：{!actorName}
    </apex:outputPanel>
</apex:component>

3.ApprovalResultClr用來獲取審批人和審批意見。使用apex class時應該注意，component中綁定的attribute在后台的變量是沒法使用在controller中的，所以不能再構造函數中使用targetObjId.

global without sharing class ApprovalResultClr {
    
    public String targetObjId{get;set;}

    public String comments{get{
        ProcessInstance pi = [SELECT Id,
                                        (SELECT StepStatus, Comments,ActorId FROM Steps order by createddate desc)
                                     FROM ProcessInstance
                                     WHERE targetObjectId = :targetObjId limit 1];
        if(pi <> null) {
            comments = pi.Steps[0].Comments;
        }
        return comments;
    }set;}

    public String actorName{get{
        ProcessInstance pi = [SELECT Id,
                                            (SELECT StepStatus, Comments,ActorId FROM Steps order by createddate desc)
                                         FROM ProcessInstance
                                         WHERE targetObjectId = :targetObjId limit 1];
        if(pi <> null) {
            String actorId = pi.Steps[0].ActorId;
            User actor = [select Id,Name from User where Id = :actorId limit 1];
            actorName = actor.Name;
        }
        return actorName;
    }set;}

}

4.配置在審批流中，使用email template

 2）在Main_Information_Update__c增加Approver__c字段以及comments，在after update的trigger中獲取審批人的信息放到相關字段上，然后配置workflow，當approver__c存在值情況下，發送郵件，郵件模板中的審批人使用Approver__c即可，此種方式不在下面體現了，有興趣的可以自行嘗試。

效果展示

1.對客戶類型進行更改

 2.保存后生成申請單

 

 3.使用審批隊列中名稱為test1的審批人進行審批

4.發送郵件內容展示

總結：此篇通過一個簡單的審批流的例子來展示出幾種不同的方式獲取審批人審批意見信息的方法，使用email template的text/html/custom最為簡單，如果需求的郵件可以使用這些方式實現，建議使用此種方式，便於維護；如果實現不了情況下，也可以使用visual force template方式，不能獲取到的內容可以內嵌apex:component搞定，如果最終這些都不太好操作情況下，退而求其次在代碼里面寫郵件發送的body。