分頁存儲過程

1.支持多列排序，自認為效率比較高的一個存儲過程：

/****** 對象:  StoredProcedure [dbo].[P_viewPage]    腳本日期: 05/14/2012 08:49:34 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO


create PROC [dbo].[P_viewPage]
-- Add the parameters for the stored procedure here
@TableName VARCHAR(200),     --表名
@FieldList VARCHAR(2000),    --顯示列名，如果是全部字段則為*
@PrimaryKey VARCHAR(100),    --單一主鍵或唯一值鍵
@Where VARCHAR(8000),        --查詢條件不含'where'字符，如id>10 and len(userid)>9
@Order VARCHAR(1000),        --排序不含'order by'字符，如id asc,userid desc，必須指定asc或desc
--注意當@SortType=3時生效，記住一定要在最后加上主鍵，否則會讓你比較郁悶
@SortType INT,               --排序規則1:正序asc 2:倒序desc 3:多列排序方法
@RecorderCount INT,          --記錄總數0:會返回總記錄
@PageSize INT,               --每頁輸出的記錄數
@PageIndex INT,              --當前頁數
@TotalCount INT OUTPUT,      --記返回總記錄
@TotalPageCount INT OUTPUT   --返回總頁數
AS
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON
IF ISNULL(@TotalCount,'') = '' SET @TotalCount = 0
SET @Order = RTRIM(LTRIM(@Order))
SET @PrimaryKey = RTRIM(LTRIM(@PrimaryKey))
SET @FieldList = REPLACE(RTRIM(LTRIM(@FieldList)),' ','')
WHILE CHARINDEX(', ',@Order) > 0 OR CHARINDEX(' ,',@Order) > 0
BEGIN
SET @Order = REPLACE(@Order,', ',',')
SET @Order = REPLACE(@Order,' ,',',')
END
IF ISNULL(@TableName,'') = '' OR ISNULL(@FieldList,'') = ''
OR ISNULL(@PrimaryKey,'') = ''
OR @SortType < 1 OR @SortType >3
OR @RecorderCount < 0 OR @PageSize < 0 OR @PageIndex < 0
BEGIN
   PRINT('ERR_00參數錯誤')
   RETURN
END
IF @SortType = 3
BEGIN
IF (UPPER(RIGHT(@Order,4))!=' ASC' AND UPPER(RIGHT(@Order,5))!=' DESC')
BEGIN
   PRINT('ERR_02排序錯誤') RETURN END
END
DECLARE @new_where1 VARCHAR(8000)
DECLARE @new_where2 VARCHAR(8000)
DECLARE @new_order1 VARCHAR(1000)
DECLARE @new_order2 VARCHAR(1000)
DECLARE @new_order3 VARCHAR(1000)
DECLARE @Sql VARCHAR(8000)
DECLARE @SqlCount NVARCHAR(4000)
IF ISNULL(@where,'') = ''
BEGIN
SET @new_where1 = ' '
SET @new_where2 = ' WHERE '
END
ELSE
BEGIN
SET @new_where1 = ' WHERE ' + @where
SET @new_where2 = ' WHERE ' + @where + ' AND '
END
IF ISNULL(@order,'') = '' OR @SortType = 1 OR @SortType = 2
BEGIN
IF @SortType = 1
   BEGIN
   SET @new_order1 = ' ORDER BY ' + @PrimaryKey + ' ASC'
   SET @new_order2 = ' ORDER BY ' + @PrimaryKey + ' DESC'
   END
IF @SortType = 2
   BEGIN
   SET @new_order1 = ' ORDER BY ' + @PrimaryKey + ' DESC'
   SET @new_order2 = ' ORDER BY ' + @PrimaryKey + ' ASC'
   END
END
ELSE
BEGIN
SET @new_order1 = ' ORDER BY ' + @Order
END
IF @SortType = 3 AND CHARINDEX(','+@PrimaryKey+' ',','+@Order)>0
BEGIN
SET @new_order1 = ' ORDER BY ' + @Order
SET @new_order2 = @Order + ','
SET @new_order2 = REPLACE(REPLACE(@new_order2,'ASC,','{ASC},'),'DESC,','{DESC},')
SET @new_order2 = REPLACE(REPLACE(@new_order2,'{ASC},','DESC,'),'{DESC},','ASC,')
SET @new_order2 = ' ORDER BY ' + SUBSTRING(@new_order2,1,LEN(@new_order2)-1)
IF @FieldList <> '*'
   BEGIN
   SET @new_order3 = REPLACE(REPLACE(@Order + ',','ASC,',','),'DESC,',',')
   SET @FieldList = ',' + @FieldList
   WHILE CHARINDEX(',',@new_order3)>0
    BEGIN
    IF CHARINDEX(SUBSTRING(','+@new_order3,1,CHARINDEX(',',@new_order3)),','+@FieldList+',')>0
     BEGIN
     SET @FieldList =
     @FieldList + ',' + SUBSTRING(@new_order3,1,CHARINDEX(',',@new_order3))
     END
    SET @new_order3 = SUBSTRING(@new_order3,CHARINDEX(',',@new_order3)+1,LEN(@new_order3))
    END
   SET @FieldList = SUBSTRING(@FieldList,2,LEN(@FieldList))
   END
END
SET @SqlCount = 'SELECT @TotalCount=COUNT(*),@TotalPageCount=CEILING((COUNT(*)+0.0)/'
+ CAST(@PageSize AS VARCHAR)+') FROM ' + @TableName + @new_where1
IF @RecorderCount = 0
BEGIN
EXEC SP_EXECUTESQL @SqlCount,N'@TotalCount INT OUTPUT,@TotalPageCount INT OUTPUT',
@TotalCount OUTPUT,@TotalPageCount OUTPUT
END
ELSE
BEGIN
SELECT @TotalCount = @RecorderCount
END
IF @PageIndex > CEILING((@TotalCount+0.0)/@PageSize)
BEGIN
SET @PageIndex = CEILING((@TotalCount+0.0)/@PageSize)
END
IF @PageIndex = 1 OR @PageIndex >= CEILING((@TotalCount+0.0)/@PageSize)
BEGIN
IF @PageIndex = 1 --返回第一頁數據
   BEGIN
   SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM '
   + @TableName + @new_where1 + @new_order1
   END
IF @PageIndex >= CEILING((@TotalCount+0.0)/@PageSize) --返回最后一頁數據
   BEGIN
   SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ('
   + 'SELECT TOP ' + STR(ABS(@PageSize*@PageIndex-@TotalCount-@PageSize))
   + ' ' + @FieldList + ' FROM '
   + @TableName + @new_where1 + @new_order2 + ' ) AS TMP '
   + @new_order1
   END
END
ELSE
BEGIN
IF @SortType = 1 --僅主鍵正序排序
   BEGIN
   IF @PageIndex <= CEILING((@TotalCount+0.0)/@PageSize)/2 --正向檢索
    BEGIN
    SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM '
    + @TableName + @new_where2 + @PrimaryKey + ' > '
    + '(SELECT MAX(' + @PrimaryKey + ') FROM (SELECT TOP '
    + STR(@PageSize*(@PageIndex-1)) + ' ' + @PrimaryKey
    + ' FROM ' + @TableName
    + @new_where1 + @new_order1 +' ) AS TMP) '+ @new_order1
    END
   ELSE --反向檢索
    BEGIN
    SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ('
    + 'SELECT TOP ' + STR(@PageSize) + ' '
    + @FieldList + ' FROM '
    + @TableName + @new_where2 + @PrimaryKey + ' < '
    + '(SELECT MIN(' + @PrimaryKey + ') FROM (SELECT TOP '
    + STR(@TotalCount-@PageSize*@PageIndex) + ' ' + @PrimaryKey
    + ' FROM ' + @TableName
    + @new_where1 + @new_order2 +' ) AS TMP) '+ @new_order2
    + ' ) AS TMP ' + @new_order1
    END
   END
IF @SortType = 2 --僅主鍵反序排序
   BEGIN
   IF @PageIndex <= CEILING((@TotalCount+0.0)/@PageSize)/2 --正向檢索
    BEGIN
    SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM '
    + @TableName + @new_where2 + @PrimaryKey + ' < '
    + '(SELECT MIN(' + @PrimaryKey + ') FROM (SELECT TOP '
    + STR(@PageSize*(@PageIndex-1)) + ' ' + @PrimaryKey
    +' FROM '+ @TableName
    + @new_where1 + @new_order1 + ') AS TMP) '+ @new_order1
    END
   ELSE --反向檢索
    BEGIN
    SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ('
    + 'SELECT TOP ' + STR(@PageSize) + ' '
    + @FieldList + ' FROM '
    + @TableName + @new_where2 + @PrimaryKey + ' > '
    + '(SELECT MAX(' + @PrimaryKey + ') FROM (SELECT TOP '
    + STR(@TotalCount-@PageSize*@PageIndex) + ' ' + @PrimaryKey
    + ' FROM ' + @TableName
    + @new_where1 + @new_order2 +' ) AS TMP) '+ @new_order2
    + ' ) AS TMP ' + @new_order1
    END
   END
IF @SortType = 3 --多列排序，必須包含主鍵，且放置最后，否則不處理
   BEGIN
   IF CHARINDEX(',' + @PrimaryKey + ' ',',' + @Order) = 0
    BEGIN
    PRINT('ERR_02') RETURN
    END
   IF @PageIndex <= CEILING((@TotalCount+0.0)/@PageSize)/2 --正向檢索
    BEGIN
    SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ( '
    + 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ( '
    + ' SELECT TOP ' + STR(@PageSize*@PageIndex) + ' ' + @FieldList
    + ' FROM ' + @TableName + @new_where1 + @new_order1 + ' ) AS TMP '
    + @new_order2 + ' ) AS TMP ' + @new_order1
    END
   ELSE --反向檢索
    BEGIN
    SET @Sql = 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ( '
    + 'SELECT TOP ' + STR(@PageSize) + ' ' + @FieldList + ' FROM ( '
    + ' SELECT TOP ' + STR(@TotalCount-@PageSize *@PageIndex+@PageSize) + ' ' + @FieldList
    + ' FROM ' + @TableName + @new_where1 + @new_order2 + ' ) AS TMP '
    + @new_order1 + ' ) AS TMP ' + @new_order1
    END
   END
END
EXEC(@Sql)

--輸出內容
SELECT    @TotalCount as N'@TotalCount',
        @TotalPageCount as N'@TotalPageCount'

2.一個比較創新的存儲過程：(注：此存儲過程利用了sql2005函數，適用於sql20005極其以上版本)

/****** 對象:  StoredProcedure [dbo].[QueryPagination]    腳本日期: 05/14/2012 08:57:04 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

/*-------------------------------------------------
 *            strFieldList       字段列表
 *            strTableList       查詢表列表
 *            strWhereClause     查詢條件
 *            strOrderFld        排序字段
 *            intTotoRecords     (輸入/輸出)總記錄數
 *            intTotoPages       (輸入/輸出)總頁數
 *            intPageSize        每頁記錄數
 *            intCurrentPage     當前頁
 *            intCountToto       是否統計總數
 *                               0:  不容積總數
 *                               1:  統計總數
-------------------------------------------------*/
CREATE       PROCEDURE [dbo].[QueryPagination]
  @t                        char(1)='',
  @strFieldList             varchar(1000)='',
  @strTableList             varchar(300)='',
  @strWhereClause           varchar(1000)='',
  @strOrderFld              varchar(100)='',
  @intCurrentPage           int=1,
  @intPageSize              int=10,
  @intCountToto             int=0,
  @intTotoRecords           int=0 out,
  @intTotoPages             int=0 out
