舉例：輸入hello world和-2，輸出ld
這個簡單。代碼如下
@ echo off&Setlocal enabledelayedexpansion
:標簽1
set 文本=hello world
set 開頭=-2
set 結尾=
set /p 文本=請輸入文本，留空使用默認值hello world
set /p 開頭=請輸入取值開頭位數，正數為從前往后數，負數為從后往前數。留空使用默認值-2
set /p 結尾=請輸入取值結尾位數，正數為從取值開頭往后數，負數為從文本結尾往前數。留空則從文本結尾結束。
if not "%結尾%"="" set 結尾=,%結尾%
set 文本=!文本:~%開頭%%結尾%!
echo 處理結果：%文本%
goto 標簽1
轉載請注明出處
1.變量的范圍
數字計算[±21 4748 3647 整數]，文本[8191個字節](set /p a=<文件 和 ^換行符 可突破該限制，暫不解釋)
2.變量的命名
不允許使用純數字
不建議使用單字母變量
命名不區分大小寫
可以使用中文作為變量名
3.變量擴展-文本(以下示例均以變量%a%示范，實際變量名可以為任何值)
文本替換
%a:文本1=文本2% 文本1替換為文本2（文本2可留空，如%a:文本1=%）
文本替換支持通配符*?等
%a:*文本1=文本2% 開頭到文本1第一次出現的地方替換為文本2（文本2可留空）
文本截取部分
%a:~10% 第10個字之后的內容
%a:~-10% 倒數第10個字之后的內容
%a:~,5% 開頭5個字
%a:~,-5% 開頭 - 倒數第5個字
%a:~10,5% 第10個字之后的5個字
%a:~10,-5% 第10個字 - 倒數第5個字
%a:~-10,5% 倒數第10個字之后的5個字
%a:~-10,-5% 倒數第10個字 - 倒數第5個字
注：文本擴展在for命令中可能不可用
示范：set a=%a:~-10,-5%
3.變量擴展-路徑(以下示例均以變量%a示范)
(此時右邊%可以省略， %~a 和 %~a% 是一樣的)
%a 路徑 "Temp\tmp 12345.txt"
%~a 刪除引號 Temp\tmp 12345.txt
%~fa 完整路徑 D:\AppData\Local\Temp\tmp 12345.txt
%~da 分區 D:
%~pa 路徑 \AppData\Local\Temp\
%~na 文件名 tmp 12345
%~xa 擴展名 .txt
%~sa 短文件名 D:\AppData\Local\Temp\TM3A8C~1.TXT
%~aa 文件屬性 --a--------
%~ta 修改日期 2016/06/02 16:26
%~za 文件大小(字節) 18
%~$b:a 在 目錄b 搜索 文件a 找到的第一個文件。
如果變量b不存在，或者沒有找到文件a，返回空字符串。
需事先給變量b賦值，多個路徑可用分號分隔。命令示例
set b=C:\WINDOWS\system32;C:\WINDOWS;C:\WINDOWS\System32\Wbem
可以組合使用來得到多重結果
%~dpa 分區和路徑 D:\AppData\Local\Temp\
%~nxa 完整文件名 tmp 12345.txt
%~dp$b:a 在 目錄b 搜索 文件a 輸出 文件a 的 分區和路徑
%~ftzaa 類似dir命令的輸出(完整路徑 日期 大小 屬性)
--a-------- 2016/06/02 16:26 18 D:\AppData\Local\Temp\tmp 12345.txt
不組合拆分開也行，比如這樣%~fa %~ta %~za %~aa
注意：路徑擴展僅適用於%0 %1 …%9和for中的單字母變量%%i，若要支持其他變量，考慮使用call
示范
@ echo off & set a=百度貼吧。百度公司。中國公司
echo %%0 %0
echo 文本
echo %%a%% %a%
echo %%a:。=-%% %a:。=-%
echo %%a:百度=%% %a:百度=%
echo %%a:*公司=123%% %a:*公司=123%
echo %%a:~5%% %a:~5%
echo %%a:~-5%% %a:~-5%
echo %%a:~,3%% %a:~,3%
echo %%a:~,-3%% %a:~,-3%
echo %%a:~5,3%% %a:~5,3%
echo %%a:~5,-3%% %a:~5,-3%
echo %%a:~-5,3%% %a:~-5,3%
echo %%a:~-5,-3%% %a:~-5,-3%
pause & echo 產生一個臨時文件>"tmp 12345.txt"
rem 使用上方辦法即可創建帶空格的文件
Call :sub "tmp 12345.txt"
rem 以上一條命令表示跳轉到sub標簽並將變量%1設置為"tmp 12345.txt"
pause & Del "tmp 12345.txt" & goto tu
:sub
echo 路徑
echo %%1 %1
echo %%~1 %~1
echo %%~f1 %~f1
echo %%~d1 %~d1
echo %%~p1 %~p1
echo %%~n1 %~n1
echo %%~x1 %~x1
echo %%~s1 %~s1
echo %%~a1 %~a1
echo %%~t1 %~t1
echo %%~z1 %~z1
echo %%~dp1 %~dp1
echo %%~nx1 %~nx1
echo %%~ftza1 %~ftza1
echo. & Goto :eof
:tu
echo 特殊變量
echo 當前目錄%%CD%% %CD%
echo 當前日期%%DATE%% %DATE%
echo 當前時間%%TIME%% %TIME%
echo 范圍在0-32767的偽隨機數%%RANDOM%% %RANDOM%
echo 錯誤返回碼%%ERRORLEVEL%% %ERRORLEVEL%
echo cmd的版本號%%CMDEXTVERSION%% %CMDEXTVERSION%
echo 顯示當前打開cmd所用的命令%%CMDCMDLINE%% %CMDCMDLINE%
echo 當前最高NUMA節點號%%HIGHESTNUMANODENUMBER%% %HIGHESTNUMANODENUMBER%
pause
截取字符串可以說是字符串處理功能中最常用的一個子功能了，能夠實現截取字符串中的特定位置的一個或多個字符。
set ifo=abcdefghijklmnopqrstuvwxyz0123456789
echo 原字符串（第二行為各字符的序號）：
echo %ifo%
echo 123456789012345678901234567890123456
echo 截取前5個字符：
echo %ifo:~0,5%
echo 截取最后5個字符：
echo %ifo:~-5%
echo 截取第一個到倒數第6個字符：
echo %ifo:~0,-5%
echo 從第4個字符開始，截取5個字符：
echo %ifo:~3,5%
echo 從倒數第14個字符開始，截取5個字符：
echo %ifo:~-14,5%
pause
出處：https://www.zhihu.com/question/356855628/answer/1000353295
=======================================================================================
FOR命令中有一些變量,他們的用法許多新手朋友還不太了解,今天給大家講解他們的用法!
先把FOR的變量全部列出來:
~I - 刪除任何引號(")，擴展 %I
%~fI - 將 %I 擴展到一個完全合格的路徑名
%~dI - 僅將 %I 擴展到一個驅動器號
%~pI - 僅將 %I 擴展到一個路徑
%~nI - 僅將 %I 擴展到一個文件名
%~xI - 僅將 %I 擴展到一個文件擴展名
%~sI - 擴展的路徑只含有短名
%~aI - 將 %I 擴展到文件的文件屬性
%~tI - 將 %I 擴展到文件的日期/時間
%~zI - 將 %I 擴展到文件的大小
%~$PATH:I - 查找列在路徑環境變量的目錄，並將 %I 擴展
到找到的第一個完全合格的名稱。如果環境變量名
未被定義，或者沒有找到文件，此組合鍵會擴展到
空字符串
我們可以看到每行都有一個大寫字母"I",這個I其實就是我們在FOR帶入的變量,我們FOR語句代入的變量名是什么,這里就寫什么.
比如:FOR /F %%z IN ('set') DO @echo %%z
這里我們代入的變量名是z那么我們就要把那個I改成z,例如%~fI改為%~fz
至於前面的%~p這樣的內容就是語法了!
好開始講解:
~I - 刪除任何引號(")，擴展 %I
這個變量的作用就如他的說明,刪除引號!
我們來看這個例子:
首先我們在桌面建立一個名字為temp.txt文本文件,在里面輸入這些內容
"1111
2222"
"3333"
44"44
然后在建立個BAT文件代碼如下:
FOR /F "delims=" %%i IN (temp.txt) DO @echo %%~i
pause
執行后,我們看CMD的回顯如下:
1111
2222"
3333
44"44
和之前temp.txt中的內容對比一下,我們會發現第一行和第三行的引號都消失了,這就是刪除引號~i的作用了!
刪除引號規則如下(BAT兄補充!)
1、若字符串首尾同時存在引號，則刪除首尾的引號；
2、若字符串尾不存在引號，則刪除字符串首的引號；
3、如果字符串中間存在引號，或者只在尾部存在引號，則不刪除。
%~fI - 將 %I 擴展到一個完全合格的路徑名
看例子:
把代碼保存放在隨便哪個地方,我這里就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~fi
pause
執行后顯示內容如下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
當我把代碼中的 %%~fi直接改成%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%i
pause
執行后就會顯示這些內容
test.bat
test.vbs
通過對比,我們很容易就看出沒有路徑了,這就是"將 %I 擴展到一個完全合格的路徑名"的作用
也就是如果%i變量的內容是一個文件名的話,他就會把這個文件所在的絕對路徑打印出來,而不只單
單打印一個文件名,自己動手動實驗下就知道了!
%~dI - 僅將 %I 擴展到一個驅動器號
看例子:
代碼如下,我還是放到桌面執行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~di
pause
執行后我CMD里顯示如下
C:
C:
我桌面就兩個文件test.bat,test.vbs,%%~di作用是,如果變量%%i的內容是一個文件或者目錄名,他就會把他這文件
或者目錄所在的盤符號打印出來!
%~pI - 僅將 %I 擴展到一個路徑
這個用法和上面一樣,他只打印路徑不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~pi
pause
我就不打結果了,大家自己復制代碼看結果吧,下面幾個都是這么個用法,代碼給出來,大家自己看結果吧!
%~nI - 僅將 %I 擴展到一個文件名
只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ni
pause
%~xI - 僅將 %I 擴展到一個文件擴展名
只打印文件的擴展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~xi
pause
%~sI - 擴展的路徑只含有短名
打印絕對短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~si
pause
%~aI - 將 %I 擴展到文件的文件屬性
打印文件的屬性
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ai
pause
%~tI - 將 %I 擴展到文件的日期/時間
打印文件建立的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ti
pause
%~zI - 將 %I 擴展到文件的大小
打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~zi
pause
%~$PATH:I - 查找列在路徑環境變量的目錄，並將 %I 擴展
到找到的第一個完全合格的名稱。如果環境變量名
未被定義，或者沒有找到文件，此組合鍵會擴展到
空字符串
這是最后一個,和上面那些都不一樣,我單獨說說!
我們先在桌面建立一個temp.txt文件,里面寫上這些內容
c:\windows
c:\windows\system32
c:\windows\teett
然后在把這些代碼保存為批處理,放在桌面.
FOR /F "delims==" %%i IN (temp.txt) DO @echo %%~$PATH:i
pause
執行后CMD顯示如下內容
c:\WINDOWS
c:\WINDOWS\system32
ECHO 處於打開狀態。
為什么會這樣呢,還有一行c:\windows\teett呢?
我們直接在CMD里輸入echo %path% 會顯示C:\WINDOWS\system32;C:\WINDOWS;C:\WINDOWS\System32\Wbem
%%~$PATH:i也就是在文本里尋找匹配這個PATH變量值的內容,如果里面的內容和PATH變量相同,就打印出來
如果不相同,就顯示一個空行!
只能適用於PATH變量,其他變量不行,如果要比較很多值,可嘗試把值賦予給PATH變量,我沒測試!
好了,FOR的的變量就介紹到這了!
下面為大家分享下實例：
bat 批處理 字符串 替換函數 和 字符串截取函數
1、字符串替換 好了，符號說到這，現在說%PATH:str1=str2% 上面語法的意思就是：將字符串變量%PATH%中的str1 替換為str2
@echo off
@color 02
set ALL=demo123
echo %ALL%
set VAT=%ALL:1=aaa%
echo %VAT%
---結果是demoaaa23
pause
2、字符串截取 ********************************************** 截取功能統一語法格式為：%a:~[m[,n]]% **********************************************
從第m為截取n長度的字符串,m 為偏移量（缺省為0），n 為截取長度（缺省為全部）,n可以是負數
%a:~0,n% 相當於函數 left(a,n) 取左邊 n 位 %a:~-m% 相當於函數 right （a,m） 取右邊 m 位 %a:~m,n% 相當於函數 mid(a,m+1,n) 從 m+1 位開始取 n 位 %a:~m,-n% 相當於函數 mid(a,m+1,len(a)-m-n),從 m+1 位開始，至倒數 n+1 位 %a:~m % 相當於函數 mid(a,m+1,len(a)-m) 或者 right(a,len(a)-m)，從m+1 位開始取右邊全部。
%a:~[m[,n]]%
%123:~0，1%
結果1
bat截取字符串
@echo off
set str=123456789
echo 第一個字符為：%str:~0,1%
echo 頭兩個字符為：%str:~0,2%
echo 頭5個字符為：%str:~0,5%
echo 去掉最后一個字符后的字符串為：%str:~0,-1%
echo 去掉最后3個字符后的字符串為：%str:~0,-3%
echo 第4個字符為：%str:~3,1%
echo 第4個及其之后的3個字符為：%str:~3,4%
echo 最后一個字符為：%str:~-1%
echo 最后一個字符為：%str:~-1,1%
echo 最后兩個字符為：%str:~-1,2%
echo 倒數第4個字符為：%str:~-4,1%
echo 倒數第4個及其之后的字符為：%str:~-4%
echo 倒數第4個及其之后的1個字符為：%str:~-4,2%
echo 倒數第4個及其之后的2個字符為：%str:~-4,3%
pause
為了說明這個問題,我在這里把批處理取字符,做下進一步的解釋,希望對新手有所啟發
如下:
echo %var:~n,k%
我們在這里對每個參數做個說明:"%var",即我們要從中要截取字符的字符串." ~ "取字
符標志符(我是這么理解的),"n" 我們將其理解為指針,"k"我們將其理解為偏移地址.(注
:指針和偏移地址都是從零開始數的)
我們還是用namejm版主的例子做下說明:
@echo off
set str=123456789
rem 定義一個str字符串為123456789
echo 第一個字符為：%str:~0,1%
rem 指針為0,偏移地址為1,即從第0位開始,取1位
echo 頭兩個字符為：%str:~0,2%
rem 指針為0,偏移地址為2,即從第0位開始,取2位
echo 頭5個字符為：%str:~0,5%
rem 指針為0,偏移地址為5,即從第0位開始,取5位
echo 去掉最后一個字符后的字符串為：%str:~0,-1%
rem 當"k"為負值時,我們可以這樣理解:從指針開始處開始取其后面所有字符,然后減去
后面"abs(k)位"..所以這個句字我們可以做如下解釋:從第0位開始取其全部字符
為:123456789然后從后面減去abs(k)位,所以最后結果為:12345678
echo 去掉最后3個字符后的字符串為：%str:~0,-3%
rem 該句解釋同上↑
echo 最后一個字符為：%str:~-1%
rem 參數"n,"和"k"都可以為缺省,缺省"n,"時可以理解為:從abs(k)位開始取其全部
echo 倒數第4個及其之后的字符為：%str:~-4%
rem 解釋同上↑
echo 最后一個字符為：%str:~-1,1%
rem n為負值時,表示從后面開始截取字符,取k位(此時n應從1開始數)
echo 最后一個字符為：%str:~-1,2%
rem 解釋同上↑
echo 倒數第4個字符為：%str:~-4,1%
rem 解釋同上↑
echo 倒數第4個及其之后的1個字符為：%str:~-4,2%
rem 解釋同上↑
echo 倒數第4個及其之后的2個字符為：%str:~-4,3%
rem 解釋同上↑
pause
出處：https://www.jb51.net/article/50354.htm
=======================================================================================
個人使用
在補充一個我自己使用，在for循環中截取路徑中最后一個字符，判斷是否是反斜線，如果是則截取反斜線前的所有字符
@echo off
setlocal enabledelayedexpansion
set varTarget=E:\_Del\2\,E:\_Del\3 E:\_Del\4 E:\_Del\5\
set distPath=
rem Format data:loop to remove \
for %%a in (%varTarget%) do (
set destTmp=%%~a
if "!destTmp!" neq "" (if "!destTmp:~-1!" equ "\" (set destTmp=!destTmp:~,-1!))
if defined distPath set distPath=!distPath!,
set distPath=!distPath!"!destTmp!"
)
其中varTarget使用了逗號、空格作為分隔符，有反斜線結尾，及無反斜線結尾作為測試