Oracle進階（一）存儲過程

1、名詞釋義

存儲過程（Stored Procedure）是一組為了完成特定功能的SQL語句集，是由流程控制和SQL語句書寫的命名語句塊。
Oracle存儲過程包含三部分：過程聲明，執行過程部分，存儲過程異常。

2、基本語法

--創建語法
CREATE [OR REPLACE] PROCEDURE 存儲過程名（PARAM1 IN TYPE，PARAM2 OUT TYPE）
AS   --as和is任選一個，在這沒有區別
變量1 類型（值范圍）;
變量2 類型（值范圍）;
BEGIN
    SELECT COUNT(*) INTO 變量1 FROM 表A WHERE列名=PARAM1；
 
    IF (判斷條件) THEN
       SELECT 列名 INTO 變量2 FROM 表A WHERE列名=PARAM1；
       DBMS_OUTPUT.PUT_LINE(‘打印信息’);
    ELSIF (判斷條件) THEN
       DBMS_OUTPUT.PUT_LINE(‘打印信息’);
    ELSE
       RAISE 異常名（NO_DATA_FOUND）;
    END IF;
EXCEPTION
    WHEN OTHERS THEN
       ROLLBACK;
END;
 
--調用語法一
BEGIN
  存儲過程名();
END;
 
--調用語法二
CALL 存儲過程名();
 
--刪除語法
DROP PROCEDURE 存儲過程名;

3、異常釋義

 ACCESS_INTO_NULL 未定義對象

CASE_NOT_FOUND CASE 中若未包含相應的 WHEN ，並且沒有設置ELSE 時
COLLECTION_IS_NULL 集合元素未初始化
CURSER_ALREADY_OPEN 游標已經打開
DUP_VAL_ON_INDEX 唯一索引對應的列上有重復的值
INVALID_CURSOR 在不合法的游標上進行操作
INVALID_NUMBER 內嵌的 SQL 語句不能將字符轉換為數字
NO_DATA_FOUND 使用 select into 未返回行，或應用索引表未初始化的
TOO_MANY_ROWS 執行 select into 時，結果集超過一行
ZERO_DIVIDE  除數為 0
SUBSCRIPT_BEYOND_COUNT 元素下標超過嵌套表或 VARRAY 的最大值
SUBSCRIPT_OUTSIDE_LIMIT 使用嵌套表或 VARRAY 時，將下標指定為負數
VALUE_ERROR 賦值時，變量長度不足以容納實際數據
LOGIN_DENIED PL/SQL 應用程序連接到 oracle 數據庫時，提供了不正確的用戶名或密碼
NOT_LOGGED_ON PL/SQL 應用程序在沒有連接 oralce 數據庫的情況下訪問數據
PROGRAM_ERROR PL/SQL 內部問題，可能需要重裝數據字典＆ pl./SQL系統包
ROWTYPE_MISMATCH 宿主游標變量與 PL/SQL 游標變量的返回類型不兼容
SELF_IS_NULL 使用對象類型時，在 null 對象上調用對象方法
STORAGE_ERROR 運行 PL/SQL 時，超出內存空間
SYS_INVALID_ID 無效的 ROWID 字符串
TIMEOUT_ON_RESOURCE Oracle 在等待資源時超時

4、存儲過程

4.1、無參存儲過程

--1)無參存儲過程語法
 
CREATE OR REPLACE PROCEDURE PRO_1_NOPAR
 AS --聲明
 
 BEGIN --執行
     --SELECT * FROM D_DEPT D;
DBMS_OUTPUT.PUT_LINE('無參存儲過程');
 EXCEPTION--異常
    WHEN OTHERS THEN
       ROLLBACK;
 END;
 
--調用
BEGIN
  PRO_1_NOPAR;
END;

4.2、帶參數存儲過程

IN表示輸入參數，是參數的默認模式。
OUT表示返回值參數，類型可以使用任意Oracle中的合法類型。
OUT模式定義的參數只能在過程體內部賦值，表示該參數可以將某個值傳遞回調。
IN OUT表示該參數可以向該過程中傳遞值，也可以將某個值傳出去。

--2）帶參數存儲過程含賦值方式
CREATE OR REPLACE PROCEDURE PRO_2_PAR   
    (VAL IN NUMBER,   
     SNAME OUT VARCHAR,  
     DT_CODE IN OUT VARCHAR)  
 AS   
    ICOUNT NUMBER;  
 BEGIN  
      SELECT COUNT(*) INTO ICOUNT FROM D_DEPT WHERE DT_ID>VAL;  
      IF ICOUNT=1 THEN  
        SNAME:= 'MLB事業部1' ||VAL;
                DT_CODE:= 'MLB1'||DT_CODE;
      ELSE  
      SNAME:= 'MLB事業部2'||VAL;
                DT_CODE:= 'MLB2'||DT_CODE;
     END IF;  
