oracle關於15位身份證轉換18位身份證函數

近期由於業務系統歷史數據的原因存在大量15位的身份證，需要轉換成18位的身份證，15是2000年之前的身份證，之后的就沒有15位了。

在網上找了一些函數，可以正常應用，函數如下：

Create Or Replace Function IDCARD15TO18(CARD Varchar2) Return Varchar2 Is
  Type TIARRAY Is Table Of Integer;
  Type TCARRAY Is Table Of Char(1);
  RESULTS Varchar2(18);
  W       TIARRAY; -- 數字數組
  A       TCARRAY; -- 字符數組
  S       Integer;
Begin
  If CARD Is Null Then
    Return '';
  End If;
  If LENGTH(CARD) <> 15 Then
    Return CARD;
  End If;
  W       := TIARRAY(7, 9, 10, 5, 8, 4, 2, 1, 6, 3, 7, 9, 10, 5, 8, 4, 2, 1);
  A       := TCARRAY('1', '0', 'X', '9', '8', '7', '6', '5', '4', '3', '2');
  RESULTS := SUBSTR(CARD, 1, 6) || '19' || SUBSTR(CARD, 7, 9);
  S       := 0;
  Begin
    For I In 1 .. 17 Loop
      S := S + To_Number(SUBSTR(RESULTS, I, 1)) * W(I);
    End Loop;
  Exception
    When Others Then
      Return '';
  End;
  S       := S Mod 11;
  RESULTS := RESULTS || A(S + 1);
  Return(RESULTS);
End IDCARD15TO18;

create table dw11 (sfz varchar2(18));
insert into dw11 values ('320122880110323');

select IDCARD15TO18(sfz) from dw11;

update  dw11 set sfz=IDCARD15TO18(sfz);

commit;即可將身份證轉換成18位的身份證了。