一、實驗目的
- 理解標志寄存器用途，理解常用標志位CF, ZF, OF, SF, TF, IF的用途和意義。
- 理解條件轉移指令je, jz, ja, jb, jg, jl等的跳轉原理，掌握組合使用匯編指令cmp和條件轉移指令實現分支和循環的用法
- 了解軟中斷指令的用法，體驗和理解中斷原理
- 綜合應用尋址方式和匯編指令完成簡單應用編程
二、實驗結論
1. 實驗任務1
task1.asm
assume cs:code, ds:data
data segment
x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment
start:
mov ax, data
mov ds, ax
mov si, offset x
mov di, offset y
call add128
mov ah, 4ch
int 21h
add128:
push ax
push cx
push si
push di
sub ax, ax
mov cx, 8
s: mov ax, [si]
adc ax, [di]
mov [si], ax
inc si
inc si
inc di
inc di
loop s
pop di
pop si
pop cx
pop ax
ret
code ends
end start
問題
line31-line34的4條inc指令，能否替換成如下代碼？
add si, 2
add di, 2
答：不能，因為inc指令不會影響CF進位標志位而add指令會，替換成add會對后面的adc指令產生影響，可能導致計算錯誤。
調試運行
數據段做加和之前：
數據段做加和之后：
可以看到原本x的位置變成x+y，原本y的位置不變。
2. 實驗任務2
task2.asm
assume cs:code, ds:data
data segment
str db 80 dup(?)
data ends
code segment
start:
mov ax, data
mov ds, ax
mov si, 0
s1:
mov ah, 1
int 21h
mov [si], al
cmp al, '#'
je next
inc si
jmp s1
next:
mov ah, 2
mov dl, 0ah
int 21h
mov cx, si
mov si, 0
s2: mov ah, 2
mov dl, [si]
int 21h
inc si
loop s2
mov ah, 4ch
int 21h
code ends
end start
調試運行
可以看到從鍵盤輸入一串字符，輸入#結尾后程序在下一行打印出輸入的字符串。
問題
① line11-18實現的功能：先保存當前輸入字符，再比較當前輸入字符是否為'#'，是跳轉到next，不是繼續輸入下個字符；
②line20-22實現的功能：輸出換行符；
③line24-30實現的功能：依次輸出鍵入的一串字符（不包括結尾的#）。
3. 實驗任務3
task3.asm
assume ds:data,cs:code,ss:stack
data segment
x dw 91, 792, 8536, 65521, 2021
len equ $ - x
data ends
stack segment
db 80 dup(0)
stack ends
code segment
start:
mov ax, data
mov ds, ax
mov ax, stack
mov ss, ax ;棧段
mov sp, 50h
mov si, 0 ;數據段指針
mov cx, 5 ;5個數，循環5次
mov bx, 0ah ;存除數10
s:
push cx ;cx在子程序中會用到，先存入棧
mov ax, [si] ;將待處理的數放入ax
call printNumber ;調用printNumber子程序，轉換成10進制並輸出
call printSpace ;調用printSpace子程序，輸出空格
add si, 2 ;指向下一個數
pop cx ;取出cx的值
loop s
jmp exit ;退出程序
printNumber: ;轉換成10進制並輸出
mov di, 0 ;計數轉化后的位數
s1: ;從低位到高位，每次求出一位
mov dx, 0
div bx ;除10
push dx ;余數入棧
inc di ;計數+1
cmp ax, 0 ;當前商是否為0
je s2 ;商為0，退出循環；不為0，繼續除
jmp s1
s2:
mov cx, di
s3: ;開始出棧
pop ax
add ax, 30h ;轉化成對應字符ASCII碼
mov dl, al
mov ah, 2
int 21h ;打印輸出
loop s3
ret
printSpace: ;打印空格
mov ah, 2
mov dl, " "
int 21h
ret
exit:
mov ah, 4ch
int 21h
code ends
end start
調試運行
可以看到成功打印轉換后的10進制數。
4. 實驗任務4
task4.asm
assume ds:data,cs:code
data segment
str db "assembly language, it's not difficult but tedious"
len equ $ - str
data ends
code segment
start:
mov ax, data
mov ds, ax
mov si, 0 ;數據段指針
mov cx, len ;字符串長度
call strupr ;調用小寫轉大寫子程序
jmp exit ;退出程序
strupr:
s:
mov al, [si] ;當前字符放入al
cmp al, 61h ;ASCII碼在[61h,7ah]為小寫字母
jb s1
cmp al, 7ah
ja s1
and al, 0dfh ;二進制位第三位變為0，小寫轉大寫
mov [si], al
s1:
inc si ;下個字符
loop s
ret
exit:
mov ah, 4ch
int 21h
code ends
end start
調試運行
子程序調用前：
子程序調用后：
可以看到字符串中的小寫字母成功轉成大寫字母。
5. 實驗任務5
task5.asm
assume cs:code, ds:data
data segment
str1 db "yes", '$'
str2 db "no", '$'
data ends
code segment
start:
mov ax, data
mov ds, ax
mov ah, 1
int 21h ; 從鍵盤輸入字符
mov ah, 2
mov bh, 0
mov dh, 24 ; 設置光標位置在第24行
mov dl, 70 ; 設置光標位置在第70列
int 10h ; 設置光標位置
cmp al, '7'
je s1
mov ah, 9
mov dx, offset str2
int 21h ; 顯示標號str2處的字符串
jmp over
s1: mov ah, 9
mov dx, offset str1
int 21h ; 顯示標號str1處的字符串
over:
mov ah, 4ch
int 21h
code ends
end start
調試運行
輸入7：
輸入其他字符：
可以看到，如果輸入7，在24行70列處打印str1；輸入其他字符，在24行70列打印str2。
程序分析
功能：從鍵盤鍵入一個字符，如果是7，在光標位置（24行70列）打印str1；是其他字符，在光標位置打印str2。
分析：
line13-14 鍵盤鍵入一個字符，存入al
line16-20 設置光標位置，24行70列
line22-26 al中字符不為7，在光標位置打印str2
line30-32 al中字符為7，在光標位置打印str1
6. 實驗任務6
task6_1.asm
;功能：裝入42號程序中斷處理程序
assume cs:code
code segment
start:
; 42 interrupt routine install code
mov ax, cs
mov ds, ax
mov si, offset int42 ; set ds:si
mov ax, 0
mov es, ax
mov di, 200h ; set es:di
mov cx, offset int42_end - offset int42
cld
rep movsb
; set IVT(Interrupt Vector Table)
mov ax, 0
mov es, ax
mov word ptr es:[42*4], 200h
mov word ptr es:[42*4+2], 0
mov ah, 4ch
int 21h
int42:
jmp short int42_start
str db "welcome to 2049!"
len equ $ - str
; display string "welcome to 2049!"
int42_start:
mov ax, cs
mov ds, ax
mov si, 202h
mov ax, 0b800h
mov es, ax
mov di, 24*160 + 32*2
mov cx, len
s: mov al, [si]
mov es:[di], al
mov byte ptr es:[di+1], 2
inc si
add di, 2
loop s
iret
int42_end:
nop
code ends
end start
task6_2.asm
assume cs:code
code segment
start:
int 42
mov ah, 4ch
int 21h
code ends
end start
調試運行
對中斷、軟中斷的理解
中斷： 中斷是指由於接收到外圍硬件(相對於CPU與內存而言)的異步信號或者來自軟件的同步信號而進行相應的硬件/軟件處理 ；
軟中斷： 由軟件本身發給操作系統內核的中斷信號，稱之為軟中斷 ；
中斷處理：
（1）（從中斷信息中）取得中斷類型碼；
（2）標志寄存器的值入棧（在中斷過程中要改變標志寄存器的值）；
（3）設置標志寄存器的第8位TF和第9位IF的值為0；
（4）CS、IP的內容依次入棧；
（5）從內存地址為中斷類型碼*4和中斷類型碼*4+的兩個字單元中讀取中斷處理程序的入口地址設置IP和CS。
自定義中斷程序：41號中斷碼
中斷例程功能：
使用的中斷碼為41號，中斷例程功能為在屏幕中間顯示“201983290041 zzyuan”。
task6_3.asm
;裝入中斷處理程序
assume cs:code
code segment
start:
;ds:si指向中斷處理程序
mov ax, cs
mov ds, ax
mov si, offset int41
;es:di指向程序裝入地址
mov ax, 0
mov es, ax
mov di, 200h
;獲取程序長度
mov cx, offset int41end-int41
cld
rep movsb
;設置中斷向量表
mov ax, 0
mov es, ax
mov word ptr es:[41*4], 200h
mov word ptr es:[41*4+2], 0
mov ah, 4ch
int 21h
;41號中斷處理程序
int41:
jmp short int41start
db "201983290041 zzyuan" ;存放要打印的字符串
int41start:
;ds:si指向待打印字符串
mov ax, cs
mov ds, ax
mov si, 202h
;es:di指向屏幕中間
mov ax, 0b800h
mov es, ax
mov di, 12*160+30*2
;cx字符串長度
mov cx, 13h
s: mov al, [si]
mov es:[di], al
mov byte ptr es:[di+1], 2 ;黑底綠字
inc si
add di, 2
loop s
mov ax, 4c00h
int 21h
int41end:nop
code ends
end start
task6_4.asm
assume cs:code
code segment
start:
int 41
mov ah, 4ch
int 21h
code ends
end start
調試運行
三、實驗總結
- 有些指令的執行結果會影響到一些標志位，如add、sub等；有些不影響，如mov、push、pop、inc、dec；
- cmp指令和轉移指令結合使用可以實現if邏輯；
- 寄存器不夠用或使用沖突問題可以借助棧解決；
- 中斷向量表存放在0000:0000~0000:03FF大小1KB的空間中，256個中斷對應256個表項，每個表項占2個字，高位字存段地址，低位字存偏移地址；
- 可以利用中斷向量表中的空閑單元存放中斷處理程序，一般可用0000:0200~0000:02FF這256字節的空間；