AS

BEGIN

  DECLARE @strSQL nvarchar(4000)
  DECLARE @intCurPage int
  DECLARE @strWhere  varchar(200)
  DECLARE @setvalue_error int

  set @strWhere = '';      -- Where 語句

  If @strWhereClause <> ''
    set @strWhere = @strWhereClause;

 Set xact_abort on
 Begin Tran

  SET @strSQL = 'SELECT COUNT(1) FROM ' + @strTableList + ' ' + @strWhere;

  exec('DECLARE cur_t CURSOR FOR '+ @strSQL)

  OPEN cur_t
  FETCH NEXT FROM cur_t into @intTotoRecords
  while @@fetch_status = 0
  begin
    fetch next from cur_t into @intTotoRecords
  end
  close cur_t
  deallocate cur_t

 Set @setvalue_error =  @@error
 If @setvalue_error<>0
  Begin
    Set @intTotoRecords = -1;
    GOTO DoNext;
    Rollback Tran
  End
  Else
  Begin
    Commit Tran
    GOTO DoNext;
  End


DoNext:
  IF @intTotoRecords<0
    GOTO errTotoRecords;      -- 返回錯誤：記錄總數錯誤

  IF @intPageSize<=0
    GOTO errPageSize;        -- 返回錯誤：每頁記錄數范圍錯誤

  -- 計算出總頁數
  IF @intTotoRecords%@intPageSize <> 0
    set @intTotoPages = cast(@intTotoRecords/@intPageSize as int) + 1;
  ELSE
    set @intTotoPages=cast(@intTotoRecords/@intPageSize as int) ;

  -- 確定待查詢的頁碼數
  -- 如果頁碼數小於等於 0 ，則查詢返回第一頁
  -- 如果頁碼數大於最大頁碼數，則查詢返回最后一頁
  IF @intCurrentPage<=0
    set @intCurPage=1;
  ELSE IF @intCurrentPage>@intTotoPages
    set @intCurPage = @intTotoPages;
  ELSE
    set @intCurPage=@intCurrentPage;


  If @strWhere <> ''
    Set @strSQL = 'SELECT * FROM (SELECT ROW_NUMBER() OVER (ORDER BY ' + @strOrderFld + ') ROWNUM,' + @strFieldList + ' FROM ' + @strTableList + ' ' + @strWhere +
                  ') TAB_TMP WHERE ROWNUM>' + cast((@intCurPage-1)*@intPageSize as varchar) + ' and ROWNUM < ' + cast(@intCurPage*@intPageSize+1 as varchar);
  Else
    Set @strSQL = 'SELECT * FROM (SELECT ROW_NUMBER() OVER (ORDER BY ' + @strOrderFld + ') ROWNUM,' + @strFieldList + ' FROM ' + @strTableList +
                  ') TAB_TMP WHERE ROWNUM>' + cast((@intCurPage-1)*@intPageSize as varchar) + ' and ROWNUM < ' + cast(@intCurPage*@intPageSize+1 as varchar) ;
  
  Execute(@strSQL);

  If @@error<>0
    return @@error;
  Else
    return 0;

errPageSize:
  return -1;

errTotoRecords:
  return -2;

END