關於AS3的事件移除釋疑

as3.0中的事件Event（位於包flash.events內，繼承至Object，子類有…）

既然是釋疑，主要是在與同事聊天的過程中提及的幾個問題：

1、addEventListener重復監聽是否會被多次調用？

2、如何移除一個匿名函數的監聽？

3、target、currentTarget之間的區別

4、關於Event對象的其它需要注意的地方

 

/*****************************************

*  addEventListener重復監聽是否會被多次調用？

******************************************/

這里重點在於“重復”兩個字，如果監聽一個對象，事件類型相同，監聽函數也是相同，則該監聽函數在事件被觸發時只被調用一次。如果監聽的事件類型不同或是監聽函數不同，則該監聽函數，在該事件類型被觸發時調用。

上面的寫法，onClickHandler函數在對象的CLICK事件被觸發時被調用一次。

使用removeEventListener則會移除該事件，CLICK事件被觸發時不再調用onClickHandler函數。

 

如果監聽函數為匿名函數：

需要移除匿名函數時，一是可以使用變量保存該匿名函數的引用，二是可以在該匿名函數內使用arguments.callee獲取該匿名函數的引用，使用removeEventListener移除對指定事件類型的監聽。

 

使用閉包獲得的匿名函數，每次調用時獲得的匿名函數都不是同一個引用，所以對事件的監聽將會被多次調用。例如有一個函數為：getClickFn()。

當多次使用該函數進行監聽時，將會被多次調用。

 

而addEventListener方法，屬於類EventDispatcher(flash.events，繼承至Object，實現IEventDispatcher)，子類有(DisplayObject…)

該方法有5個參數。addEventListener(eventType, listenerFn, useCapture:Boolean=false, priority:int=0, useWeakReference:Boolean=false);

一般很少用到后面的參數，分別是：

useCapture –> 是否在捕獲階段監聽事件，默認在冒泡階段進行監聽

priority –> 默認為0，也就是監聽事件時，回調監聽函數的“層次”順序，比如之后監聽的函數要在事件觸發時有攔截操作等（取消事件冒泡，阻止其后事件的觸發stopPropagation、stopImmediatePropagation）

useWeakReference –>  是否為弱引用，強烈建議避免使用該參數，不易控制。

hasEventListener用來檢查對象是否為特定的事件類型注冊了監聽器。

 

 

/*****************************************

* target、currentTarget的區別

******************************************/

這個是比較容易混淆，但也非常常見。一句話概括來講就是：

target -- 觸發事件的事件源，currentTarget -- 觸發事件的監聽對象。

 

 

/*****************************************

* 關於Event其它要注意的地方

******************************************/

首先要很清楚，一個事件它經歷了哪幾個階段：捕獲階段 –> 目標階段 –> 冒泡階段

然后就是stopPropagation、stopImmediatePropagation這兩個方法它們的區別，寫個例子就知道了<從方法的說明中就能知道大概意思，寫個Demo加深印象就可以了>

 

寫了一堆，最后還是寫一個demo，比較實際一點：

package
{
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.filters.GlowFilter;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFieldType;
    import flash.text.TextFormat;
    /**
     * ...
     * @author Meteoric
     */
    public class EventDemo extends Sprite
    {

        public function EventDemo()
        {
            initView();
        }

        private var txt:TextField;

        private function getTextGlowFilter(colorVal:uint=0x000000, blur:Number=2):GlowFilter
        {
            var color:uint = colorVal;
            var alpha:Number = 1;
            var blurX:Number = blur;
            var blurY:Number = blur;
            var strength:Number = 255;
            var quality:Number = 1;

            return new GlowFilter(color, alpha, blurX, blurY, strength, quality);
        }

        private function initView():void
        {
            txt = new TextField();
            txt.x = 200;
            txt.y = 50;
            txt.selectable = false;
            txt.mouseEnabled = false;
            txt.autoSize = TextFieldAutoSize.LEFT;
            txt.width = 350;
            //txt.height = 100;
            txt.wordWrap = true;
            txt.multiline = true;
            txt.type = TextFieldType.INPUT;
            txt.background = true;
            txt.backgroundColor = 0x232323;

            var txtfor:TextFormat = new TextFormat();
            txtfor.size = 15;
            txtfor.font = "verdana";
            txtfor.bold = true;
            txtfor.color = 0xffffff;

            txt.defaultTextFormat = txtfor;
            txt.filters = [getTextGlowFilter(0xffcc66)];

            addChild(txt);

            //監聽事件
            var mc:MovieClip = new MovieClip();

            mc.graphics.clear();
            mc.graphics.beginFill(0xcc0000, .7);
            mc.graphics.drawCircle(100, 100, 50);
            mc.graphics.endFill();

            addChild(mc);

            mc.buttonMode = true;


            //重復的監聽只會被調用一次
            mc.addEventListener(MouseEvent.CLICK, onClickHandler);
            mc.addEventListener(MouseEvent.CLICK, onClickHandler);
            mc.addEventListener(MouseEvent.CLICK, onClickHandler);

            //檢測是否綁定了指定的事件
            setTxt('是否監聽了MouseEvent.CLICK事件：' + mc.hasEventListener(MouseEvent.CLICK));

            //移除指定的監聽事件
            mc.removeEventListener(MouseEvent.CLICK, onClickHandler);

            //重復監聽的事件，移除一次后將不再被監聽
            setTxt('是否監聽了MouseEvent.CLICK事件：' + mc.hasEventListener(MouseEvent.CLICK));

            //使用匿名函數進行事件的監聽
            mc.addEventListener(MouseEvent.CLICK, function(e:MouseEvent):void {
                    var _mc:MovieClip = e.target as MovieClip;
                    _mc.removeEventListener(MouseEvent.CLICK, arguments.callee);

                    setTxt('~~haha~~我就是匿名函數【remove】');
                });

            //下面使用getClickFn獲得的是兩個不同的匿名函數引用
            mc.addEventListener(MouseEvent.CLICK, getClickFn(100, function(fn:Function, evt:MouseEvent):void {

                    var _mc:MovieClip = evt.target as MovieClip;

                    _mc.removeEventListener(MouseEvent.CLICK, fn);

                    setTxt("~~hehe~~另外一個匿名函數【remove】");

                }), false, 1);

            mc.addEventListener(MouseEvent.CLICK, getClickFn(50));
        }

        private function onClickHandler(e:MouseEvent):void
        {
            setTxt("----onClickHandler" + getNow());
        }

        private function getClickFn(n:Number=0, fn:Function=null):Function
        {
            var num:Number = n;

            return function(evt:MouseEvent):void {
                fn && fn(arguments.callee, evt);

                setTxt('當前num的值：' + (++num));
            }
        }

        private function getNow():String
        {
            var date:Date = new Date();
            var year:Number = date.getFullYear();
            var month:Number = date.getMonth() + 1;
            var day:Number = date.getDay();

            var hours:Number = date.getHours();
            var minutes:Number = date.getMinutes();
            var seconds:Number = date.getSeconds();

            return [year, month, day].join("-") + " " + [hours, minutes, seconds].join(":");
        }

        private function setTxt(str:String):void
        {
            txt.appendText(str + '\n');

            trace(str);
        }

    }

}