win10/11清除默認打開方式

win10清楚默認打開方式的方法

一.手動清除

步驟1：

按Windows鍵+R鍵呼出“運行”，在運行對話框中輸入Regedit 打開注冊表編輯器 定位到如下分支：HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion \Explorer\FileExts(后綴名)\OpenWithList

右側窗口即顯示出某某文件的“打開方式”中的各種應用程序 用鼠標右擊要清除的項目選擇“刪除”即可，建議先備份一下。

步驟2：

例如定位到如下分支： HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts.mp3\OpenWithList, 右側窗口即顯示出MP3文件“打開方式”中的各種應用程序，用鼠標右擊要清除的項目，選擇“刪除”即可，其他類型文件的“打開方式”菜單也可做同樣清理。

參考

---

二.自動清除指定文件類型的默認打開方式

方法一

打開記事本，復制粘貼下列代碼：

@echo off
setlocal enabledelayedexpansion
set "ext=%~x1"
:loop
if defined ext set "ext=!ext:"=!"
if defined ext goto ok
echo 如果你不知道文件的擴展名，關閉批處理然后把文件拖到批處理文件的圖標上。
set /p "v=請輸入擴展名（如txt）然后回車："
for /f "delims=" %%i in (".!v!") do set "ext=%%~xi"
goto loop
:ok
echo 擴展名：!ext!
pause
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\!ext!" /f
reg query "HKCR\!ext!" /ve|find /i "!ext:~1!_auto_file">nul
if not errorlevel 1 (
reg delete "HKCR\!ext!" /ve /f
reg delete "HKCR\!ext:~1!_auto_file" /f
)
taskkill /im explorer.exe /f
start %windir%\explorer.exe
pause
goto :eo

然后另存為.bat文件

打開保存的bat文件就會出現

然后輸入需要清除默認打開方式的文件類型后綴，按兩次回車即可

參考

注意:此種方式測試出現權限問題失敗

---

方法二

使用系統設置無法清除默認應用（只能修改和設置），清除操作需要通過修改注冊表完成。

操作步驟

1. 創建一個CMD文件，輸入以下內容：

@echo off
set /p ext=請輸入要清除的后綴（不加.）：
 
echo.希望清除的后綴默認值：.%ext%
pause
 
::使用命令清除
assoc .%ext%=
 
::清除相關注冊表項
echo.Windows Registry Editor Version 5.00>edit.reg
echo.[-HKEY_CLASSES_ROOT\.%ext%]>>edit.reg
echo.[-HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%ext%]>>edit.reg
 
start edit.reg
echo.確認導入后按任意鍵繼續……
pause >nul
del edit.reg
 
::重啟資源管理器
taskkill /f /im explorer.exe
start explorer.exe

2. 雙擊直接運行該文件，並按要求輸入內容和導入注冊表。

注：若出現中文亂碼請使用ASCII編碼保存該文件。

3. 完成后會自動重啟資源管理器。

參考

已經親自測試沒問題