五種方法可以實現批出里的延時，推薦使用方法一，該方法也是使用最多的.
方法一 用ping命令延遲(這是最簡單而且是最常見的)：
@echo off
echo "use ping to delay"
set SLEEP=ping 127.0.0.1 /n
echo %time%
%SLEEP% 4 > nul
echo %time%
pause
方法二 還可以用for循環作延遲，例如：
@echo off
echo "use for to delay"
echo %time%
for /l %%i in (1,1,100) do echo %%i >nul
echo %time%
pause
方法三 用choice命令作延遲：例如
@echo off
echo "use choice to delay"
CHOICE /T 3 /C ync /CS /D y
if errorlevel 1 goto next
:next
:: /T：為暫停秒數（0~9999）這里是暫停10秒的意思
:: /D：為在 nnnn 秒之后（即/T設定的時間）指定默認選項。
:: /c：為指定要創建的選項列表。默認列表是 "YN"。若只作延遲，這里可以設置默認選項為y，暫停后通過if去到默認的標簽處執行后面的命令。
:: 若想了解更多可以在cmd中輸入choice/?
方法四 用vbs作延遲（可精確到毫秒）：
@echo off
echo "use vbs to delay"
echo %time%
call :delay 3000
echo %time%
pause
exit
:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
方法五 純粹用bat延遲（最為復雜，可精確到毫秒）：
@echo off
set /p delay=請輸入需延遲的毫秒數：
set TotalTime=0
set NowTime=%time%
::讀取起始時間，時間格式為：13:01:05.95
echo 程序開始時間：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::讀取起始時間的分鍾數
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將起始時間的秒數轉為毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 讀取現在時間的分鍾數
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將現在時間的秒數轉為毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序結束時間：%time%
echo 設定延遲時間：%delay%毫秒
echo 實際延遲時間：%TotalTime%毫秒
pause