批處理啟動/停止Windows服務（升級版）

goto explain
    學習批處理寫法，其中用到的內容包含：批處理函數參數傳遞、字符串分割、讀寫文件、本地變量延遲以及注釋等。
    這里以批處理控制幾個指定的Windows服務的啟動/停止以及服務狀態設置為例。    
:explain

@echo off
rem Run as administrator
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
rem Switch to the file current directory
cd /d "%~dp0"

rem 設置本地為延遲擴展
setlocal enabledelayedexpansion 

:flag_loop

cls
rem echo %0

rem 如果要增加其他的服務，只需要增加服務名稱(服務名稱可以包含空格)，按分號分隔（僅修改這一處地方就可以）
set WS=MariaDB10.4;MariaDB10.5;MSSQLSERVER;aspnet_state;ZyrhDeviceService;


rem 數組下標開始，這里特意設計為從1開始
set WS_START=1
rem 數組元素數量，自動增長
set WS_COUNT=1

:flag_split
rem 分割字符串WS，按分號;分隔
rem tokens=1*，tokens表示分段的方式，tokens=1*表示第一個分隔符;之前的作為一部分,剩下的(*表示)作為一部分。這兩部分在循環體總可以用%%a表示第一部分，%%b表示第二部分
rem delims=;表示以分號作為分隔符
for /f "tokens=1* delims=;" %%a in ("%WS%") do (
    rem echo n:%%a
    rem 將分割出來的字符串賦值給數組元素
    set WS[%WS_COUNT%]="%%a"
    set /a WS_COUNT+=1
    rem 將截取剩下的部分賦給變量WS
    set WS=%%b
)
rem 如果還有剩余,則繼續分割
if defined WS goto :flag_split

set /a WS_COUNT-=1

echo   [:Loop] Action Type:
echo   S - Start, X - Stop, C - Config, N - Name, D - Description

echo.
echo   Please select service id:
for /l %%n in (%WS_START%, 1, %WS_COUNT%) do ( 
   rem echo wn:!WS[%%n]! 
   rem 啟用了變量延遲，變量需要用!!括起來
   call :flag_state !WS[%%n]! %%n
)

:flag_type
echo.
set /p "input=  [:Type]  Please input service id (%WS_START% - %WS_COUNT%) (R - :Loop, Q - Exit) : "

::獲取輸入字符串的長度
call :get_len %input% len

set type=%input%
set action_str=

rem 如果輸入2個（或2個以上）字符，如S1或X2等，則拆分前2個字符,第1個字符作為action動作：S-啟用，X-停止，后面的字符作為類型數字
rem 按照之前的設計規則，應該是1S而不是S1，這樣做的目的是為了兼容類型超出10個以上，10S處理起來比S10要麻煩很多
if %len% geq 2 (
    set action_str=%input:~0,1%
    set type=%input:~1%
    call :upper_case !action_str! action_str
)
call :upper_case %type% type
set input=%type%
set /a num=%type%*1

call :check_exit %type%

if %type%==%num% (
    if %num% gtr %WS_COUNT% (
        echo   Please enter the numbers %WS_START% - %WS_COUNT% .
        goto flag_type
    ) else if %num% leq 0 (
        echo   Please enter the numbers %WS_START% - %WS_COUNT% !
        goto flag_type
    ) else (
        call :flag_state !WS[%type%]! %type%
        if "%action_str%" == "S" (
            call :flag_start "!WS[%type%]!" %type%
        ) else if "%action_str%" == "X" (
            call :flag_stop "!WS[%type%]!" %type%
        ) else if "%action_str%" == "C" (
            call :flag_config "!WS[%type%]!"
        ) else if "%action_str%" == "N" (
            call :flag_name "!WS[%type%]!"
        ) else if "%action_str%" == "D" (
            call :flag_desc "!WS[%type%]!"
        ) else (
            call :flag_action !WS[%type%]! %type%
        )
    )
) else if "%type%" == "R" (
    goto flag_loop
) else (
    goto flag_type
)

goto comments
    函數
    根據用戶輸入確定不同的操作
    參數1: 要操作的服務名稱，字符串
    參數2: 要操作的服務的編號（即上面打印的服務列表的編號ID）
:comments
:flag_action
    echo.
    rem 這里的□ (<0x08>)是一個退格符，是為了顯示出后面的兩個空格位置
    set /p "action=  Please input action key (S - Start, X - Stop, C - :Config, N - :Name, D - :Desc, R - :Type, Q - Exit) : "

    call :upper_case %action% action

    call :check_exit %action%

    if "%action%" == "S" (
        call :flag_start "%~1" %~2
    ) else if "%action%" == "X" (
        call :flag_stop "%~1" %~2
    ) else if "%action%" == "C" (
        call :flag_config "%~1"
    ) else if "%action%" == "N" (
        call :flag_name "%~1"
    ) else if "%action%" == "D" (
        call :flag_desc "%~1"
    ) else if "%action%" == "R" (
        goto flag_type
    ) else (
        goto flag_action
    )
