分享一位國外大牛寫的不規則物體像素級碰撞檢測算法及詳解

最近在做一個有關投籃的小游戲，需要用到像素級碰撞檢測，as3自帶的hitTestObject顯然無法滿足需要。網上搜尋了一下，在9ria挖墳挖到兩篇好文章：

分享一個超高效的不規則物體碰撞檢測的類~~

[Lii]超高效的不規則物體碰撞檢測<效率優化> 

第一篇文章介紹了一位國外大牛寫的不規則物體像素級碰撞檢測算法，原理是用bitmap繪制兩對象不透明區域，利用混合模式計算出兩對象的相交區域。

第二篇文章則在該算法的基礎上進行了效率的優化，原理是判斷出兩對象發生hitTestObject碰撞后，將碰撞矩形區域縮小至20*20進行判斷，縮小后的檢測結果可能與實際結果不同，因此需要改變縮小倍率進行多次檢測。但效率也已比原算法要優化，特別在針對大尺寸的像素檢測時，效率可提高50%~500%，20*20的小尺寸對象則效率持平。

在實際測試中，優化過的算法，一如網友反映的那樣，當檢測物體不旋轉時檢測正常；當檢測物體是旋轉的情況，檢測結果會有異常，其效果類似於自帶的hitTestObject，無法做到像素級檢測。根據自己游戲的需要，檢測的物體大小並不大，在80*80以內，且一定要能在物體旋轉情況下檢測正常，所以使用了原算法。現附上算法的詳細注釋，更好理解算法原理：

 

package
{
    import flash.display.BitmapData;
    import flash.display.BlendMode;
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    
    import flash.geom.ColorTransform;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    
    /**
     * 高效的不規則物體碰撞檢測類
     */
    public class HitTest
    {
        public function HitTest()
        {
        }
            
        /** 判斷兩物體是否發生碰撞（可調節精度） */
        public static function complexHitTestObject( target1:DisplayObject, target2:DisplayObject,  accuracy:Number = 1 ):Boolean
        {
            return complexIntersectionRectangle( target1, target2, accuracy ).width != 0;
        }
        
        /** 獲取碰撞相交矩形區域 */
        public static function intersectionRectangle( target1:DisplayObject, target2:DisplayObject ):Rectangle
        {
            // 如果有任一對象沒加入顯示列表，或者兩對象hitTestObject的結果為false，則代表兩對象沒有發生碰撞
            if( !target1.root || !target2.root || !target1.hitTestObject( target2 ) ) return new Rectangle();
            
            // 分別得到兩對象的顯示矩形區域
            var bounds1:Rectangle = target1.getBounds( target1.root );
            var bounds2:Rectangle = target2.getBounds( target2.root );
            
            // 得出兩對象相交部分的矩形區域
            var intersection:Rectangle = new Rectangle();
            intersection.x   = Math.max( bounds1.x, bounds2.x );
            intersection.y    = Math.max( bounds1.y, bounds2.y );
            intersection.width      = Math.min( ( bounds1.x + bounds1.width ) - intersection.x, ( bounds2.x + bounds2.width ) - intersection.x );
            intersection.height = Math.min( ( bounds1.y + bounds1.height ) - intersection.y, ( bounds2.y + bounds2.height ) - intersection.y );
            
            return intersection;
        }
        
        /** 獲取碰撞相交矩形區域（可調節精度） */
        public static function complexIntersectionRectangle( target1:DisplayObject, target2:DisplayObject, accuracy:Number = 1 ):Rectangle
        {        
            //不允許設置accuracy小於0，會拋出錯誤
            if( accuracy <= 0 ) throw new Error( "ArgumentError: Error #5001: Invalid value for accurracy", 5001 );
            
            //如果兩對象hitTestObject的結果為false，則代表兩對象沒有發生碰撞
            if( !target1.hitTestObject( target2 ) ) return new Rectangle();
            
            var hitRectangle:Rectangle = intersectionRectangle( target1, target2 );
            // 判斷重疊區域的長寬任一是否超過碰撞臨界值，沒超過則視為兩對象沒有發生碰撞。臨界值默認為1，可根據accuracy調節精度
            if( hitRectangle.width * accuracy <1 || hitRectangle.height * accuracy <1 ) return new Rectangle();
            
            
            //---------------------------------- 核心算法---------------------------------------
            //創建一個用於draw的臨時BitmapData對象
            var bitmapData:BitmapData = new BitmapData( hitRectangle.width * accuracy, hitRectangle.height * accuracy, false, 0x000000 ); 
            
            //把target1的不透明處繪制為指定顏色
            bitmapData.draw( target1, HitTest.getDrawMatrix( target1, hitRectangle, accuracy ), new ColorTransform( 1, 1, 1, 1, 255, -255, -255, 255 ) );
            //把target2的不透明處繪制為指定顏色，並將混合模式設置為DIFFERENCE模式
            bitmapData.draw( target2, HitTest.getDrawMatrix( target2, hitRectangle, accuracy ), new ColorTransform( 1, 1, 1, 1, 255, 255, 255, 255 ), BlendMode.DIFFERENCE );
            
            //target1與target2的不透明處如果發生相交，那么相交部分區域的32位顏色信息必為0xFF00FFFF，即得出兩對象的像素碰撞區域
            var intersection:Rectangle = bitmapData.getColorBoundsRect( 0xFFFFFFFF,0xFF00FFFF );
            
            bitmapData.dispose();
            //----------------------------------  ---------------------------------------
            
            // Alter width and positions to compensate for accurracy
            //前面是乘以accuracy縮放兩對象后，再通過疊加模式計算出相交區域的，因此在此要再除以一次accuracy，恢復原本相交區域大小
            if( accuracy != 1 )
            {
                intersection.x /= accuracy;
                intersection.y /= accuracy;
                intersection.width /= accuracy;
                intersection.height /= accuracy;
            }
            
            intersection.x += hitRectangle.x;
            intersection.y += hitRectangle.y;
            
            return intersection;
        }
        
        
        protected static function getDrawMatrix( target:DisplayObject, hitRectangle:Rectangle, accurracy:Number ):Matrix
        {
            var localToGlobal:Point;
            var matrix:Matrix;
            
            var rootConcatenatedMatrix:Matrix = target.root.transform.concatenatedMatrix;
            
            localToGlobal = target.localToGlobal( new Point( ) );
            matrix = target.transform.concatenatedMatrix;
            matrix.tx = localToGlobal.x - hitRectangle.x;
            matrix.ty = localToGlobal.y - hitRectangle.y;
            
            matrix.a = matrix.a / rootConcatenatedMatrix.a;
            matrix.d = matrix.d / rootConcatenatedMatrix.d;
            if( accurracy != 1 ) matrix.scale( accurracy, accurracy );
            
            return matrix;
        }
                
    }
}