利用多線程解除耦合/線程解耦合/DeAfterCreate/DeClose

當軟件啟動時，我們希望從配置文件中加載參數，然后用這些參數，改變窗口的狀態大小，或者組件的屬性。

通常的做法是在 TForm 的 OnCreate 事件中或者 OnFirstShow 事件中執行這些任務。 但是，但某些改變窗口的語句，

在這些事件中執行時，是會發生沖突的。比如：在 OnShow 事件中，不能去改變 visiable 屬性。因此，我們需要一個真正解除耦合的事件，

此處將其定義為 DeAfterCreate , 即稱為 解除耦合的 AfteCreate 事件。 同樣地，也實現了一個 DeClose 事件。

本例源代碼(delphi 10.3.2)

unit uFrmDeBase;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TFrmDeBase = class(TForm)
    procedure FormShow(Sender: TObject);
  private
    { Private declarations }
    FNotFirstShow: Boolean; // 取名為這樣是利用默認值為 false, 減少去 create 事件中去賦值。
  protected
    procedure DeAfterCreate(); virtual;
    procedure DeClose();
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

procedure TFrmDeBase.DeAfterCreate;
begin
end;

procedure TFrmDeBase.DeClose;
begin
  TThread.CreateAnonymousThread(
    procedure
    begin
      TThread.Queue(nil,
        procedure
        begin
          Self.Close;
        end);
    end).Start; // 創建一個匿名線程
    // 在匿名線程中，再排隊執行主線程時空的代碼
end;

procedure TFrmDeBase.FormShow(Sender: TObject);
begin
  // 我們利用 FirstOnShow 這個時機，創造一個解除耦合的 DeAfterCreate 事件。
  if not FNotFirstShow then
  begin
    FNotFirstShow := true;
    TThread.CreateAnonymousThread(
      procedure
      begin
        TThread.Queue(nil,
          procedure
          begin
            DeAfterCreate;
          end);

      end).Start;
  end;
end;

end.

unit uFrmMain;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, uFrmDeBase, Vcl.StdCtrls;

type
  TFrmMain = class(TFrmDeBase)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  protected
    procedure DeAfterCreate(); override;
  public
    { Public declarations }
  end;

var
  FrmMain: TFrmMain;

implementation

{$R *.dfm}
{ TFrmMain }

procedure TFrmMain.Button1Click(Sender: TObject);
begin
  inherited;
  DeClose;
  // 你可以在各種事件中(OnClose事件中除外)，執行 DeClose 函數。
  // 不必擔心耦合問題。
  // 這個相當於“延時執行” Close 動作。
  // ***
  // 如果沒有解除耦合,就可能在 Close 動作之后，返回到別的事件函數中，執行了比如設置組件信息操作。導致出錯。
  // “延時執行”，相當於此函數不在“任何函數中調用的。“完全獨立”。
  // 解除耦合，是很重要的編程思維，可以讓多任務，復雜關系調用簡單化。
end;

procedure TFrmMain.DeAfterCreate;
begin
  // 此處是解耦合的 AfterCreate 事件
  // 在此時，窗口已經真正創建完畢
  // 可以在此處加載各種參數
  // 可以設置窗口大小，位置，等信息而不會發生錯誤。
  /// *****************
  // 比如：你直接在 OnShow / OnCreate 等其它事件中
  // 因為沒有解除耦合，下面的功能會發生錯誤
  self.Position := poScreenCenter;
  self.Visible := false;
  self.Visible := true;
  self.BringToFront;
end;

end.