學到了_IDEA從數據庫表生成實體類

目錄

• IDEA連接數據庫
• 選擇表生成實體
• 自定義配置

照舊，先說點廢話，因為以前太蠢了，每次數據庫里的表的字段要去生成實體對象時，都哼哧哼哧自己手動去寫那些該死的字段名，還有可能手寫寫錯，如今我終於悟了，一定有其他人也不想做這件事，代碼就是用來偷懶的

果然IDEA深得我心，可以在連接數據庫之后生成實體類，非常之好用，甚至還可以支持你自定義去轉換類型和加一些注解

但是推薦寫一個空的項目去生成這樣的實體類，然后再復制到自己的真實項目中

好的，廢話完畢！ 正文開始

IDEA連接數據庫

IDEA右邊側欄有個DataSource，可以通過這個來連接數據庫，我們先成功連接數據庫

點擊進入后填寫數據庫進行連接，注意記得一定要去Test Connection 確保正常連接

選擇表生成實體

選擇一個表右鍵，選擇如下選項進行生成，會彈出一個選擇存放實體類路徑的窗口，選擇放在合適的目錄下就好

自定義配置

如果發現數據庫的某些字段沒有轉換成你需要的字段，如varbinary會自動轉換成String，但你想讓其轉換為byte或其他類型，可以更改groovy腳本，在project中的如下位置找到groovy腳本

可以在文件的這一部分更改映射關系

如果想在生成的字段上加一些注釋，可以在groovy腳本中找到generate函數，然后在其輸出這里進行更改，如我在這里增加了@TableField注解

比較完善的一個groovy腳本，可以直接粘貼內容替換原來的groovy腳本

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

//自定義包名
packageName = ""
typeMapping = [
        //類型映射
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)int/)                             : "Long",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "BigDecimal",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}


def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter {out -> generate(out, className, fields,table)}
}

def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
    out.println "import javax.persistence.Column;"
    out.println "import javax.persistence.Entity;"
    out.println "import javax.persistence.Table;"
    out.println "import java.io.Serializable;"
    out.println "import lombok.Data;"
    out.println("import javax.persistence.Id;")

    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    out.println "/**\n" +
            " * @Title "+ table.getName()+" \n" +
            " * @Description  \n" +
            " * @author liyuan \n" +
            " * @Date "+ new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
            " */"
    out.println ""
    out.println "@Entity"
    out.println "@Table ( name =\""+table.getName() +"\" )"
    out.println "@Data"
    out.println "public class $className  implements Serializable {"
    out.println ""
    out.println genSerialID()
    fields.each() {
        out.println ""

        //添加字段注釋
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

        //為字段添加注解
        if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"

        //顯示變量
        out.println "\tprivate ${it.type} ${it.name};"
    }

    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment(),
                annos: "\t@Column(name = \""+col.getName()+"\")"]
        if("id".equals(Case.LOWER.apply(col.getName())))
            comm.annos +="\n\t@Id"
        fields += [comm]
    }
}

def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    s = s[1..s.size() - 1]
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel){
    if(!str || str.size() <= 1)
        return str

    if(toCamel){
        String r = str.toLowerCase().split('_').collect{cc -> Case.LOWER.apply(cc).capitalize()}.join('')
        return r[0].toLowerCase() + r[1..-1]
    }else{
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect{cc -> ((char)cc).isUpperCase() ? '_' + cc.toLowerCase() : cc}.join('')
    }
}

static String genSerialID()
{
    return "\tprivate static final long serialVersionUID =  "+Math.abs(new Random().nextLong())+"L;"
}

done! 又是學到了的一天