goto:eof

goto comments
    函數
    查詢服務狀態，並返回明確的服務狀態，如 RUNNING 或 STOPPED，接受兩個參數
    參數1: 要查詢的服務名稱，字符串
    參數2: 接受返回結果的變量
:comments
:flag_state
    set st=
    call :flag_qc "%~1" %~2 st

    set fn="%~1_tmp_123.log"
    rem 查詢服務狀態信息，提取 STATE 內容並寫入到文件中
    sc query "%~1" |findstr "STATE" > %fn%

    set value=
    rem 讀取文件內容到value變量
    set /p value=<./%fn%

    del %fn%

    set index=2
    rem 按冒號:分割字符串，並提取第2部分的內容（下標是從1開始的）
    for /F "tokens=%index% delims=:" %%a in ("%value%") do set value=%%a

    rem 按空格分割字符串，並提取第2部分的內容（下標是從1開始的）
    for /F "tokens=%index% delims= " %%a in ("%value%") do set value=%%a
    echo   %~2  %~1            ----  %value%    ----  %st%
goto:eof

:flag_qc
    set fn="%~1_qc_123.log"
    rem 查詢服務配置信息，提取 START_TYPE 內容並寫入到文件中
    sc qc "%~1" |findstr "START_TYPE" > %fn%

    set value=
    rem 讀取文件內容到value變量
    set /p value=<./%fn%

    del %fn%

    set index=2
    rem 按冒號:分割字符串，並提取第2部分的內容（下標是從1開始的）
    for /F "tokens=%index% delims=:" %%a in ("%value%") do set value=%%a

    rem 截取字符串，從第5個字符開始（空格也算是字符）
    set value=%value:~5%

    rem 替換雙空格為單個空格
    set value=%value:  = %

    rem echo   %~2     %~1         --------  %value%

    rem 將返回值賦值給變量3
    set %~3=%value%
goto:eof

:flag_start
    echo   start %~1
    sc start "%~1"
    timeout 2
    call :flag_state "%~1" %~2
    goto flag_type
goto:eof

:flag_stop
    echo   stop %~1
    sc stop "%~1"
    timeout 2
    call :flag_state "%~1" %~2
    goto flag_type
goto:eof

:flag_config
    echo.
    set /p "config=  Please input config key (1 - Automatic, 2 - Manual, 3 - Disabled, 4 - Delayed Auto, R - :Type, Q - Exit) : "

    call :upper_case %config% config

    call :check_exit %config%

    rem 設置服務啟動方式 auto - Automatic, demand - Manual, disabled - Disabled, delayed-auto - Automatic (Delayed Start)
    if "%config%" == "1" (
        rem start= 這里需要一個空格
        sc config "%~1" start= auto
    ) else if "%config%" == "2" (
        sc config "%~1" start= demand
    ) else if "%config%" == "3" (
        sc config "%~1" start= disabled
    ) else if "%config%" == "4" (
        sc config "%~1" start= delayed-auto
    ) else if "%config%" == "R" (
        goto flag_type
    ) else (
        goto flag_config
    )
goto:eof

:flag_name
    echo.
    set /p "name=  Please input service name (R - :Type, Q - Exit) : "

    call :check_exit %name%

    if "%name%" == "R" (
        goto flag_type
    ) else (
        sc config "%~1" DisplayName= "%name%"
        goto flag_type
    )
goto:eof

:flag_desc
    echo.
    set /p "desc=  Please input service description (R - :Type, Q - Exit) : "

    call :check_exit %desc%

    if "%desc%" == "R" (
        goto flag_type
    ) else (
        sc description "%~1" "%desc%"
        goto flag_type
    )
goto:eof

:check_exit
    if "%~1" == "Q" (
        goto flag_exit
    ) else if "%~1" == "EXIT" (
        goto flag_exit
    ) else if "%~1" == "QUIT" (
        goto flag_exit
    )
goto:eof

:upper_case
    set val=%~1
    for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set val=%%val:%%i=%%i%%
    set %~2=%val%
goto:eof

:lower_case
    set val=%~1
    for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do call set val=%%val:%%i=%%i%%
    set %~2=%val%
goto:eof

:get_len
    set str=%~1
    set len=0
    :label
    set /a len+=1
    set str=%str:~0,-1%
    if defined str goto :label
    ::echo len:%len%
    set %~2=%len%
goto:eof

:flag_exit
exit