實驗8：數據平面可編程實踐——P4

一、實驗目的

1. 掌握V1Model框架下P4_16的程序結構和基本語法
2. 能夠運用 P4 進行簡單數據平面編程

---

二、實驗環境

1. 下載虛擬機軟件Oracle VisualBox或VMware；
2. 在虛擬機中安裝Ubuntu 16.04 Desktop amd64，並安裝完整Mininet和P4開發環境；
3. 提供P4鏡像P4-Suite2018.ova，提取碼：egwf

---

三、實驗要求

• 學習P4官方示例教程，鏈接：https://github.com/p4lang/tutorials，了解P4-16版本的基本語法、基於V1Model的P4代碼結構，完成如下練習：

（一）基本要求

• 熟悉使用P4實現交換機IPv4的基本轉發原理，編寫P4程序，在下面的拓撲中實現IPV4 隧道轉發。
  
• 補完P4教程中的basic_tunnel.p4

/* -*- P4_16 -*- */
#include <core.p4>
#include <v1model.p4>

const bit<16> TYPE_MYTUNNEL = 0x1212;
const bit<16> TYPE_IPV4 = 0x800;

/*************************************************************************
*********************** H E A D E R S  ***********************************
*************************************************************************/

typedef bit<9>  egressSpec_t;
typedef bit<48> macAddr_t;
typedef bit<32> ip4Addr_t;

header ethernet_t {
    macAddr_t dstAddr;
    macAddr_t srcAddr;
    bit<16>   etherType;
}

header myTunnel_t {
    bit<16> proto_id;
    bit<16> dst_id;
}

header ipv4_t {
    bit<4>    version;
    bit<4>    ihl;
    bit<8>    diffserv;
    bit<16>   totalLen;
    bit<16>   identification;
    bit<3>    flags;
    bit<13>   fragOffset;
    bit<8>    ttl;
    bit<8>    protocol;
    bit<16>   hdrChecksum;
    ip4Addr_t srcAddr;
    ip4Addr_t dstAddr;
}

struct metadata {
    /* empty */
}

struct headers {
    ethernet_t   ethernet;
    myTunnel_t   myTunnel;
    ipv4_t       ipv4;
}

/*************************************************************************
*********************** P A R S E R  ***********************************
*************************************************************************/

parser MyParser(packet_in packet,
                out headers hdr,
                inout metadata meta,
                inout standard_metadata_t standard_metadata) {

    state start {
        transition parse_ethernet;
    }

    state parse_ethernet {
        packet.extract(hdr.ethernet);
        transition select(hdr.ethernet.etherType) {
            TYPE_MYTUNNEL: parse_myTunnel;
            TYPE_IPV4: parse_ipv4;
            default: accept;
        }
    }

    state parse_myTunnel {
        packet.extract(hdr.myTunnel);
        transition select(hdr.myTunnel.proto_id) {
            TYPE_IPV4: parse_ipv4;
            default: accept;
        }
    }

    state parse_ipv4 {
        packet.extract(hdr.ipv4);
        transition accept;
    }

}

/*************************************************************************
************   C H E C K S U M    V E R I F I C A T I O N   *************
*************************************************************************/

control MyVerifyChecksum(inout headers hdr, inout metadata meta) {   
    apply {  }
}


/*************************************************************************
**************  I N G R E S S   P R O C E S S I N G   *******************
*************************************************************************/

control MyIngress(inout headers hdr,
                  inout metadata meta,
                  inout standard_metadata_t standard_metadata) {
    action drop() {
        mark_to_drop(standard_metadata);
    }
    
    action ipv4_forward(macAddr_t dstAddr, egressSpec_t port) {
        standard_metadata.egress_spec = port;
        hdr.ethernet.srcAddr = hdr.ethernet.dstAddr;
        hdr.ethernet.dstAddr = dstAddr;
        hdr.ipv4.ttl = hdr.ipv4.ttl - 1;
    }
    
    table ipv4_lpm {
        key = {
            hdr.ipv4.dstAddr: lpm;
        }
        actions = {
            ipv4_forward;
            drop;
            NoAction;
        }
        size = 1024;
        default_action = drop();
    }
    
    action myTunnel_forward(egressSpec_t port) {
        standard_metadata.egress_spec = port;
    }

    table myTunnel_exact {
        key = {
            hdr.myTunnel.dst_id: exact;
        }
        actions = {
            myTunnel_forward;
            drop;
        }
        size = 1024;
        default_action = drop();
    }

    apply {
        if (hdr.ipv4.isValid() && !hdr.myTunnel.isValid()) {
            // Process only non-tunneled IPv4 packets
            ipv4_lpm.apply();
        }

        if (hdr.myTunnel.isValid()) {
            // process tunneled packets
            myTunnel_exact.apply();
        }
    }
}

