Arduino I2C + 溫濕度傳感器AM2321

（2015.5.17：本日志的內容有所更新，參見《使用Arduino Wire Library讀取溫濕度傳感器AM2321》。）

AM2321是廣州奧松電子生產的數字式溫濕度傳感器。雖是國產品牌，其精度也可以與國外的主流溫濕度傳感IC媲美。

• 尺寸：11.3x7.8x4mm（長x寬x高）
• 封裝：0.05 pitch PTH
• 工作電壓：2.6~5V
• 功耗：測量時0.5mA，休眠狀態10μA
• 接口：I2C，最大速率100kbps；或單總線通訊
• 分辨率：溫度0.1°C，相對濕度0.1%RH
• 精度：出廠前已校正，室溫時溫度誤差+/-0.3°C，相對濕度誤差+/-3%RH（皆典型值）
• 重復性：溫度+/-0.2°C，相對濕度+/-0.1%RH

美中不足：與國外同精度產品相比，AM2321的重復性和漂移指標偏大；功耗偏高；只能手動焊接，給產品量產帶來不便。

電路連接

AM2321支持5V工作，將電源、地、SCL、SDA四個管腳直接與UNO板子的對應管腳相連。對於Arduino UNO，I2C總線的SDA信號線對應A4管腳，SCL時鍾線對應A5管腳。之后，SCL、SDA線需要通過上拉電阻連接到5V電源，電阻值可取4.7k或10k。

 

功能調試

第一次調試花了不少時間，最終借助示波器才搞定。需留意的幾個問題：

1. I2C地址問題。雖然手冊里寫的地址是0xB8（0b10111000），但實際上器件是采用的7位地址，應該表述成0x5C（0b1011100），代碼中的地址也應寫成0x5C，否則無法通信。

2. 喚醒AM2321時的時序問題。器件不回ACK，且最后一個時鍾下降沿到發stop信號需間隔0.8~3ms。這個時序條件在Arduino的Wire庫中沒有處理的函數，因此只能將A4、A5設置成GPIO，利用bit-banging實現。shiftOut()函數可以實現字節的串行輸出，且速率剛好也是100kbps左右。[注：后面發現即使沒有這個等待時間，傳感器也能正常工作，詭異。]

3. A4、A5管腳在GPIO和硬件I2C之間的功能切換問題。在調用Wire.begin()函數之后，再使用pinMode()或digitalWrite()函數就無效了。發現在Wire.begin()函數中設置了I2C的控制寄存器TWCR，需將TWCR恢復到調用Wire.begin()前的狀態，才可以用GPIO的方式操作A4、A5。

4. 讀返回數據時的時序問題。手冊要求發送地址后，需要等待至少30μs后才能讀取數據。這個功能在Wire庫里也不支持，但直接用庫里的函數（間隔約10μs）讀取，沒有發現有通信錯誤的問題。

5. 傳感器發送數據之后，會觸發下一次溫濕度測量，測量結果供下次數據讀取。因此連續讀取兩次才能獲得當前的溫濕度值，即：第一次讀取的是上一次測量的值，第二次讀取的才是當前測量值。兩次讀取的最小間隔為2秒。

測試代碼

/*
Measurement of temperature and humidity using the AM2321 sensor
Attention: 
    The protocol AM2321 used is not a standard i2c.
    Bit-banging is used to wake up the sensor, 
    and then i2c functions are used to communicate.
Connection:
AM2321           UNO
VDD <--------->  5V
GND <--------->  GND
SCL <---------> SCL(A5)
SDA <---------> SDA(A4)
*/

#include <Wire.h>

#define ADDRESS_AM2321 0x5C //not 0xB8
#define SIGN_WRITE 0x00
#define SDA_PIN A4
#define SCL_PIN A5

byte fuctionCode = 0;
byte dataLength = 0;
byte humiHigh = 0;
byte humiLow = 0;
byte tempHigh = 0;
byte tempLow = 0;
byte crcHigh = 0;
byte crcLow = 0;

int humidity = 0;
int temperature = 0;
unsigned int crcCode = 0;

