地圖中自動出現物品.
點擊查看代碼
格式: ThrowItem 地圖號 坐標X 坐標Y 范圍 物品 數量|揀取間隔
說明: 地圖號=Self表示當前地圖.
------------------------------------------------------------------------
例子:在盟重土城安全區自動出現紅包.
#IF
Random 100
#ACT
ThrowItem 3 330 330 10 紅包 5
--------------------------------------------------------------------------------
例子:在盟重土城安全區自動出現紅包,60秒后可揀取.
#IF
Random 100
#ACT
ThrowItem 3 330 330 10 紅包 5|60
--------------------------------------------------------------------------------
例子:可寫入多個物品同時出現，一行一個物品。
#IF
Random 100
#ACT
ThrowItem 3 330 330 10 紅包 5|60
ThrowItem 3 330 330 10 裁決之杖 5|60
ThrowItem 3 330 330 10 屠龍 5|60
ThrowItem 3 330 330 10 龍紋劍 5|60
ThrowItem 3 330 330 10 骨玉權杖 5|60
傳奇稱號系統腳本
點擊查看代碼
自定義稱號，具體參考配套工具(GameTools.exe)說明
基本
稱號數據庫(FengHaos.DB)需與物品數據庫(StdItems.DB)等放在同一目錄下，如：D:\mirserver\Mud2\DB
稱號附加條件
Need(附加條件)
0:需等級 NeedLevel=等級
1:需攻擊力 NeedLevel=攻擊力
2:需魔法 NeedLevel=魔法
3:需道術 NeedLevel=道術
設置稱號發送確認信息(即設置主宰龍衛或護花使者時，讓對方是否同意)
格式: GIVEFENGHAOAGREE 角色名 類型(1-255)
說明：執行命令時，會設置對方的變量 <$SETFENGHAOHUM> --即設置人變量
類型用於觸發腳本段標識,即稱號的idx字段,確認后執行,QF段 @FengHaoAgree+類型
[@InPutString51]
#IF
CHECKFENGHAOCOUNT < 8
.gender man
CHECKFENGHAOLISTCOUNT 0 < 10
#act
GIVEFENGHAOAGREE 14
#say
請等對方確認！
#elseSay
不是男性或不能再有更多的稱號或不在線！！！或者你已經有10個護花使者了
QF文件
[@FengHaoAgree14]
#IF
#ACT
GIVEFENGHAO <$USERNAME> 護花使者 <$SETFENGHAOHUM>
@ReloadHumTitleDB GM命令,重載稱號數據庫(FengHaos.DB)
需修改string.txt文件下的HumanShowName=%ChrName\%GuildName\%DearName\%MasterName\%Comradename\%Huhuaname
回收稱號觸發：QF文件 @FengHaoFuncX X-序號(DB里的序號字段)
Mir200\Envir\DominatSendPoint.txt 主宰令世界地圖坐標設置文件
增加：地圖參數PEAK(需測試)
說明：地圖巔峰狀態,攻擊能力提升
格式：PEAK(最低攻擊倍率/最高攻擊倍率)
注：倍率除100為實際倍數
當最高攻擊倍率大於100時，進入地圖提示"您在此地圖臨時獲得巔峰戰神狀態,攻擊能力大幅提升!"
100內時提示"您在此地圖臨時獲得巔峰勇士狀態,攻擊能力提升!"
NPC命令：
功能：給予玩家稱號
格式：GIVEFENGHAO 角色名 稱號名 設置人
注：當有同樣的稱號時，則不能再增加此稱號
設置人：即"傳奇之星"進行設置"護花使者"時使用,如果設置人不在線或沒有"傳奇之星"稱號則設置失敗
即"瑪法主宰者"進行設置"主宰龍衛"時使用,如果設置人不在線或沒有"瑪法主宰者"稱號則設置失敗
注：最高只能設置10個護花使者或主宰龍衛
功能：回收玩家稱號
格式：RECYCFENGHAO 角色名 稱號名
功能：檢查玩家是否有指定稱號
格式：CHECKFENGHAO 稱號名
功能：檢查玩家所有稱號的數量
格式：CHECKFENGHAOCOUNT 角色名 操作符(<,>,=) 數量(0-8)
功能：檢查玩家護花使者或主宰龍衛的數量
格式：CHECKFENGHAOLISTCOUNT 類型(0-護花使者 1-主宰龍衛) 操作符(<,>,=) 數量(0-10)
功能：檢查行會設置行會之星的間隔(無行會無效)
格式：CheckGuildStarDay 操作符(<,>,=) 小時數
變量<$GUILDSTARDATE>---授於行會之星的操作日期
[物品DB]－使用不減持久，稱號消失時觸發QF文件回收，，需設置死亡不爆出等屬性
1092;護花使者令;2;253;1;0;0;0;2182;10000;0;0;0;0;0;0;0;0;0;0;0;0;20000;5;
1093;主宰令牌;2;254;1;0;0;0;2181;10000;0;0;0;0;0;0;0;0;0;0;0;0;20000;5;
腳本示例
[@Main]
內容自己填寫即可\
<稱號/@稱號> \
[@稱號]
<設置傳奇之星/@傳奇之星> <任命護花使者/@任命護花使者> \
<設置瑪法主宰者/@瑪法主宰者> <任命主宰龍衛/@任命主宰龍衛>
[@傳奇之星]
#IF
CHECKFENGHAOCOUNT <$USERNAME> < 8
gender WOMAN
#act
GIVEFENGHAO <$USERNAME> 傳奇之星
give 護花令牌
#elseSay
你不是女性或不能再有更多的稱號了，沒位了！！！
[@任命護花使者]
<任命護花使者名字/@@InPutString51> ←輸入需要設置的玩家名字！\ \
〖<返回/@main>〗
[@InPutString51]
#IF
CHECKFENGHAOCOUNT <$STR(S51)> < 8
<$STR(S51)>.gender man
CHECKFENGHAOLISTCOUNT 0 < 10
#act
GIVEFENGHAO <$STR(S51)> 護花使者 <$USERNAME>
#elseSay
<$STR(S51)>不是男性或不能再有更多的稱號或不在線！！！或者你已經有10個護花使者了
[@瑪法主宰者]
#IF
CHECKFENGHAOCOUNT <$USERNAME> < 8
#act
GIVEFENGHAO <$USERNAME> 瑪法主宰者
give 主宰令牌
#elseSay
你不能再有更多的稱號了，沒位了！！！
[@任命主宰龍衛]
<任命主宰龍衛名字/@@InPutString52> ←輸入需要設置的玩家名字！\ \
〖<返回/@main>〗
[@InPutString52]
#IF
CHECKFENGHAOCOUNT <$STR(S52)> < 8
CHECKFENGHAOLISTCOUNT 1 < 10
#act
GIVEFENGHAO <$STR(S52)> 主宰龍衛 <$USERNAME>
#elseSay
<$STR(S52)>不能再有更多的稱號或不在線！！！或者你已經有10個主宰龍衛了
QF觸發
[@FengHaoFunc13]
#IF
#ACT
take 護花使者令
SENDMSG 7 提示：回收護花使者令
[@FengHaoFunc0]
#IF
#ACT
take 主宰令
SENDMSG 7 提示：回收主宰令
點擊查看代碼
通過腳本命令建立一個NPC,服務器重啟后消失.
格式: CreateNPC NPC名字 地圖 坐標X(-1時隨機坐標) 坐標Y(-1時隨機坐標) 外觀 腳本文件 腳本文件是否要加上地圖名稱
(例如.設置為0時腳本文件必須帶“-3”如:“傳送員-3.txt” 設置為1時腳本文件不需要帶“-3”如:“傳送員.txt”這樣的好處就是
你可以在任意地圖地圖創建NPC，只要一個腳本“傳送員.txt”而不需要“傳送員-0.txt、傳送員-3.txt”等等好多NPC腳本)
注意: 腳本文件必須在Market_Def目錄中.
例如:首先在Market_Def中建立一個叫 測試-3.txt 的腳本文件.
通過另外一個NPC建立另一個NPC，示范腳本。
[@main]
你好，你可以通過我建立新的NPC哦。\
<建立NPC/@建立1> <建立NPC/@建立2> \
[@建立1]
#IF
#ACT
CreateNPC 測試 3 330 330 8 測試-3 0
#SAY
通過腳本在土城330 330 坐標處建立了一個NPC.
[@建立2]
#IF
#ACT
CreateNPC 測試NPC 3 -1 -1 8 測試NPC 1
#SAY
通過腳本隨機在土城建立了一個NPC
點擊查看代碼
此腳本是教大家怎么創建一個鏡像地圖，當玩家進入某個地圖后，地圖會變成這個玩家的名字
這個是傳奇的鏡像地圖功能，具體大家可以參考傳奇精英發布的腳本
動態創建一個鏡像地圖
ADDMIRRORMAP
格式：AddMirrorMap A B C D E F
功能：動態創建一個鏡像地圖
說明：創建成功后，人物D99變量返回1，否則返回0
A，原地圖編號，在地圖配置文件中存在的地圖！
B，新地圖編號，臨時使用的地圖編號，就和鏡像地圖功能一樣！
C，新地圖名，這里指客戶端顯示的名字
D，該地圖存在的有效時長(秒)，時間到后，此地圖將自動回收，並且將地圖上的人傳送至E參數設置的地圖
E，人物退出時返回的地圖編號
F, 小地圖編號
DelMirrorMap
格式：DelMirrorMap 地圖名
功能：刪除動態創建的鏡像地圖
MirrorMapTime
格式：MirrorMapTime 地圖名 時間（單位：秒）
功能：設置/獲取鏡像地圖的時間
說明：如果時間不寫，則表示獲取當前地圖的剩余時間，時間返回在D99變量
如果獲取地圖失敗或不是鏡像地圖，則D99返回-1
CheckMirrorMap
格式：CheckMirrorMap 地圖名
功能：檢測鏡像地圖是否已經創建
-------------------------------下面是使用例子---------------------------------
;使用人物名稱做為副本地圖的名稱創建副本
[@main]
#if
#act
MirrorMapTime <$USERNAME>
#SAY
剩余時間：<$STR(D99)>秒\ \
<創建副本/@創建副本>\
<進入副本/@進入副本>\
<刪除副本/@刪除副本>\
[@刪除副本]
#ACT
DELMIRRORMAP <$USERNAME>
goto @main
[@進入副本]
#IF
LARGE D99 0
#ACT
give 回城卷 1
map <$USERNAME>
#ELSEACT
goto @main
SENDMSG 6 副本地圖還沒有創建
[@創建副本]
#if
CheckMirrorMap <$USERNAME>
#ACT
goto @main
SENDMSG 6 該副本地圖已經創建
BREAK
#IF
#ACT
AddMirrorMap 0 <$USERNAME> 比奇副本 60 0159 101
;創建一個連接，地圖3 坐標 X:333 Y:333 連接到新創建的副本地圖坐標 X:333 Y:333
AddMapGate 連接 3 333 333 1 <$USERNAME> 333 333 60
#if
Equal D99 1
#ACT
goto @main
SENDMSG 6 創建成功
#ELSEACT
goto @main
SENDMSG 6 創建失敗