Arduino I2C + 溫濕度傳感器Si7021

 

Si7021是Silicon Labs生產的溫濕度傳感器芯片。其主要特性：

• 濕度精度：誤差典型值+/-2%RH，最大值+/-3%RH（0~80%RH），出廠已校正
• 溫度精度：誤差典型值+/-0.3°C，最大值+/-0.4°C（-10°C~85°C），出廠已校正
• 測量范圍：溫度范圍0~100%RH；溫度范圍最大-40°C~125°C
• 工作電壓：1.9~3.6V
• 低功耗：工作時150μA，待機時60nA
• 接口：I2C，最大速率支持400kbps
• 長期穩定性：濕度≤0.25%RH/yr，溫度≤0.01°C/yr
• 封裝：3x3 mm DFN
• 片上集成加熱器（heater）
• 可選的疏水性保護蓋

與Arduino的連接

由於Arduino UNO的工作電壓是5V，而Si7021無法在5V電平下工作，二者的連接需要電平轉換。轉換的方法是在Si7021和Arduino中間通過I2C Logic Level Converter進行連接。雙向邏輯電平轉換器的原理可參考Philips Semiconductor的應用筆記“Bi-directional level shifter for i2c bus and other systems”。轉換器兩端都自帶了I2C總線需要的上拉電阻。

功能調試

1. Si7021測量過程中，可以選擇讓其將SCL拉低（Hold Master Mode），或者不回應MCU發來的訊息（No Hold Master Mode）。

2. 相對濕度測量包含了溫度測量；溫度測量可以單獨進行。

3. 進行相對濕度或溫度測量時，MCU對測量值低字節是否發送ACK，決定了Si7021是否返回CRC校驗碼。當讀取上次相對濕度測量時的溫度值時，Si7021不回復CRC校驗碼。以下代碼中有一半內容是CRC校驗相關的，並不是必須的，CRC算法也未進行優化。

4. 當Si7021用於環境測量時，芯片放置、PCB熱阻隔設計對測量精度、響應時間有很大影響，具體可參見官方“Si70xx Humidity Sensor Designer's Guide”文檔。

測試代碼

 

/*
Measurement of relative humidity and temperature using Si7021
*/

#include <Wire.h>

#define ADDRESS_SI7021 0x40
#define MEASURE_RH_HOLD 0xE5
#define READ_T_FROM_PRE_RH_MEASUREMENT 0xE0

byte buffer[] = {0, 0, 0};
byte crcHumi;

word outHumi = 0;
word outTemp = 0;
float valueHumi = 0;
float valueTemp = 0;

void setup()
{
    Wire.begin();
    Serial.begin(9600);
}

void loop()
{
    //perform a RH measurement and read back the RH value
    Wire.beginTransmission(ADDRESS_SI7021);
    Wire.write(MEASURE_RH_HOLD);
    Wire.endTransmission();

    Wire.requestFrom(ADDRESS_SI7021, 3);
    if(Wire.available() >= 3)
    {
        buffer[0] = Wire.read(); //high byte
        buffer[1] = Wire.read(); //low byte
        buffer[2] = Wire.read(); //crc
    }
    outHumi = (buffer[0]<<8) | buffer[1];
    crcHumi = CRC8(buffer, 3);
    
    //read temperature from previous RH measurement  
    Wire.beginTransmission(ADDRESS_SI7021);
    Wire.write(READ_T_FROM_PRE_RH_MEASUREMENT);
    Wire.endTransmission();

    Wire.requestFrom(ADDRESS_SI7021, 2);
    if(Wire.available() >= 2)
    {
        buffer[0] = Wire.read(); //high byte
        buffer[1] = Wire.read(); //low byte; no crc
    }
    outTemp = (buffer[0]<<8) | buffer[1];

    valueHumi = 125.0*outHumi/65536 - 6;
    valueTemp = 175.72*outTemp/65536 - 46.85;

    Serial.print(valueHumi);    Serial.print(" \%RH\t");
    Serial.print(valueTemp);    Serial.println(" `C");

    if (crcHumi == 0 && outHumi != 0 && outTemp != 0)
    {
        Serial.println("CRC checked.");
    }
    else
    {
        Serial.println("Error!");
    }

    delay(4000);
}

byte CRC8(byte *data, byte len)
{
    byte crc[8];
    byte result = 0;
    byte i;
    byte doInvert;
    String bitString = MakeString(data, len);

    for (i = 0; i < 8; i++)
    {
        crc[i] = 0;
    }

    for (i = 0; i < bitString.length(); i ++)
    {
        doInvert = (byte(bitString[i] == '1')) ^ crc[7];
        crc[7] = crc[6];
        crc[6] = crc[5];
        crc[5] = crc[4] ^ doInvert;
        crc[4] = crc[3] ^ doInvert;
        crc[3] = crc[2];
        crc[2] = crc[1];
        crc[1] = crc[0];
        crc[0] = doInvert;
    }

    for (i = 0; i < 8; i++)
    {
        bitWrite(result, i, crc[i]);
    }

    return result;
}

String MakeString(byte *data, byte len)
{
    int i, j;
    String tempString[len];
    String bitString="";

    for (i = 0; i < len; i++)
    {
        tempString[i] = String(data[i], BIN);
        int zeros = 8 - tempString[i].length();
        for (j = 0; j < zeros; j++)
        {
            tempString[i] = '0' + tempString[i];
        }
    }

    for (i = 0; i < len; i++)
    {
        bitString = bitString + tempString[i];
    }

    return bitString;
}

 

若連接正常，Si7021將會每隔4秒觸發一次測量，並通過串口打印結果：

參考資料

Silicon Labs - Si7021 Datasheet
Application Note: Bi-directional level shifter for i2c bus and other systems
Application Note: Si70xx Humidity Sensor Designer's Guide
Online CRC Calculation