關閉“未發現 NVIDIA 控制面板”的彈窗

【鳴謝】CSDN ID：Wilbert Lee

前言

迫於壓力，眾多廠商開始推廣 DCH 版本驅動，NVIDIA 也不例外，而兩者的差別在於后者的安裝包中不帶有 NVIDIA 控制面板。

解法

有兩種辦法：

• 重新安裝 NVIDIA 控制面板。
• 禁用 NVIDIA Display Container LS 服務。

【個人延伸-風歸來】

找到該服務

常規選項卡---可執行文件的路徑，其值拷貝出來，為：

C:\Windows\System32\DriverStore\FileRepository\nv_dispi.inf_amd64_33895c186dfc2a0d\Display.NvContainer\NVDisplay.Container.exe -s NVDisplay.ContainerLocalSystem -f C:\ProgramData\NVDisplay.ContainerLocalSystem.log -l 3 -d C:\Windows\System32\DriverStore\FileRepository\nv_dispi.inf_amd64_33895c186dfc2a0d\Display.NvContainer\plugins\LocalSystem -r -p 30000 -cfg NVDisplay.ContainerLocalSystem\LocalSystem

通過任務管理器驗證，上述路徑里的NVDisplay.Container.exe正好是彈窗對應的進程。

其中的NVDisplay.Container.exe同目錄下有一個bat文件，名為：NvContainerRecovery.bat。該bat文件的內容為：

@echo off

if "%1" == "" (
    echo Usage: NvContainerRecovery {Service Name}
    goto NvContainerRecoveryEnd
)

set __LOG_FILE=NvContainerRecovery.log
if not "%2" == "" set __LOG_FILE=C:\ProgramData\NVIDIA\NvContainerRecovery%1.log

set __RECOVERY_FILE=%LOCALAPPDATA%\NvContainerRecovery%1.reg

echo Create recovery registry file %__RECOVERY_FILE% > %__LOG_FILE%
echo REGEDIT4 > %__RECOVERY_FILE%
echo. >> %__RECOVERY_FILE%
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\NVIDIA Corporation\NvContainer\%1] >> %__RECOVERY_FILE%
echo "Recovery"=dword:00000001 >> %__RECOVERY_FILE%
echo. >> %__RECOVERY_FILE%
echo [HKEY_LOCAL_MACHINE\SOFTWARE\NVIDIA Corporation\NvContainer\%1] >> %__RECOVERY_FILE%
echo "Recovery"=dword:00000001 >> %__RECOVERY_FILE%
type %__RECOVERY_FILE% >> %__LOG_FILE%
echo Import %__RECOVERY_FILE% in registry >> %__LOG_FILE%
regedit.exe /s %__RECOVERY_FILE%

echo. >> %__RECOVERY_FILE%
echo Starting service %1 >> %__LOG_FILE%
net start %1 >> %__LOG_FILE% 2>&1
if %ERRORLEVEL% EQU 0 goto NvContainerRecoveryEnd

rem In case of failure, remove recovery setting from registry
echo. >> %__RECOVERY_FILE%
echo Prepare rollback registry file %__RECOVERY_FILE% >> %__LOG_FILE%
echo REGEDIT4 > %__RECOVERY_FILE%
echo. >> %__RECOVERY_FILE%
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\NVIDIA Corporation\NvContainer\%1] >> %__RECOVERY_FILE%
echo "Recovery"=- >> %__RECOVERY_FILE%
echo. >> %__RECOVERY_FILE%
echo [HKEY_LOCAL_MACHINE\SOFTWARE\NVIDIA Corporation\NvContainer\%1] >> %__RECOVERY_FILE%
echo "Recovery"=- >> %__RECOVERY_FILE%
type %__RECOVERY_FILE% >> %__LOG_FILE%

echo Import %__RECOVERY_FILE% in registry >> %__LOG_FILE%
regedit.exe /s %__RECOVERY_FILE%

:NvContainerRecoveryEnd
if exist "%__RECOVERY_FILE%" (
    echo. >> %__RECOVERY_FILE%
    echo Delete registry file %__RECOVERY_FILE% >> %__LOG_FILE%
    del /Q %__RECOVERY_FILE%
)
set __RECOVERY_FILE=
set __LOG_FILE=