王爽《匯編語言》第四版 超級筆記
第13章 int指令
中斷信息可以來自CPU的內部和外部，當CPU的內部有需要處理的事情發生的時候，將產生需要馬上處理的中斷信息，引發中斷過程。
在上一章中，我們講解了中斷過程和兩種內中斷的處理。
本章我們講解另一種重要的內中斷，由int指令引發的中斷。
13.1 int指令、編寫供應用程序調用的中斷例程
int指令的格式為：int n為中斷類型碼，它的功能是引發中斷過程。
CPU執行int n指令，相當於引發一個n號中斷的中斷過程，執行過程如下。
（1）取中斷類型碼n；
（2）標志寄存器入棧，IF=0，TF=0；
（3）CS、IP入棧；
（4）(IP)=(nx4)，(CS)=(nx4+2)。
從此處轉去執行n號中斷的中斷處理程序。
可以在程序中使用int指令調用任何一個中斷的中斷處理程序。例如下面的程序：
assume cs:code
code segment
start: mov ax,0b800h
mov es,ax
mov byte ptr es:[12*160+40*2],'!'
int 0
code ends
end start
這個程序在Windows 2000中的DOS方式下執行時，將在屏幕中間顯示一個“!”，然后顯示"Divide overflow"后返回到系統中。“!”是我們編程顯示的，而“Divide overflow"是哪里來的呢？
我們的程序中又沒有做除法，不可能產生除法溢出。程序是沒有做除法，但是在結尾使用了int 0指令。
CPU執行int 0指令時，將引發中斷過程，執行0號中斷處理程序，而系統設置的0號中斷處理程序的功能是顯示“Divide overflow"，然后返回到系統。
可見int指令的最終功能和call指令相似，都是調用一段程序。
一般情況下，系統將一些具有一定功能的子程序，以中斷處理程序的方式提供給應用程序調用。我們在編程的時候，可以用int指令調用這些子程序。
當然，也可以自己編寫一些中斷處理程序供別人使用。以后，我們可以將中斷處理程序簡稱為中斷例程。
我們己經編寫過中斷0的中斷例程了，現在我們討論可以供應用程序調用的中斷例程的編寫方法。下面通過兩個問題來討論。
問題一：編寫、安裝中斷7ch的中斷例程。
功能：求一word型數據的平方。
參數：(ax)=要計算的數據。
返回值：dx、ax中存放結果的高16位和低16位。
應用舉例：求2x3456^2。
assume cs:code
code segment
start: mov ax,3456 ;(ax)=3456
int 7ch ;調用中斷7ch的中斷例程，計算ax中的數據的平方
add ax,ax
adc dx,dx ;dx:ax存放結果，將結果乘以2
mov ax,4c00h
int 21h
code ends
end start
分析一下，我們要做以下3部分工作。
（1）編寫實現求平方功能的程序；
（2）安裝程序，將其安裝在0:200處；
（3）設置中斷向量表，將程序的入口地址保存在7ch表項中，使其成為中斷7ch的中斷例程。
安裝程序如下。
assume cs:code
code segment
start: mov ax,cs
mov ds,ax
mov si,offset sqr ;設置ds:si指向源地址
mov ax,0
mov es,ax
mov di,200h ;設置es:di指向目的地址
mov cx,offset sqrend-offset sqr ;設置cx為傳輸長度
cld ;設置傳輸方向為正
rep movsb
mov ax,0
mov es,ax
mov word ptr es:[7ch*4],200h
mov word ptr es:[7ch*4+2],0
mov ax,4c00h
int21h
sqr: mul ax
iret
sqrend:nop
code ends
end start
注意，在中斷例程sqr的最后，要使用iret指令。用匯編語法描述，iret指令的功能為：
pop IP
pop CS
popf
CPU執行int 7ch指令進入中斷例程之前，標志寄存器、當前的CS和IP被壓入棧中，在執行完中斷例程后，應該用iret指令恢復int 7ch執行前的標志寄存器和CS、IP的值，從而接着執行應用程序。
int指令和iret指令的配合使用與call指令和ret指令的配合使用具有相似的思路。
問題二：編寫、安裝中斷7ch的中斷例程。
功能：將一個全是字母，以0結尾的字符串，轉化為大寫。
參數：ds:si指向字符串的首地址。
應用舉例：將data段中的字符串轉化為大寫。
assume cs:code
data segment
db 'conversation',0
data ends
code segment
start: mov ax,data
mov ds,ax
mov si,0
int 7ch
mov ax,4c00h
int 21h
code ends
end start
安裝程序如下。
assume cs:code
code segment
start: mov ax,cs
mov ds,ax
mov si,offset capital
mov ax,0
mov es,ax
mov di,200h
mov ex,offset capitalend-offset capital
cld
rep movsb
mov ax,0
mov es,ax
mov word ptr es:[7ch*4],200h
mov word ptr es: [7ch*4+2],0
mov ax,4c00h
int 21h
capital:push cx
push si
change: mov cl,[si]
mov ch,0
jcxz ok
and byte ptr [si],11011111b
inc si
jmp short change
ok: pop si
pop cx
iret
capitalend:nop
code ends
end start
在中斷例程capital中用到了寄存器si和cx，編寫中斷例程和編寫子程序的時候具有同樣的問題，就是要避免寄存器的沖突。應該注意例程中用到的寄存器的值的保存和恢復。
13.2 對int、iret和棧的深入理解
問題：用7ch中斷例程完成loop指令的功能。
loop s的執行需要兩個信息，循環次數和到s的位移，所以7ch中斷例程要完成loop指令的功能，也需要這兩個信息作為參數。我們用cx存放循環次數，用bx存放位移。
應用舉例：在屏幕中間顯示80個“!”。
assume cs:code
code segment
start: mov ax,0b800h
mov es,ax
mov di,160*12
mov bx,offset s-offset se ;設置從標號se到標號s的轉移位移
mov cx,80
s: mov byte ptr es:[di],'!'
add di,2
int 7ch ;如果(cx)不等於0,轉移到標號s處
se:nop
mov ax,4c00h
int 21h
code ends
end start
在上面的程序中，用int 7ch調用7ch中斷例程進行轉移，用bx傳遞轉移的位移。
分析：為了模擬loop指令，7ch中斷例程應具備下面的功能。
（1）dec cx；
（2）如果(cx)不等於0，轉到標號s處執行，否則向下執行。
下面我們分析7ch中斷例程如何實現到目的地址的轉移。
（1）轉到標號s顯然應設(CS)=標號s的段地址，(IP)=標號s的偏移地址。
（2）那么，中斷例程如何得到標號s的段地址和偏移地址呢？
int 7ch引發中斷過程后，進入7ch中斷例程，在中斷過程中，當前的標志寄存器、CS和IP都要壓棧，此時壓入的CS和IP中的內容，分別是調用程序的段地址(可以認為是標號S的段地址)和int 7ch后一條指令的偏移地址(即標號se的偏移地址)。
在中斷例程中，可以從棧里取得標號s的段地址和標號se的偏移地址，而用標號se的偏移地址加上bx中存放的轉移位移就可以得到標號s的偏移地址。
（3）現在知道，可以從棧中直接和間接地得到標號s的段地址和偏移地址，那么如何用它們設置CS:IP呢？
可以利用iret指令，我們將棧中的se的偏移地址加上bx中的轉移位移，則棧中的se的偏移地址就變為了s的偏移地址。我們再使用iret指令，用棧中的內容設置CS、IP，從而實現轉移到標號s處。
7ch中斷例程如下。
lp: push bp
mov bp,sp
dec cx
jcxz Ipret
add [bp+2],bx
Ipret: pop bp
iret
因為要訪問棧，使用了bp，在程序開始處將bp入棧保存，結束時出棧恢復。當要修改棧中se的偏移地址的時候，棧中的情況為：棧頂處是bp原來的數值，下面是se的偏移地址，再下面是s的段地址，再下面是標志寄存器的值。
而此時，bp中為棧頂的偏移地址，所以((ss)x16+(bp)+2)處為se的偏移地址，將它加上bx中的轉移位移就變為s的偏移地址。最后用iret岀棧返回，CS:IP即從標號s處開始執行指令。
如果(cx)=0，則不需要修改棧中se的偏移地址，直接返回即可。CPU從標號se處向下執行指令。
13.3 BIOS和DOS所提供的中斷例程及安裝過程
在系統板的ROM中存放着一套程序，稱為BIOS(基本輸入輸岀系統)，BIOS中主要包含以下幾部分內容。
（1）硬件系統的檢測和初始化程序；
（2）外部中斷和內部中斷的中斷例程；
（3）用於對硬件設備進行I/O操作的中斷例程；
（4）其他和硬件系統相關的中斷例程。
操作系統DOS也提供了中斷例程，從操作系統的角度來看，DOS的中斷例程就是操作系統向程序員提供的編程資源。
BIOS和DOS在所提供的中斷例程中包含了許多子程序，這些子程序實現了程序員在編程的時候經常需要用到的功能。
程序員在編程的時候，可以用int指令直接調用BIOS和DOS提供的中斷例程，來完成某些工作。
和硬件設備相關的DOS中斷例程中，一般都調用了BIOS的中斷例程。
前面課程中，我們都是自己編寫中斷例程，將它們放到安裝程序中，然后運行安裝程序，將它們安裝到指定的內存區中。此后，別的應用程序才可以調用。
而BIOS和DOS提供的中斷例程是如何安裝到內存中的呢？
我們下面講解它們的安裝過程。
（1）開機后，CPU一加電，初始化(CS)=0FFFFH，(IP)=0，自動從FFFF:0單元開始執行程序。FFFF:0處有一條轉跳指令，CPU執行該指令后，轉去執行BIOS中的硬件系統檢測和初始化程序。
（2）初始化程序將建立BIOS所支持的中斷向量，即將BIOS提供的中斷例程的入口地址登記在中斷向量表中。注意，對於BIOS所提供的中斷例程，只需將入口地址登記在中斷向量表中即可，因為它們是固化到ROM中的程序，一直在內存中存在。
（3）硬件系統檢測和初始化完成后，調用int 19h進行操作系統的引導。從此將計算機交由操作系統控制。
（4）DOS啟動后，除完成其他工作外，還將它所提供的中斷例程裝入內存，並建立相應的中斷向量。
13.4 BIOS和DOS中斷例程應用
我們舉幾個例子，來看一下BIOS中斷例程的應用。
int 10h中斷例程是BIOS提供的中斷例程，其中包含了多個和屏幕輸出相關的子程序。
一般來說，一個供程序員調用的中斷例程中往往包括多個子程序，中斷例程內部用傳遞進來的參數來決定執行哪一個子程序。BIOS和DOS提供的中斷例程，都用ah來傳遞內部子程序的編號。
下面看一下int 10h中斷例程的設置光標位置功能。
mov ah,2 ;置光標
inov bh,0 ;第0頁
mov dh,5 ;dh中放行號
mov dl,12 ;dl中放列號
int 10h
(ah)=2表示調用第10h號中斷例程的2號子程序，功能為設置光標位置，可以提供光標所在的行號(80x25字符模式下：0~24)、列號(80x25字符模式下：0-79)，和頁號作為參數。
(bh)=0，(dh)=5，(dl)=12，設置光標到第0頁，第5行，第12列。
bh中頁號的含義：內存地址空間中，B8000H~BFFFFH共32kB的空間，為80x25彩色字符模式的顯示緩沖區。一屏的內容在顯示緩沖區中共占4000個字節。
顯示緩沖區分為8頁，每頁4KB(約等於4000B)，顯示器可以顯示任意一頁的內容。一般情況下，顯示第0頁的內容。
通常情況下，B8000H~B8F9FH中的4000個字節的內容將出現在顯示器上。
再看一下int 10h中斷例程的在光標位置顯示字符功能。
mov ah,9 ;在光標位置顯示字符
mov al,'a' ;字符
mov bl,7 ;顏色屬性
mov bh,0 ;第0頁
mov cx,3 ;字符重復個數
int 10h
(ah)=9表示調用第10h號中斷例程的9號子程序，功能為在光標位置顯示字符，可以提供要顯示的字符、顏色屬性、頁號、字符重復個數作為參數。
bl中的顏色屬性的格式如下。
可以看出，和顯存中的屬性字節的格式相同。
編程：在屏幕的5行12列顯示3個紅底高亮閃爍綠色的“a”。
assume cs:code
code segment
mov ah,2 ;置光標
mov bh,0 ;第0頁
mov dh,5 ;dh中放行號
mov dl,12 ;dl中放列號
int 10h
mov ah,9 ;在光標位置顯示字符
mov al,'a' ;字符
mov bl,11001010b;顏色屬性
mov bh,0 ;第0頁
mov cx,3 ;字符重復個數
int 10h
mov ax,4c00h
int 21h
code ends
end
注意，閃爍的效果必須在全屏DOS方式下才能看到。
int 21h中斷例程是DOS提供的中斷例程，其中包含了DOS提供給程序員在編程時調用的子程序。
我們前面一直使用的是int 21h中斷例程的4ch號功能，即程序返回功能，如下：
mov ah,4ch ;程序返回
mov al,0 ;返回值
int 21h
(ah)=4ch表示調用第21h號中斷例程的4ch號子程序，功能為程序返回，可以提供返回值作為參數。
我們前面使用這個功能的時候經常寫做：
mov ax,4c00h
int 21h
我們看一下int21h中斷例程在光標位置顯示字符串的功能：
ds:dx指向字符串 ;要顯示的字符串需用"$"作為結束符
mov ah,9 ;功能號9,表示在光標位置顯示字符串
int 21h
(ah)=9表示調用第21h號中斷例程的9號子程序，功能為在光標位置顯示字符串，可以提供要顯示字符串的地址作為參數。
編程：在屏幕的5行12列顯示字符串"Welcome to masm!”。
assume cs:code
data segment
db 'Welcome to masm','$'
data ends
code segment
start: mov ah,2 ;置光標
mov bh,0 ;第0頁
mov dh,5 ;dh中放行號
mov dl,12 ;dl中放列號
int 10h
mov ax,data
mov ds,ax
mov dx,0 ;ds:dx指向字符串的首地址data:0
mov ah,9
int 21h
mov ax,4c00h
int 21h
code ends
end start
上述程序在屏幕的5行12列顯示字符串"Welcome to masm!”，直到遇見"$" $本身並不顯示，只起到邊界的作用。
如果字符串比較長，遇到行尾，程序會自動轉到下一行開頭處繼續顯示；如果到了最后一行，還能自動上卷一行。
DOS為程序員提供了許多可以調用的子程序，都包含在int 21h中斷例程中。我們這里只對原理進行了講解，對於DOS提供的所有可調用子程序的情況，讀者可以參考相關的書籍。