ABAP 用指針的方式

首先要定義指針

FIELD-SYMBOLS: <fs_out> LIKE gt_tab_out.

然后在循環賦值時使用ASSIGNING關鍵字對指針初始化。

LOOP AT lt_tab_out ASSIGNING <fs_out> WHERE aufnr NE space.
        READ TABLE lt_afko WITH KEY aufnr = <fs_out>-aufnr.
        IF sy-subrc EQ 0.
          MOVE lt_afko-fevor TO <fs_out>-fevor.
          MOVE lt_afko-txt TO <fs_out>-fevortxt.
          CLEAR lt_afko.
        ENDIF.
      ENDLOOP.

2、指針的定義和賦值：（這部分網上參考一部分，后續自己有遇到繼續補充）

1、定義指針:
    指針的定義主要有以下語句
    定義任意類型的指針，但是不具備欄位結構（僅僅是一個地址）
    　　FIELD-SYMBOLS <carrid> TYPE ANY.
　　參考數據庫表定義（這種指針是含有欄位結構的，參考內表同理）
    
    　　FIELD-SYMBOLS <sflight> TYPE sflight.
    　　FIELD-SYMBOLS <sflight> LIKE sflight.
    　　FIELD-SYMBOLS <sflight> LIKE LINE OF sflight.
　　動態定義具有欄位結構的指針類型
    
    　　 DATA: tabname TYPE tabname VALUE 'SFLIGHT' ,   
    　　　dref TYPE REF TO data.
    　　  FIELD-SYMBOLS: <itab> TYPE ANY TABLE.    
    　　  CREATE DATA dref TYPE TABLE OF (tabname).
    　　  ASSIGN dref->* TO <itab>.
    2、指針的分配（常用句法）
    分配某個變量給指針
    　　 ASSIGN var TO <field-symbols>
　　分配結構中的某個字段的地址給指針
    
    　　ASSIGN COMPONENT pos OF STRUCTURE struc TO <field-symbols>.
　　分配整個內表行給指針（指針必須定義為有欄位結構的類型）   
    　　READ TABLE itab INDEX/WITH KEY ASSIGNING <field-symbols>.
    　　LOOP AT itab
    　　ASSIGNING  <field-symbols>.
     　　ENDLOOP.
    分配類的方法或借口給指針
    　　ASSIGN dref->* TO <field-symbols>.

賦值：
FIELD-SYMBOLS: <fs1>.   "定義一個指針
DATA: num0     TYPE i VALUE 10,
      num1(10) TYPE c VALUE '巴拉巴拉'.
ASSIGN num0 TO <fs1>.

WRITE:/ '<FS1>:',<fs1>.     "輸出結果：10
WRITE:/ 'num0:',num0.       "輸出結果：10

IF <fs1> IS ASSIGNED.       "一定要進行判斷
  <FS1> = 21.
ENDIF.
WRITE:/ 'num0:',num0.       "輸出結果：21 ；當指針的值變化時，賦值給指針的變量的值也將改變

1， 創建動態內表： 
a,動態內表的結構的定義. 
   動態內表表結構的定義必須使用表結構與 table type: lvc_t_fcat一樣的內表. 
   一般情況下，我們都內表的所有列定義成字符型. 
b,根據表結構生成內表. 
   系統提供了一個標准的method來產生動態表，使用方法如下: 
2， 動態內表的賦值： 
a,獲取指定的字段 
b,給指定的字段賦值 
3， 讀取動態內表的值： 
a,獲取指定的字段 
b,讀取指定的字段值 

REPORT  zdyn_test.
FIELD-SYMBOLS: <dyn_table> TYPE STANDARD TABLE,
<dyn_wa>,
<dyn_field>.
DATA: dy_table TYPE REF TO data,
     dy_line  TYPE REF TO data,
     it_structure TYPE lvc_t_fcat,
     wa_structure TYPE lvc_s_fcat.
