Delphi 字符串替換 SysUtils.StringReplace

Delphi 字符串替換 SysUtils.StringReplace

StringReplace  返回一個字符串，其中一個子字符串替換為另一個子字符串。

原型：

function StringReplace(const S, OldPattern, NewPattern: string;
  Flags: TReplaceFlags): string;
var
  SearchStr, Patt, NewStr: string;
  Offset: Integer;
begin
  if rfIgnoreCase in Flags then
  begin
    SearchStr := AnsiUpperCase(S);
    Patt := AnsiUpperCase(OldPattern);
  end else
  begin
    SearchStr := S;
    Patt := OldPattern;
  end;
  NewStr := S;
  Result := '';
  while SearchStr <> '' do
  begin
    Offset := AnsiPos(Patt, SearchStr);
    if Offset = 0 then
    begin
      Result := Result + NewStr;
      Break;
    end;
    Result := Result + Copy(NewStr, 1, Offset - 1) + NewPattern;
    NewStr := Copy(NewStr, Offset + Length(OldPattern), MaxInt);
    if not (rfReplaceAll in Flags) then
    begin
      Result := Result + NewStr;
      Break;
    end;
    SearchStr := Copy(SearchStr, Offset + Length(Patt), MaxInt);
  end;
end;

描述：

• StringReplace將OldPattern指定的子字符串替換為NewPattern指定的子字符串。StringReplace假定源字符串可能包含多字節字符。
• S是源字符串，其子字符串已更改。
• OldPattern是用來定位並替換為NewPattern的子字符串。
• NewPattern是替換OldPattern的子字符串。
• Flags是一組標志，用於控制StringReplace如何定位和替換OldPattern的引用。如果標志不包括rfReplaceAll，StringReplace只替換S中第一次出現的OldPattern。否則，StringReplace將用NewPattern替換OldPattern的所有實例。如果Flags參數包括rfIgnoreCase，則比較操作不區分大小寫。

附.TReplaceFlags 類型（TReplaceFlags指示如何執行搜索和替換操作）

type TReplaceFlags = set of (rfReplaceAll, rfIgnoreCase);

參數：

• rfReplaceAll  //替換所有事件。如果不存在此標志，則只替換第一個出現的目標子字符串。
• rfIgnoreCase  //不敏感地匹配子字符串大小寫的出現。如果不存在此標志，則只考慮區分大小寫的匹配。

示例：

var
    sStr: String;
begin
    sStr:= 'Hi TaoRoy 2022 ';
    ShowMessage(StringReplace (sStr, 'o', 'i', []));//Hi TaiRoy 2022  替換第一個

    sStr:= 'Hi TaoRoy 2022 ';
    ShowMessage(StringReplace (sStr, 'o', 'i', [rfReplaceAll]));  //Hi TaiRiy 2022  替換所有
    
    sStr:= 'Hi TaoRoy 2022 Open the world ';
    ShowMessage(StringReplace (sStr, 'o', 'i', [rfReplaceAll])); //Hi TaiRiy 2022 Open the wirld  //替換所有，區分大小寫
    
    sStr:= 'Hi TaoRoy 2022 Open the world ';
    ShowMessage(StringReplace (sStr, 'o', 'i', [rfReplaceAll, rfIgnoreCase]));//Hi TaiRiy 2022 ipen the wirld  //替換所有，不區分大小寫

　　

 

 

 

創建時間：2022.02.17　　更新時間：