*
* Initialize the program
dev_close_window () //關閉圖形窗口
dev_open_window (0, 0, 768, 576, 'black', WindowHandle) //打開一個原點在（0,0）的寬為768，高為576，背景為黑色的圖形窗口；
dev_update_off ()
dev_set_draw ('margin') //定義區域的填充模式，margin顯示邊緣，fill填充全部區域
dev_set_line_width (3) //定義線寬為3
set_display_font (WindowHandle, 14, 'mono', 'true', 'false') //設置顯示字體（窗口句柄，字體大小，字體，是否加粗，是否斜體）
*
* Calibrate the camera
*
CalTabDescrFile := 'caltab_big.descr' //標定板描述文件
StartCamPar := [0.008,0,0.0000086,0.0000086,384,288,768,576] //相機參數（焦距，畸變，像素尺寸寬，像素尺寸高，中心點坐標寬，中心點坐標高，圖片寬，圖片高）
create_calib_data ('calibration_object', 1, 1, CalibDataID) //創建標定數據模型，即標定的數據將存放於CalibDataID中。
set_calib_data_cam_param (CalibDataID, 0, 'area_scan_division', StartCamPar) //設定相機的初始化參數（標定數據模型句柄，相機索引，相機類型，相機參數）
set_calib_data_calib_object (CalibDataID, 0, CalTabDescrFile) //在標定模型中設定標定對象（對象句柄，標定對象索引，3D標定板文件名）
NumImages := 10
for I := 1 to NumImages by 1
read_image (Image, 'calib/calib-3d-coord-' + I$'02d') //讀取圖像（輸出對象，文件名）
dev_display (Image)//顯示圖片，類似matlab中的imshow
Message := 'Find calibration plate in\nall calibration images (' + I + '/' + NumImages + ')'//
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')//顯示消息（窗口句柄，要顯示的字符，當前的坐標系統，窗口顯示的起始坐標，字體顏色，是否要顯示白色底紋）
* Find the calibration plate
find_calib_object (Image, CalibDataID, 0, 0, I - 1, [], [])//（輸入圖像，標定數據模型句柄，相機索引，標定對象索引，標定對象位置索引，通用參數名稱，通用參數值）
get_calib_data (CalibDataID, 'camera', 0, 'init_params', StartCamPar)//獲取標定數據（標定數據模型句柄，標定數據項的類型，影響項目索引，查詢數據名稱，響應數據）（依靠索引號和數據名稱來返回輸出的數據值。可查詢與模型相關的數據，與相機相關的數據（包括相機的內外參數），與標定對象相關的數據，與標定對象的姿態相關的數據。控制輸出是要查詢的標定數據）
get_calib_data_observ_points (CalibDataID, 0, 0, I - 1, Row, Column, Index, Pose)//獲取觀察點數據（標定數據模型句柄，相機索引，標定對象索引，位姿索引，檢測點行號，檢測點列號，檢測點對應到標定對象觀察點索引，粗略的位姿數據（相對相機））
get_calib_data_observ_contours (Contours, CalibDataID, 'caltab', 0, 0, I - 1)//獲取校准數據輪廓（輸出輪廓，標定數據模型句柄，輪廓名，相機索引，標定對象索引，位姿索引）
gen_cross_contour_xld (Cross, Row, Column, 6, 0.785398)//為每個輸入點生成一個十字形（生成XLD輪廓，輸入點集行號，輸入點集列號，十字形長度，十字形方向）
dev_set_color ('green')//用於定義顯示區域顏色，這個設置到下一個dev_set_color才會被改變；
dev_display (Contours)//顯示對象
dev_set_color ('yellow')//
dev_display (Cross)//
stop()
endfor
disp_continue_message (WindowHandle, 'black', 'true')// 等待用戶操作是否繼續
stop ()
calibrate_cameras (CalibDataID, Error)// 通過最小化過程確定相機的參數
get_calib_data (CalibDataID, 'camera', 0, 'params', CamParam)//
*
* Perform measurements
*
for I := 1 to NumImages by 1
read_image (Image, 'calib/calib-3d-coord-' + I$'02d') //
*
* Now, measure the size of the black border of the plate
get_measure_positions (Image, PlateRegion, CalibDataID, I, Distance, Phi, RowCenter, ColumnCenter)//
gen_rectangle2_contour_xld (Rectangle, RowCenter, ColumnCenter, Phi, Distance * 0.52, 8)//
gen_measure_rectangle2 (RowCenter, ColumnCenter, Phi, Distance * 0.52, 8, 768, 576, 'nearest_neighbor', MeasureHandle)//產生測量句柄，准備提取和矩形主軸垂直的直邊緣
*
measure_pos (Image, MeasureHandle, 1, 40, 'all', 'all', RowEdge, ColumnEdge, Amplitude, Distance1)//提取和矩形或弧垂直的邊緣線
close_measure (MeasureHandle)//
Rows := [RowEdge[0],RowEdge[|RowEdge| - 1]]//
Columns := [ColumnEdge[0],ColumnEdge[|RowEdge| - 1]]//
gen_cross_contour_xld (Cross, Rows, Columns, 16, Phi)//
*
* Transform the two border points into the world coordinate system
get_calib_data (CalibDataID, 'calib_obj_pose', [0,I - 1], 'pose', Pose)//
image_points_to_world_plane (CamParam, Pose, Rows, Columns, 'm', SX, SY)//
distance_pp (SY[0], SX[0], SY[1], SX[1], Width)//
*
* Display results of width measurement
dev_display (Image)//
dev_set_color ('white')//
dev_set_line_width (3)//
dev_display (Rectangle)//
dev_set_color ('green')//
dev_set_draw ('fill')//
dev_set_line_width (2)//
dev_display (Cross)//
dev_set_draw ('margin')//
disp_message (WindowHandle, 'Width = ' + (Width * 100)$'8.3f' + 'cm', 'window', 12, 12, 'black', 'true')//
disp_continue_message (WindowHandle, 'black', 'true')//
stop ()
*
* Now, measure the size of the calibration marks
*
* Extract the ellipses in the image 提取圖像中的橢圓
erosion_circle (PlateRegion, ROI, 17.5)//生成一個圓形結構膨脹元素（，腐蝕區域，元素結構尺寸）
reduce_domain (Image, ROI, ImageReduced)//選取圖像中感興趣的區域
edges_sub_pix (ImageReduced, Edges, 'canny', 1, 20, 60)//使用濾波器來精確檢測邊緣
select_contours_xld (Edges, SelectedEdges, 'contour_length', 20, 99999999, -0.5, 0.5)//根據一些特征選擇XLD輪廓(contour)
* Fit ellipses to extracted edges
fit_ellipse_contour_xld (SelectedEdges, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder)//根據橢圓和橢圓弧近似提取XLD輪廓
MeanRadius1 := mean(Radius1)//
MeanRadius2 := mean(Radius2)//
DevRadius1 := deviation(Radius1)//
DevRadius2 := deviation(Radius2)//
* Transform the ellipses to world coordinates, where they should be circles
* and convert the circles from meters to millimeters so that we can see them.
contour_to_world_plane_xld (SelectedEdges, WorldCircles, CamParam, Pose, 'mm')//
* Fit ellipses to the circles in world coordinates
fit_ellipse_contour_xld (WorldCircles, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, RadiusW1, RadiusW2, StartPhi, EndPhi, PointOrder)//
MeanRadiusW1 := mean(RadiusW1)//
MeanRadiusW2 := mean(RadiusW2)//
DevRadiusW1 := deviation(RadiusW1)//
DevRadiusW2 := deviation(RadiusW2)//
*
* Display results of ellipse measurement
dev_display (Image)//
dev_set_color ('yellow')//
dev_set_line_width (3)//
dev_display (SelectedEdges)//
Message := 'Measured dimensions of the ellipses'//
Message[0] := ' Mean Radius1; Mean Radius2; (Standard deviations [%])'//
Message[1] := 'Image coordinates: ' + MeanRadius1$'5.2f' + 'px; ' + MeanRadius2$'5.2f' + 'px (' + (DevRadius1 / MeanRadius1 * 100)$'4.2f' + ', ' + (DevRadius2 / MeanRadius2 * 100)$'4.2f' + ')'//
Message[2] := 'World coordinates: ' + (MeanRadiusW1 / 10)$'5.2f' + 'cm; ' + (MeanRadiusW2 / 10)$'5.2f' + 'cm (' + (DevRadiusW1 / MeanRadiusW1 * 100)$'4.2f' + ', ' + (DevRadiusW2 / MeanRadiusW2 * 100)$'4.2f' + ')'//
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')//
if (I < 10)
disp_continue_message (WindowHandle, 'black', 'true')//
stop ()
endif
endfor
clear_calib_data (CalibDataID)//