用友U8開發-兩種方式實現BOM全階展開查詢

1. 第一種是跟蹤物料清單資料查詢執行過程，獲取到的查詢對應的存儲過程
   1.1 這是母件信息查詢
   

   EXEC sp_executesql N'exec Usp_BO_Bo02020_Root @v_where,@v_CreateUser1,@v_CreateUser2',
       N'@v_where nvarchar(100),@v_CreateUser1 nvarchar(4000),@v_CreateUser2 nvarchar(4000)',
       @v_where = N' and  1=1   And ((c.InvCode >= N''999-PCBA'') And (c.InvCode <= N''999-PCBA'')) And (a.Status IN (N''3''))',
       @v_CreateUser1 = N'', @v_CreateUser2 = N'';

   1.2 這是子件信息查詢

   EXEC sp_executesql N'exec Usp_BO_Bo02020_detail @v_BomID,@v_PartID,@v_QueryType,@v_showTDL,@v_llc,@v_effdate,@v_status1,@v_status3,@v_status4,@v_CreateUser,@v_CreateUser1',
       N'@v_BomID int,@v_PartID int,@v_QueryType int,@v_showTDL int,@v_llc int,@v_effdate datetime,@v_status1 int,@v_status3 int,@v_status4 int,@v_CreateUser nvarchar(4000),@v_CreateUser1 nvarchar(4000)',
       @v_BomID = 1000008582, @v_PartID = 41498, @v_QueryType = 3, @v_showTDL = 1,
       @v_llc = 0, @v_effdate = '2015-01-01 00:00:00', @v_status1 = 0,
       @v_status3 = 3, @v_status4 = 0, @v_CreateUser = N'', @v_CreateUser1 = N'';

   其中@v_QueryType 1全階 2僅顯示下一層 3僅顯示最底層，@v_where的條件按照示例的格式自己仿照就行了，子件的查詢需要傳入BomID和PratID，因為系統標准的存儲過程查詢是考慮自由項的，其他參數說明和具體的執行過程可以直接到數據庫中找到對應存儲過程查看

2. 第二種是網上看到的，自己改了一下
   

   DECLARE @partid INT;
   SELECT  @partid = 169;
   WITH    parts ( pbom, pid, cbom, cbid, cid, baseqtyn, baseqtyd, qty, lvl, cdepcode, cwhcode, seq )
             AS ( SELECT   NULL ,p.ParentId ,p.BomId ,p.BomId ,p.ParentId ,0 ,0 ,0 ,0 ,NULL ,NULL ,0 
                  FROM     dbo.bom_parent AS p WITH ( NOLOCK )
                           LEFT JOIN bom_bom AS b WITH ( NOLOCK ) ON b.BomId = p.BomId
                  WHERE    b.VersionEffDate <= GETDATE()
                           AND b.VersionEndDate > GETDATE()
                           AND b.BomType = 1
                  UNION ALL
                  SELECT   p.BomId ,
   p.ParentId ,cb.BomId ,c.OpComponentId ,c.ComponentId ,c.BaseQtyN ,c.BaseQtyD ,
   qty = ( c.BaseQtyN / c.BaseQtyD ) / ( 1- ISNULL(cb.ParentScrap,0) / 100 ) * ( 1+ ISNULL(c.CompScrap,0) / 100 ) ,--使用數量考慮損耗率
   0 AS lvl ,bo.DrawDeptCode ,bo.Whcode ,
                           CAST(ROW_NUMBER() OVER ( PARTITION BY c.BomId ORDER BY c.SortSeq ) AS INT) AS seq 
                  FROM     dbo.bom_parent AS p WITH ( NOLOCK )
                           JOIN dbo.bom_bom AS b WITH ( NOLOCK ) ON b.BomId = p.BomId
                           JOIN dbo.bom_opcomponent AS c WITH ( NOLOCK ) ON c.BomId = p.BomId
                           LEFT JOIN dbo.bom_parent AS cb WITH ( NOLOCK ) ON c.ComponentId = cb.ParentId --關聯虛擬件
                           LEFT JOIN dbo.bom_bom AS bc WITH ( NOLOCK ) ON bc.BomId = cb.BomId
                           LEFT JOIN dbo.bom_opcomponentopt bo WITH ( NOLOCK ) ON c.OptionsId = bo.OptionsId  --關聯子件選項資料
                  WHERE    b.VersionEffDate <= GETDATE()
                           AND b.VersionEndDate > GETDATE()
                           AND ( ( bc.VersionEffDate <= GETDATE()
                                   AND bc.VersionEndDate > GETDATE() AND bc.BomType = 1)OR bc.BomId IS NULL)),
           bom
             AS ( SELECT   parts.pid AS ancestor ,
   parts.pbom ,parts.pid ,parts.cbid ,parts.cbom ,parts.cid ,parts.baseqtyn ,
   parts.baseqtyd ,parts.qty ,parts.lvl ,parts.cdepcode ,parts.cwhcode ,CAST('01' AS NVARCHAR(50)) AS pseq
                  FROM     parts
                  WHERE    parts.pbom IS NULL
                           AND parts.pid = @partid--'999-PCBA'
                  UNION ALL
                  SELECT   p.ancestor ,c.pbom ,c.pid ,c.cbid ,c.cbom ,c.cid ,c.baseqtyn ,c.baseqtyd ,c.qty ,p.lvl + 1 ,c.cdepcode ,c.cwhcode ,
                           CAST(p.pseq + '.' + RIGHT('00'+ CAST(c.seq AS NVARCHAR(50)),2) AS NVARCHAR(50))
                  FROM     parts AS c
                           JOIN bom AS p ON p.cbom = c.pbom
                )
       SELECT  i1.cInvCode 母件編碼,i1.cInvName 母件名稱,b.cbid ,i2.cinvcode 子件編碼,i2.cinvname 子件名稱,com.cComUnitName 單位,
               convert(decimal(18,2),b.baseqtyn) 基本用量,convert(decimal(18,2),b.baseqtyd) 基礎用量,
               convert(decimal(18,2),b.qty) 使用數量,b.lvl 級次,b.cdepcode 部門編碼,d.cdepname 部門名稱,b.cwhcode 倉庫編碼,w.cwhname 倉庫名稱,b.pseq
       FROM    bom AS b
       LEFT JOIN dbo.bas_part b1 WITH (NOLOCK) ON b.pid=b1.PartId
       LEFT JOIN dbo.bas_part b2 WITH (NOLOCK) ON b.cid=b2.PartId
       LEFT JOIN dbo.Inventory i1 WITH (NOLOCK) ON i1.cinvcode=b1.InvCode
       LEFT JOIN inventory i2 WITH (NOLOCK) ON i2.cInvCode=b2.InvCode
       LEFT JOIN dbo.ComputationUnit com WITH (NOLOCK) ON com.cComunitCode = i2.cComUnitCode
       LEFT JOIN dbo.Department d WITH (NOLOCK) ON d.cdepcode=b.cdepcode
       LEFT JOIN dbo.Warehouse w WITH (NOLOCK) ON w.cWhCode=b.cwhcode
       ORDER BY b.pseq
       OPTION  ( MAXRECURSION 10 );  

   同樣是傳入partid去查詢的，需要考慮自由項，如果沒有自由項可以改成只傳存貨編碼也可以，這個也可以改良下做成計算BOM成本的銷售報價單