Delphi自代的JSON類TJSONObject

相關資料：

https://download.csdn.net/download/zhujianqiangqq/56461664        代碼包下載 

實例代碼：

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs
  ,System.JSON //使用JSON就要引入這個
  ,Vcl.StdCtrls
  ;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  oJSON: TJSONObject;
  I: Integer;
  oJSONArray: TJSONArray;
  oJSONPair: TJSONPair;
begin
  oJSON := TJSONObject.ParseJSONValue(Trim('{"code":100,"state":"true","data":["hero","npc","pet"]}')) as TJSONObject;
  //json節點數
  Memo1.Lines.Add(IntToStr(oJSON.Count)); //3
  //使用Index取出節點的“名字”“值”
  for I:=0 to oJSON.count-1 do
  begin
    Memo1.Lines.Add(oJSON.Get(I).JsonString.toString + ' = ' +
                    oJSON.Get(I).JsonValue.ToString);
                    //"code" = 100  //"state" = "true"  //"data" = ["hero","npc","pet"]
  end;
  //獲得節點字符串
  Memo1.Lines.Add(oJSON.Get('state').ToJSON);//"state":"true"
  //使用name取出節點的“名字”“值”
  Memo1.Lines.Add(oJSON.Get('state').JsonString.Value); //state
  Memo1.Lines.Add(oJSON.Get('state').JsonValue.Value);//true
  Memo1.Lines.Add(oJSON.Get('state').JsonString.ToString);//"state"
  Memo1.Lines.Add(oJSON.Get('state').JsonValue.ToString); //"true"
  //使用name取出節點的“值”
  Memo1.Lines.Add(oJSON.GetValue('state').ToString);//"true"
  //修改節點的“值”
  oJSON.Get('state').JsonValue := TJSONString.Create('dddd');
  //移除一個節點
  oJSON.RemovePair('state');
  //增加一個節點
  oJSON.AddPair('state', 'eeeeee');
  //遍歷json數組
  oJSONArray := TJSONArray(oJSON.GetValue('data'));
  for I:=0 to oJSONArray.Size - 1 do
  begin
    Memo1.Lines.Add(oJSONArray.Items[I].Value); //hero  //npc  //pet
  end;
  //使用index獲取節點
  oJSONPair := oJSON.Pairs[0];
  Memo1.Lines.Add(oJSONPair.JsonString.Value);//code
  Memo1.Lines.Add(oJSONPair.JSONValue.Value);//100
  Memo1.Lines.Add(oJSONPair.JsonString.ClassName);//TJSONString
  Memo1.Lines.Add(oJSONPair.JsonValue.ClassName);//TJSONNumber
  //如果你沒有在最后釋放，也不會出錯，不過會不會被罵就不知道了！可別說我沒加TRY，我這么寫是為了整齊好看。
  oJSON.Free;
end;

end.