Unity shader學習之Alpha Test

可以在fragment中使用cg的函數--clip來進行透明度測試。

函數定義如下：

void clip(float4 x);

void clip(float3 x);

void clip(float2 x);

void clip(float1 x);

void clip(float x);

參數：裁剪時使用的標量或矢量條件。

描述：如果給定參數的任何一個分量是負數，就會舍棄當前像素的輸出顏色。等同於：

            void clip(float4 x)
            {
                if (any(x < 0))
                    discard;
            }                

轉載請注明出處：http://www.cnblogs.com/jietian331/p/7154001.html

 

shader如下：

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Alpha Test"
{
    Properties
    {
        _MainTex("Main Texture", 2D) = "white" {}
        _Specular("Specular", Color) = (1,1,1,1)
        _Gloss("Gloss", Range(8, 256)) = 8
        _CutOff("Cut Off", Range(0, 1)) = 0
    }

    SubShader
    {
        Pass
        {
            Tags
            {
                "LightMode" = "ForwardBase"
            }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCg.cginc"
            #include "Lighting.cginc"

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;
            float _CutOff;

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                fixed4 color : COLOR;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
                float2 uv : TEXCOORD0;
                float3 worldNormal : TEXCOORD1;
                float3 worldLight : TEXCOORD2;
                float3 worldView : TEXCOORD3;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldLight = normalize(WorldSpaceLightDir(v.vertex));
                o.worldView = normalize(WorldSpaceViewDir(v.vertex));
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                fixed4 albedo = tex2D(_MainTex, i.uv) * i.color;

                // alpha test
                clip(albedo.a - _CutOff);
                // equals to:
                //if(albedo.a - _CutOff < 0)
                //    discard;

                fixed3 ambient = albedo.rgb * UNITY_LIGHTMODEL_AMBIENT.rgb;
                fixed3 diff = albedo.rgb * _LightColor0.rgb * max(0, dot(i.worldNormal, i.worldLight));
                fixed3 halfDir = normalize(i.worldLight + i.worldView);
                fixed3 spec = albedo.rgb * _Specular.rgb * pow(max(0, dot(halfDir, i.worldNormal)), _Gloss);
                fixed3 col = ambient + diff + spec;
                return fixed4(col, 1);
            }

            ENDCG
        }
    }

    Fallback "Diffuse"
}

 

效果如下：

 資源如下：

http://files.cnblogs.com/files/jietian331/transparent_texture.rar

 

有2個問題：

1. 從效果圖中可看出，alpha test 得到的透明效果很“極端”——要么完全透明，要么完全不透明，而且在邊緣上參差不齊，有鋸齒，這是因為在邊界處紋理的透明度變化精度問題。

2. 在片元着色器中discard操作會造成性能的下降。為什么？

因為Unity采用了Early-Z技術來提高GPU的性能，即把深度測試提前，先進行深度測試，再進行片元着色器的着色，這樣被舍棄的片元便不需要再進行片元着色器的處理了，這樣有利於提升GPU的性能。

而這種技術與片元着色器的discard操作是沖突的，因此現代的GPU會判斷片元着色器中的操作是否與提前測試沖突，如果有沖突就會禁用提前測試，也就造成了性能上的下降。