/*************************************************************************
****************  E G R E S S   P R O C E S S I N G   *******************
*************************************************************************/

control MyEgress(inout headers hdr,
                 inout metadata meta,
                 inout standard_metadata_t standard_metadata) {
    apply {  }
}

/*************************************************************************
*************   C H E C K S U M    C O M P U T A T I O N   **************
*************************************************************************/

control MyComputeChecksum(inout headers  hdr, inout metadata meta) {
     apply {
    update_checksum(
        hdr.ipv4.isValid(),
            { hdr.ipv4.version,
          hdr.ipv4.ihl,
              hdr.ipv4.diffserv,
              hdr.ipv4.totalLen,
              hdr.ipv4.identification,
              hdr.ipv4.flags,
              hdr.ipv4.fragOffset,
              hdr.ipv4.ttl,
              hdr.ipv4.protocol,
              hdr.ipv4.srcAddr,
              hdr.ipv4.dstAddr },
            hdr.ipv4.hdrChecksum,
            HashAlgorithm.csum16);
    }
}

/*************************************************************************
***********************  D E P A R S E R  *******************************
*************************************************************************/

control MyDeparser(packet_out packet, in headers hdr) {
    apply {
        packet.emit(hdr.ethernet);
        packet.emit(hdr.myTunnel);
        packet.emit(hdr.ipv4);
    }
}

/*************************************************************************
***********************  S W I T C H  *******************************
*************************************************************************/

V1Switch(
MyParser(),
MyVerifyChecksum(),
MyIngress(),
MyEgress(),
MyComputeChecksum(),
MyDeparser()
) main;

• make run將上述P4程序編譯並運行
  
• xterm h1 h2 h3打開命令行，並在h2、h3命令行下運行./receive.py開始監聽
  
• h1命令行下運行開始向h2、h3發送數據包

1. 不使用隧道

• ./send.py 10.0.2.2 "Hi, h2, i am 031902102"
  
• ./send.py 10.0.3.3 "Hi, h3, i am 031902102"
  
  可以看到，數據包正常按照目的ipv4地址送達

2. 使用隧道

• ./send.py 10.0.2.2 "this is tunnel to h3" --dst_id 3
  
  使用隧道技術后，可以看到數據包無視10.0.2.2的目的ip地址，而根據dst_id送達h3

---

個人總結

實驗難度

相對較難，主要體現在閱讀量和理解量上
本次實驗主要學習V1Model框架下P4_16的程序結構和基本語法，實驗在P4_Suite上進行，實驗目的在於是我們能夠運用 P4 進行簡單數據平面編程。 實驗的總體內容具有一定的理解、學習難度。但基礎部分並不是特別困難，進階部分需要進一步對P4及相關知識加深理解和知識儲備，所以本次進階部分未能實現（好吧，我承認是我菜）。

遇到問題

• Q1：起初還沒看pdf，想要先運行P4官方教程里附帶的basic.p4和basic_tunnel.p4看看效果，結果basic正常通過make run運行起來了，而basic_tunnel運行不起來
• 解決方法：之后通過閱讀pdf（全英文PTSD復發），知道了我們需要自行補完** TODO: **后所寫的功能或所需變更的邏輯。
• Q2：basic_tunnel.p4正常運行后，試圖在命令行里運行receive.py但出現以下報錯：
  
• 解決方法：仔細回顧所需達成目標和之前實驗后，我明白了我犯傻了，./receive.py需要在主機的命令行里開啟監聽，而不是在外部。

實驗心得

通過本次實驗實踐，我初步了解掌握V1Model框架下P4_16的程序結構和基本語法，能使用P4進行十分初步的編程。但我自知自己的知識對於P4還很不深入，仍十分需要進一步的學習和實踐，這可以在接下來的SDN實踐大作業中進一步學習加強。本次實驗也是SDN課程學習的最后一次實驗，從本課程中，我對於SDN這一重要的技術領域有了初步的認識，也培養了相當的興趣。今后的學習生活中，我也會在SDN，繼續學習相關知識技術來充實自己。