SQL Server 數據文件收縮和查看收縮進度

SQL Server在刪除數據后，會重新利用這部分空間，所以如果不是空間緊張的情況下，可以不回收。

回收一般先回收日志文件，因為這個回收速度非常快，可以短時間內清理出一部分可用空間。

回收步驟：

1、查看日志文件大小【一般回收比較大的】 

--適用於RDS For SQL Server2012
SELECT DB_NAME(database_id) AS [Database Name],[Name] AS [Logical Name],[Physical_Name] AS [Physical Name],((size * 8) / 1024) AS [Size(MB)]
FROM sys.master_files
ORDER BY [Size(MB)] DESC
--適用於RDS For SQL Server2008R2，需要對數據庫逐個執行
USE 數據庫名
GO
SELECT a.name as 邏輯文件名, size/128 [totalspace文件大小(兆)],
FILEPROPERTY(a.name, 'SpaceUsed')/128 [usedspace已用空間(兆)],
size/128 - FILEPROPERTY(a.name, 'SpaceUsed')/128 [未用空間(兆)],
FILEPROPERTY(a.name, 'SpaceUsed')*100.0/size [使用率(%)]
FROM sys.database_files a cross join (select recovery_model_desc, log_reuse_wait,log_reuse_wait_desc,is_auto_shrink_on from sys.databases where name=DB_NAME())b
WHERE type=1

 

 2、查看日志文件空間是否可回收【只有log_reuse_wait_desc是NOTHING狀態才可回收】

1.  
   SELECT [name] ,[log_reuse_wait_desc]
2.  
   FROM master.sys.databases
3.  
   WHERE [name] = '數據庫名【第1步獲取】'

 3、回收日志文件空間

DBCC SHRINKFILE(logicalName【第1步獲取】)

常見的日志等待類型是
LOG_BACKUP，日志還沒有備份，所以不能截斷
解決方案：
ACTIVE_TRANSACTION，有活躍事務阻塞了日志截斷
解決方案：
執行 DBCC OPENTRAN ，獲取下長時間的活躍事務的SPID
然后執行 DBCC INPUTBUFFER(SPID) 查看下這個請求SQL，考慮是否可以kill阻塞源，kill后再查下log_reuse_wait，嘗試shrink

 4、查看數據文件大小

USE 數據庫名
GO
SELECT a.name as 邏輯文件名, size/128 [totalspace文件大小(兆)],
    FILEPROPERTY(a.name, 'SpaceUsed')/128 [usedspace已用空間(兆)],
    size/128 - FILEPROPERTY(a.name, 'SpaceUsed')/128 [未用空間(兆)],
    FILEPROPERTY(a.name, 'SpaceUsed')*100.0/size [使用率(%)]
FROM sys.database_files a cross join (select recovery_model_desc, log_reuse_wait,log_reuse_wait_desc,is_auto_shrink_on  from sys.databases where name=DB_NAME())b
WHERE type=0

 5、收縮數據文件【按照經驗，最好每5G循環收縮，如果影響業務，隨時中斷，不會回滾】

1.  
   declare @usedspace int , @totalspace int
2.  
   select @usedspace = xxx, @totalspace =yyy
3.  
   while @totalspace > @usedspace
4.  
   begin
5.  
   set @totalspace = @totalspace -5 * 1024
6.  
   DBCC SHRINKFILE( 邏輯文件名, @totalspace )
7.  
   end

 注：邏輯文件名，usedspace，totalspace從第4步的結果集獲取

6、查看收縮進度【預估值】 

SELECT DB_NAME(database_id) as dbname,
session_id, request_id, start_time
, percent_complete
, dateadd(mi ,estimated_completion_time/60000,getdate ()) as ETC
 FROM sys.dm_exec_requests where percent_complete<>0

 

--查詢當前數據庫備份進度
SELECT   DB_NAME(er.[database_id]) [DatabaseName],er.[command] AS [CommandType],er.[percent_complete]
,er.start_time,CONVERT(DECIMAL(5, 2) , er.[percent_complete]) AS [Complete_Percent]
,CONVERT(DECIMAL(38, 2), er.[total_elapsed_time] / 60000.00) AS [ElapsedTime_m]  
,CONVERT(DECIMAL(38, 2), er.[estimated_completion_time] / 60000.00) AS [EstimatedCompletionTime_m]  
FROM sys.dm_exec_requests AS er  
WHERE er.[command] in ( 'RESTORE DATABASE' ,'BACKUP DATABASE')  --DB_NAME(er.[database_id]) in ('ky2011') and
 
 
--查看數據庫收縮進度
SELECT DB_NAME(er.[database_id]) [DatabaseName],er.[command] AS [CommandType],er.[percent_complete]
,er.start_time,CONVERT(DECIMAL(5, 2) , er.[percent_complete]) AS [Complete_Percent]
,CONVERT(DECIMAL(38, 2), er.[total_elapsed_time] / 60000.00) AS [ElapsedTime_m]  
,CONVERT(DECIMAL(38, 2), er.[estimated_completion_time] / 60000.00) AS [EstimatedCompletionTime_m] 
FROM sys.dm_exec_requests as er WHERE command in ('DbccFilesCompact','AUTOSHRINK')