EXCEPTION  
     WHEN TOO_MANY_ROWS THEN  
     DBMS_OUTPUT.PUT_LINE('返回值多於1行');  
     WHEN OTHERS THEN  
     DBMS_OUTPUT.PUT_LINE('在PRO_1_PAR過程中出錯！');  
END;  
 
--調用
declare  
     REVAL NUMBER;  
     RENAME varchar(40);  
     RECODE varchar(40);  
begin    --過程調用開始  
     REVAL:=20210421;  
     RENAME:='';  
     RECODE:='JUNIOR';  
     --指定值對應變量順序可變  
     PRO_2_PAR(SNAME=>RENAME,VAL=>REVAL,DT_CODE=>RECODE);           
    DBMS_OUTPUT.PUT_LINE(RENAME||'   '||RECODE);  
END;  --過程調用結束

4.3、帶if的存儲過程

--3)帶if的存儲過程
CREATE OR REPLACE PROCEDURE PRO_3_IF(A IN NUMBER, B IN NUMBER,RS OUT NUMBER)
AS
    TEMP NUMBER;
BEGIN
    TEMP:=A;
    IF A < B THEN
        TEMP := B;
    END IF;
    RS:=TEMP;
END;
 
--調用
DECLARE
    RS NUMBER;
BEGIN
    PRO_3_IF(10,20,RS);
    DBMS_OUTPUT.PUT_LINE('RS='||RS);
END;

4.4、帶if else的存儲過程

CREATE OR REPLACE PROCEDURE PRO_4_IFELSE(A IN NUMBER, B IN NUMBER,RS OUT NUMBER)
AS
BEGIN
    IF A > B THEN
        RS := A;
    ELSE
        RS := B;
    END IF;
END;
 
--調用
DECLARE
    RS NUMBER;
BEGIN
    PRO_4_IFELSE(30,20,RS);
    DBMS_OUTPUT.PUT_LINE('RS='||RS);
END; 

4.5、帶elsif的存儲過程

CREATE OR REPLACE PROCEDURE PRO_5_ELSEIF(Y IN NUMBER)
AS
BEGIN
    IF Y=2020 THEN
        DBMS_OUTPUT.PUT_LINE('2020年');
    ELSIF Y =2021 THEN
        DBMS_OUTPUT.PUT_LINE('2021年');
    ELSE
        DBMS_OUTPUT.PUT_LINE('未知年份');
    END IF;
END;
 
--存儲過程調用
BEGIN
  PRO_5_ELSEIF(Y => 2021);
END;

 

4.6、帶while循環的存儲過程

--6)帶while循環的存儲過程
CREATE OR REPLACE PROCEDURE PRO_6_WHILE(I IN NUMBER)
AS
    J NUMBER;
BEGIN
    J := 1;
    WHILE J <= I LOOP
        DBMS_OUTPUT.PUT_LINE('J='||J);
        J := J + 1;
    END LOOP;
END;
 
--存儲過程調用
BEGIN
  PRO_6_WHILE(I=> 100);
END;

4.7、帶select into的存儲過程

在利用SELECT…INTO…語法時，必須先確保數據庫中有該條記錄，否則會報出"NO_DATA_FOUND"異常。
可先利用SELECT COUNT(*) FROM 查看數據庫中是否存在該記錄，存在則使用SELECT…INTO。
在存儲過程中，別名不能和字段名稱相同，否則雖然編譯可以通過，但在運行階段會報錯。

--7)帶SELECT INTO的存儲過程
CREATE OR REPLACE PROCEDURE PRO_7_SELINTO(ID IN NUMBER)
AS
M VARCHAR(50);
G VARCHAR(50);
BEGIN
  SELECT MONTH,ORG_OID INTO M,G FROM D_DEPT where DT_ID=ID;
   DBMS_OUTPUT.PUT_LINE('M'||M||'G'||G);
  EXCEPTION
  WHEN NO_DATA_FOUND THEN
      DBMS_OUTPUT.PUT_LINE('NO_DATA_FOUND異常');
END;
 
 
--存儲過程調用
BEGIN
  PRO_7_SELINTO(ID=> 21);
END;

4.8、帶for的存儲過程

--8）帶for循環的存儲過程
 
CREATE OR REPLACE PROCEDURE PRO_8_FOR
AS
BEGIN
 FOR D IN (SELECT * FROM D_LESSON) LOOP
     IF (D.LN_ID>10) THEN
        DBMS_OUTPUT.PUT_LINE(D.LN_ID);
      END IF;
  END LOOP;
COMMIT;
END;
 
--調用方式一
BEGIN
  PRO_8_FOR();
END;
 
--調用方式二
CALL PRO_8_FOR();
 
--刪除儲存過程
DROP PROCEDURE PRO_8_FOR;

4.9、帶immediate的存儲過程

--1、給動態SQL傳值(USING 子句)
 
CREATE OR REPLACE PROCEDURE PRO_LOOP_BYDATE(V_STARTDATE IN DATE,
                                              V_ENDDATE   IN DATE) IS
  V_DATE    DATE;
  V_ERR_MSG VARCHAR2(2000) := '-1';
 
