嘗試MatCap類型shader

本文轉載自查看原文 2017-05-19 16:07 5827 unity shader

聽說MatCap能在低端機上做出很漂亮的pbr效果，就嘗試了一下。

MatCap全稱MaterailCapture，里面存的是光照信息，通過法線的xy分量去采樣matcap，得到在該方向法線的光照信息，因為不是實時光照，所以性能好，好不好看就看你的Matcap做得好不好了。下面是簡單的matcap嘗試：

Shader "Unlit/SimpleMatCapShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _MatCap("MatCap", 2D) = "white" {}
        _MatCapFactor("MatCapFactor", Range(0,5)) = 1
        _EnvTex("EnvTex (CubeMap)", Cube) = "_SkyBox" {}
        _EnvFactor("EnvStrength", Range(0,1)) = 0.8
    }

    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 twoUv : TEXCOORD0;//主紋理uv存xy,matCapUv存在zw,這算一種優化
                float4 vertex : SV_POSITION;
                float3 RefDir : TEXCOORD1;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _MatCap;
            half _MatCapFactor;
            samplerCUBE _EnvTex;
            half _EnvFactor;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.twoUv.xy = TRANSFORM_TEX(v.uv, _MainTex);
                //matcap存的其實是：法線中xy分量作為uv，對應的光照顏色信息，即用xy去采樣就好，注：xy必須是歸一化法線中的分量，故z才沒必要
                o.twoUv.zw = UnityObjectToWorldNormal(v.normal).xy;
                o.twoUv.zw = o.twoUv.zw * 0.5 + 0.5;//(-1,1)->(0,1)
                float3 wolrdN = UnityObjectToWorldNormal(v.normal);
                o.RefDir = reflect(-WorldSpaceViewDir(v.vertex), wolrdN);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.twoUv.xy);
                fixed4 mapCapCol = tex2D(_MatCap, i.twoUv.zw);
                fixed4 reflection = texCUBE(_EnvTex, i.RefDir);
                col.rgb = col.rgb * mapCapCol.rgb * _MatCapFactor + reflection.rgb * _EnvFactor;
                return col;
            }
            ENDCG
        }
    }
}