START-OF-SELECTION.
PERFORM create_structure.  " 定義內表的結構
PERFORM create_dynamic_table.  " 按照定義的內表結構，產生一個內表
PERFORM write_data_to_dyntable.  " 向動態內表中寫數
PERFORM output_dyntable_data.   " 從動態內表中取數，並寫到屏幕
*&---------------------------------------------------------------------*
*&      Form  create_structure
*&---------------------------------------------------------------------*
FORM create_structure .
wa_structure-fieldname = 'COL1'.  " 第一列列名
wa_structure-col_pos   = 1.       " 表示第一列 --- 可心省略，默認情況下，第一行對應到生產內表的第一列，如果指定，則按指定的列順序生成內表
wa_structure-inttype = 'C'.       " 數據類型
wa_structure-intlen = 6.          " 長度
APPEND wa_structure TO it_structure.
wa_structure-fieldname = 'COL2'.  " 第二列列名
wa_structure-col_pos   = 2.       " 表示第二列--- 可心省略，默認情況下，第一行對應到生產內表的第一列，如果指定，則按指定的列順序生成內表
wa_structure-inttype = 'C'.       " 數據類型
wa_structure-intlen = 6.          " 長度
APPEND wa_structure TO it_structure.
wa_structure-fieldname = 'COL3'.  " 第三列名
wa_structure-col_pos   = 3.       " 表示第三列 --- 可心省略，默認情況下，第一行對應到生產內表的第一列，如果指定，則按指定的列順序生成內表
wa_structure-inttype = 'C'.       " 數據類型
wa_structure-intlen = 6.          " 長度
APPEND wa_structure TO it_structure.
ENDFORM.                    " create_structure
*&---------------------------------------------------------------------*
*&      Form  create_dynamic_table
*&---------------------------------------------------------------------*
FORM create_dynamic_table .
CALL METHOD cl_alv_table_create=>create_dynamic_table
   EXPORTING
it_fieldcatalog = it_structure
   IMPORTING
ep_table        = dy_table.
ASSIGN dy_table->* TO <dyn_table>.    " 用表類型指針 <dyn_table> 指向 數據對象的內容.
ENDFORM.                    " create_dynamic_table
*&---------------------------------------------------------------------*
*&      Form  write_data_to_dyntable
*&---------------------------------------------------------------------*
FORM write_data_to_dyntable .
DATA:wa_new_line TYPE REF TO data.
DATA:i TYPE n.
DATA:j TYPE n.
CREATE DATA wa_new_line LIKE LINE OF <dyn_table>.  " 建立一個與動態內表結構相同的數據對象，且數據對象為是一個結構
ASSIGN wa_new_line->* TO <dyn_wa>.
" 用<dyn_wa>指針指向該結構
DO 3 TIMES.
i = i + 1.
   CLEAR j.
   LOOP AT it_structure INTO wa_structure.
j = j + 1.
     ASSIGN COMPONENT wa_structure-fieldname OF STRUCTURE <dyn_wa> TO <dyn_field>.  " 用指針 <dyn_field>指向工作區<dyn_wa>中的一個字段，字段名為wa_structure-fieldname.
     CONCATENATE i j INTO <dyn_field>.                                              " 給指針指向的字段賦值
   ENDLOOP.
   APPEND <dyn_wa> TO <dyn_table>.
ENDDO.
ENDFORM.                    " write_data_to_dyntable
*&---------------------------------------------------------------------*
*&      Form  output_dyntable_data
*&---------------------------------------------------------------------*
FORM output_dyntable_data .
LOOP AT it_structure INTO wa_structure.
   WRITE: wa_structure-fieldname(5).
ENDLOOP.
LOOP AT <dyn_table> INTO <dyn_wa>.
   WRITE: / .
   LOOP AT it_structure INTO wa_structure.
     ASSIGN COMPONENT wa_structure-fieldname OF STRUCTURE <dyn_wa> TO <dyn_field>.  " 用指針 <dyn_field>指向工作區<dyn_wa>中的一個字段，字段名為wa_structure-fieldname.
     WRITE: <dyn_field>.
   ENDLOOP.
ENDLOOP.
ENDFORM.                    " output_dyntable_data