BEGIN
  V_DATE := V_STARTDATE;
  WHILE V_DATE < V_ENDDATE LOOP
    EXECUTE IMMEDIATE 'BEGIN PRO_DW_PRO_D_LIST_V(:V_DATE,:V_ERR_MSG); END;'
          --傳入開始日期  返回錯誤信息
      USING IN V_DATE, OUT V_ERR_MSG; --黓認為IN類型,其它類型必須顯式指定
    V_DATE := V_DATE + 1;
  END LOOP;
 
END PRO_LOOP_BYDATE;
 
--調用
DECLARE
STARTDATE DATE;
ENDDATE DATE; 
BEGIN
   STARTDATE:=TO_DATE(20210423,'YYYYMMDD');  
   ENDDATE:=TO_DATE(20210423,'YYYYMMDD');  
  PRO_LOOP_BYDATE(V_STARTDATE => STARTDATE,
                      V_ENDDATE => ENDDATE);
END;
 
 
--2、傳遞並檢索值.INTO子句用在USING子句前
 
CREATE OR REPLACE PROCEDURE PRO_INTO_USING
  IS 
   LN_ID    PLS_INTEGER := 41;   
   LN_NAME      VARCHAR2(256);   
   LN_DESC      VARCHAR2(256);   
BEGIN   
   EXECUTE IMMEDIATE 'SELECT LN_NAME, LN_DESC FROM D_LESSON WHERE LN_ID = :1'   
     INTO LN_NAME, LN_DESC  --返回動態SQL中的LN_NAME, LN_DESC值
     USING LN_ID ;  -- 把參數LN_ID 傳入到動態SQL
         
          DBMS_OUTPUT.PUT_LINE('ID:'||LN_ID||'LN_NAME:'||LN_NAME||'LN_DESC'||LN_DESC);
END; 
 
--調用
CALL PRO_INTO_USING();

4.10 帶游標的存儲過程

4.10.1 游標語法與屬性

--游標創建語法
DECLARE 
---聲明CURSOR,創建和命名一個SQL工作區
CURSOR CURSOR_NAME IS 
    SELECT ENAME FROM EMP;
    V_REALNAME VARCHAR2(20);
BEGIN
    OPEN CURSOR_NAME;---打開CURSOR,執行SQL語句產生的結果集
    FETCH CURSOR_NAME INTO V_REALNAME;--提取CURSOR,提取結果集中的記錄
    DBMS_OUTPUT.PUT_LINE(V_REALNAME);
    CLOSE CURSOR_NAME;--關閉CURSOR
END;
 
--游標的屬性：
   %ISOPEN        是否打開        BOOLEAN類型
   %ROWCOUNT    影響的行數    不是總行數，例如總數100，已經取了10條，那么這個數為10
   %FOUND         是否找到        BOOLEAN類型
   %NOTFOUND    是否沒找到     BOOLEAN類型

4.10.2 無參游標存儲過程

--使用無參CURSOR，查詢所有員工的姓名和工資
CREATE OR REPLACE PROCEDURE PROC_10_CURSOR_NOPAR
AS
BEGIN
DECLARE
    --定義游標
    CURSOR CEMP IS SELECT ENAME,SAL FROM EMP;
    --定義變量
    VENAME EMP.ENAME%TYPE;
    VSAL   EMP.SAL%TYPE;
BEGIN
    --打開游標，這時游標位於第一條記錄之前
    OPEN CEMP;
    --循環
    LOOP
       --向下移動游標一次
       FETCH CEMP INTO VENAME,VSAL;
       --退出循環,當游標下移一次后，找不到記錄時，則退出循環
       EXIT WHEN CEMP%NOTFOUND;
       --輸出結果
       DBMS_OUTPUT.PUT_LINE(VENAME||'：'||VSAL);
    END LOOP;
    --關閉游標
    CLOSE CEMP;
END;
END;
 
--調用
BEGIN
  PROC_10_CURSOR_NOPAR;
END;

4.10.3 帶參游標存儲過程

--使用帶參CURSOR，查詢10號部門的員工姓名和工資
CREATE OR REPLACE PROCEDURE PROC_10_CURSOR_PAR(DEPTNO NUMBER)
AS
BEGIN
DECLARE
    CURSOR CEMP(PDEPTNO EMP.DEPTNO%TYPE) IS SELECT ENAME,SAL FROM EMP WHERE DEPTNO=PDEPTNO;
    PENAME EMP.ENAME%TYPE;
    PSAL EMP.SAL%TYPE;
BEGIN
    OPEN CEMP(DEPTNO);
    LOOP
        FETCH CEMP INTO PENAME,PSAL;    
        EXIT WHEN CEMP%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE(PENAME||'的工資是'||PSAL);
    END LOOP;
    CLOSE CEMP;
END;
END;
 
--調用
 
DECLARE        
DEPTNO NUMBER(10):=&EMPNO;   
BEGIN     
PROC_10_CURSOR_PAR(DEPTNO);   
END;