byte backupTWCR = 0;

void setup()
{
    Serial.begin(115200);
}

void loop()
{
    //step 1. wake up the sensor
    SendWakeUp(); 
    backupTWCR = TWCR;

    //step 2. send command 
    Wire.begin();
    Wire.beginTransmission(ADDRESS_AM2321);
    Wire.write(0x03);
    Wire.write(0x00);
    Wire.write(0x04);
    Wire.endTransmission();

    delayMicroseconds(1500);

    //step 3. read data, and recover the TWCR register
    Wire.requestFrom(ADDRESS_AM2321, 8);
    fuctionCode = Wire.read();
    dataLength = Wire.read();
    humiHigh = Wire.read();
    humiLow = Wire.read();
    tempHigh = Wire.read();
    tempLow = Wire.read();
    crcLow = Wire.read();
    crcHigh = Wire.read();

    //get the result
    humidity = (humiHigh<<8) | humiLow;
    temperature = (tempHigh<<8) | tempLow;
    crcCode = (crcHigh<<8) | crcLow;

    Serial.print(temperature/10.0, 1);    Serial.println(" `C");
    Serial.print(humidity/10.0, 1);    Serial.println(" \%RH");
    CheckCRC();

    //recover the TWCR register, e.g. disable the I2C bus
    TWCR = backupTWCR; 

    delay(4000);
}

void SendWakeUp()
{
    //set pinmode
    pinMode(SCL_PIN, OUTPUT);
    pinMode(SDA_PIN, OUTPUT);
    digitalWrite(SCL_PIN, HIGH);
    digitalWrite(SDA_PIN, HIGH);

    //issue a START condition
    delayMicroseconds(5);
    digitalWrite(SDA_PIN, LOW); 
    delayMicroseconds(5);
    digitalWrite(SCL_PIN, LOW); 
    delayMicroseconds(5);

    //send ADDRESS+W
    shiftOut(SDA_PIN, SCL_PIN, MSBFIRST, ((ADDRESS_AM2321<<1) | SIGN_WRITE));

    //send clock for ack
    pinMode(SDA_PIN, INPUT_PULLUP);// or INPUT mode
    delayMicroseconds(5);
    digitalWrite(SCL_PIN, HIGH);
    delayMicroseconds(5);
    digitalWrite(SCL_PIN, LOW);
    pinMode(SDA_PIN, OUTPUT);
    digitalWrite(SDA_PIN, LOW);
    
    delayMicroseconds(1000);

    //issue a STOP condition
    digitalWrite(SCL_PIN, HIGH);
    delayMicroseconds(5);
    digitalWrite(SDA_PIN, HIGH);
}

void CheckCRC() //from the datesheet
{
    byte backValues[] = {fuctionCode, dataLength, humiHigh, \
        humiLow, tempHigh, tempLow};
    unsigned int crc = 0xFFFF;
    int i;
    int len = 6;
    int j = 0;
    while (len--)
    {
        crc ^= backValues[j];
        j++;
        for (i=0; i<8; i++)
        {
            if (crc & 0x01)
            {
                crc >>= 1;
                crc ^= 0xA001;
            }
            else
            {
                crc >>= 1;
            }
        }
    } 
    if (crc == crcCode)
    {
        Serial.println("CRC checked.");
    }
    else
    {
        Serial.println("CRC Error!");
    }
}

 [注] 后面發現，第一步喚醒時即使直接用Wire庫中的beginTransmission()和endTransmission()函數即可，即使沒有手冊中要求的0.8~3ms等待時間，傳感器也能正常運行。從示波器上看，傳感器不回ACK，硬件I2C等待的時間僅10us左右，卻不影響工作。看來手冊的描述有問題。使用Wire Library標准庫來讀取AM2321，可以參照另一篇日志。

參考資料

奧松官網信息 - AM2321數字溫濕度傳感器
TI - Troubleshooting I2C Bus Protocol 關於I2C調試問題處理的文檔，推薦
拆解國產奧松微小型濕度傳感器AM2321
wangdong/AM2321 - GitHub